Diamond Dave (DIMNDAVE.BAS)
Diamond Dave, game by Stephen Stout, 45
Description
Diamond Dave, game by Stephen Stout, 45
From the Antic disk of August 1987 (Vol. 6 No. 4).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 5.4 KB
- Dialect
- Atari BASIC
- Lines
- 102
- Variables
X1,X2,ST,IX,IY,X,Y,Z,DMN,D,S2$,I,ML,MOVE$,LIVES,LEVEL,S1$,ROW(,P0$,PY(,P1$,FIL1$,FIL2$,BUF$,MI$,CHSET,A
BASIC listing (102 lines)
2 REM DIAMOND DAVE
4 REM BY STEPHEN STOUT
6 REM (c)1987, ANTIC PUBLISHING
10 GOTO 570
20 POKE 53248,X1:POKE 53249,X2:X1=X1+1:X2=X2-1
30 IF X1>210 THEN X1=32
40 IF X2<32 THEN X2=210
50 IF PEEK(53252)<>0 AND PEEK(53252)<>2 THEN 210
60 IF PEEK(53253)<>0 AND PEEK(53253)<>2 THEN 210
70 POKE 77,0:ST=STICK(0):IX=(ST=7)-(ST=11):IY=(ST=13)-(ST=14)
80 IF STRIG(0)=0 THEN 180
90 IF IX=0 AND IY=0 THEN 20
100 IF X+IX<0 OR X+IX>19 OR Y+IY<1 OR Y=IY>22 THEN 20
110 LOCATE X+IX,Y+IY,Z:IF Z<>32 AND Z<>163 AND Z<>5 THEN 20
120 POSITION X,Y:? #6;"#":X=X+IX:Y=Y+IY:POSITION X,Y:? #6;"!":SOUND 0,0,0,15:SOUND 0,0,0,0
130 IF Z<>5 THEN 20
140 DMN=DMN+1:POSITION 0+DMN-1,0:? #6;"%":D=X+1+(Y-1)*20:S2$(D,D)="♥"
150 FOR I=250 TO 10 STEP -10:SOUND 0,I,10,8:NEXT I:SOUND 0,0,0,0
160 IF DMN=5 THEN FOR I=1 TO 300:NEXT I:GOTO 270
170 GOTO 20
180 ML=USR(ADR(MOVE$),ADR(S2$),PEEK(88)+PEEK(89)*256+20,460)
190 POKE 53278,0:X=9:Y=1
200 FOR I=10 TO 250 STEP 10:SOUND 0,I,10,8:NEXT I:SOUND 0,0,0,0:GOTO 20
210 LIVES=LIVES-1:POSITION 19-LIVES,0:? #6;" "
220 X=9:Y=1
230 FOR I=15 TO 0 STEP -1:SOUND 0,0,0,I:FOR D=1 TO 15:NEXT D:POKE 710,PEEK(20):NEXT I:POKE 710,148
240 IF LIVES=0 THEN 480
250 ML=USR(ADR(MOVE$),ADR(S2$),PEEK(88)+PEEK(89)*256+20,460):POKE 53278,0
260 GOTO 20
270 IF LEVEL=11 THEN 480
280 POKE 53248,0:POKE 53249,0:POKE 559,0
290 LEVEL=LEVEL+1:POSITION 13,0:? #6;CHR$(ASC(STR$(LEVEL))+128):POSITION 0,0:? #6;" "
300 IF LEVEL=10 THEN POSITION 12,0:? #6;"10"
310 IF LEVEL=11 THEN POSITION 12,0:? #6;"11"
320 ML=USR(ADR(MOVE$),ADR(S1$),PEEK(88)+PEEK(89)*256+20,460)
330 FOR Y=3 TO 21:X=INT(RND(0)*8)+1:POSITION X,Y:? #6;" "
340 X=INT(RND(0)*8)+11:POSITION X,Y:? #6;" ":NEXT Y
350 FOR I=1 TO 5
360 X=INT(RND(0)*18)+1:Y=INT(RND(0)*20)+2:LOCATE X,Y,D:IF D<>32 THEN 360
370 POSITION X,Y:? #6;"┐"
380 NEXT I
390 ML=USR(ADR(MOVE$),PEEK(88)+PEEK(89)*256+20,ADR(S2$),460)
400 X1=32:X2=210
410 D=INT(RND(0)*11)+1:IF ROW(D)<>0 THEN 410
420 ROW(D)=1
430 IF INT(LEVEL/2)*2<>LEVEL THEN P0$(PY(D))="<◀[▶WCj<":GOTO 450
440 P1$(PY(D))="<◀[▶=[f<"
450 X=9:Y=1:POKE 53278,0:DMN=0
460 POKE 559,58
470 GOTO 20
480 FOR I=10 TO 250 STEP 1:SOUND 0,I,10,8:NEXT I:SOUND 0,0,0,0:POKE 53248,0:POKE 53249,0
490 ML=USR(ADR(MOVE$),ADR(S2$),PEEK(88)+PEEK(89)*256+20,460)
500 POSITION 3,9:? #6;"##############"
510 IF LIVES=0 THEN POSITION 3,10:? #6;"# YOU LOST #":GOTO 530
520 IF LEVEL=11 THEN POSITION 3,10:? #6;"# YOU WON #"
530 POSITION 3,11:? #6;"# #":POSITION 3,12:? #6;"#HIT TRIGGER#"
540 POSITION 3,13:? #6;"##############"
550 POKE 77,0:IF STRIG(0)=1 THEN 550
560 RUN
570 GRAPHICS 0:POKE 559,0:POKE 16,64:POKE 53774,64
580 FOR I=53248 TO 53255:POKE I,0:NEXT I:FOR I=704 TO 707:POKE I,0:NEXT I
590 CLR :DIM FIL1$(1),FIL2$((INT(ADR(FIL1$)/2048)+1)*2048-ADR(FIL1$)-1)
600 DIM BUF$(768),MI$(256),P0$(256),P1$(256)
610 BUF$(1)=CHR$(0):BUF$(768)=CHR$(0):BUF$(2)=BUF$:MI$=BUF$:P0$=BUF$:P1$=BUF$
620 DIM MOVE$(56):MOVE$="hh┐▕h┐├h┐┤h┐┘h┐╱h┐┐ ♥p♣1├┌┘f├P▕f▕f┘P▕f┤F┐%┐I▶PhF╱%╱I▶P◆◆"
630 RESTORE 640:FOR I=0 TO 15:READ D:POKE 1664+I,D:NEXT I
640 DATA 104,162,6,160,138,169,7,76,92,228,238,197,2,76,98,228
650 CHSET=144*256
660 ML=USR(ADR(MOVE$),57344,CHSET,1024)
670 RESTORE 710
680 GOTO 700
690 FOR I=0 TO 7:READ D:POKE CHSET+A*8+I,D:NEXT I
700 READ A:IF A<>-1 THEN GOTO 690
710 DATA 1,56,124,130,146,254,40,68,130
720 DATA 3,255,255,255,255,255,255,255,255
730 DATA 4,223,255,251,127,255,254,223,251
740 DATA 5,146,84,0,124,254,124,56,16
750 DATA -1
760 DIM S1$(460),S2$(460)
770 TRAP 780:S1$(LEN(S1$)+1)="DDDDDDDDDDDDDDDDDDDD♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥":GOTO 770
780 S1$(10,10)="├":S2$=S1$
790 DIM ROW(11):FOR I=0 TO 11:ROW(I)=0:NEXT I
800 DIM PY(11):PY(0)=0:PY(1)=49:FOR I=2 TO 11:PY(I)=PY(I-1)+16:NEXT I
810 GRAPHICS 1+16:POKE 559,0:POKE 16,64:POKE 53774,64
820 POKE 708,8:POKE 709,196
830 POSITION 3,0:? #6;"antic magazine":POSITION 6,1:? #6;"presents"
840 D=PEEK(560)+PEEK(561)*256+4:POKE D+6,7:POKE D+8,7
850 POSITION 4,5:? #6;"DIAMOND DAVE":POSITION 2,7:? #6;"BY STEPHEN STOUT"
860 POSITION 2,20:? #6;"TRIGGER TO BEGIN"
870 POKE 559,34
880 POKE 77,0:IF STRIG(0)=0 THEN 900
890 GOTO 880
900 GRAPHICS 1+16:POKE 559,0:POKE 16,64:POKE 53774,64
910 LEVEL=0:POSITION 6,0:? #6;"LEVEL: 1"
920 LIVES=5:POSITION 15,0:? #6;"!!!!!"
930 POKE 756,144:POKE 708,8:POKE 711,36:ML=USR(1664)
940 POKE 704,196:POKE 705,68
950 POKE 54279,ADR(BUF$)/256
960 POKE 53277,3
970 POKE 623,0
980 POKE 53256,0:POKE 53257,0
990 GOTO 270
