Sting Rayer (STINGRAY.BAS)

Sting Rayer, game by Steve Argyle, 18

Description

Sting Rayer, game by Steve Argyle, 18

From the Antic disk of June 1987 (Vol. 6 No. 2).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.2 KB

Dialect
Atari BASIC
Lines
65
Variables
SCORE, PNT, SHOTS, X, Y, N, O, D, HIT, E, C
BASIC listing (65 lines)
4 REM STING RAYER
5 REM BY STEVE ARGYLE
6 REM (c) 1987, ANTIC PUBLISHING
7 GOSUB 400
8 SCORE=0:PNT=200:SHOTS=30
10 X=15:Y=12
20 GRAPHICS 0:POKE 752,1
30 POSITION 2,0:? "STING RAYER   shots=";SHOTS:POSITION 27,0:? "score=0"
35 REM IS TRIGGER PUSHED?
36 IF SHOTS=0 THEN 500
37 IF STRIG(0)=0 THEN FOR N=15 TO 25:SOUND O,N,10,10:NEXT N:GOSUB 100:SOUND 0,0,0,0
40 REM ADD TO X,Y IF JOYSTICK MOVED
41 D=STICK(0):X=X+(D=7)+(D=6)+(D=5)-(D=10)-(D=11)-(D=9)
42 Y=Y-(D=10)-(D=14)-(D=6)+(D=9)+(D=13)+(D=5)
43 REM STOP FROM RUNNING OFF SCREEN
44 IF X<1 THEN X=1
45 IF Y<2 THEN Y=2
46 IF Y>12 THEN Y=12
47 IF X>33 THEN X=33
48 REM DRAW TIE FIGHTER AT NEW PLACE
49 POSITION X,Y-1
50 ? "     "
55 POSITION X,Y
60 ? " ◣▂◢ "
65 POSITION X,Y+1
70 ? "     "
72 IF HIT>0 THEN HIT=HIT-1:GOTO 35
75 GOSUB 135
80 IF PNT>100 THEN PNT=PNT-5
85 GOTO 35
100 REM SUBROUTINE FOR BULLET
105 SHOTS=SHOTS-1:POSITION 22,0:? SHOTS;" "
110 FOR N=Y+1 TO 21:POSITION X+2,N:? " "
111 IF N=E+1 AND C=X THEN POP :GOTO 200
112 POSITION X+2,N+1:? "▕"
114 NEXT N
115 POSITION X+2,N:? "*"
120 SOUND 0,25,8,10:POKE 20,0
125 IF PEEK(20)<6 THEN 125
130 POSITION X+2,N:? " ":SOUND 0,0,0,0:RETURN
135 C=C+INT(RND(0)*3)-1:E=E+INT(RND(0)*3)-1
136 IF C<1 THEN C=1
137 IF C>35 THEN C=35
138 IF E>19 THEN E=19
139 IF E<14 THEN E=14
140 POSITION C,E
145 ? "    "
149 POSITION C,E+1
150 ? "  ♣ "
156 POSITION C,E+2
158 ? "    "
170 RETURN
200 REM HIT
205 SOUND 0,35,8,10:POKE 20,0
210 POSITION X+2,N:? "*"
215 POSITION X+2,N+2:? PNT;
218 GOSUB 400
220 IF PEEK(20)<20 THEN 220
222 SCORE=SCORE+PNT:POSITION 33,0:? SCORE:PNT=200
225 POSITION X+2,N:? " ":POSITION X+2,N+2:? "   ";
230 HIT=10+INT(RND(0)*9):RETURN
400 C=2+INT(RND(0)*32):E=15+INT(RND(0)*4):RETURN
500 POSITION 11,2:? "- OUT OF AMMO -":POSITION 14,4:? "press START"
510 IF PEEK(53279)<>6 THEN 510
520 RUN