Golf Handicapper (GOLFHDCP.BAS)

Golf Handicapper by Jerry White, 38

Description

Golf Handicapper by Jerry White, 38

From the Antic disk of June 1987 (Vol. 6 No. 2).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 4.6 KB

Dialect
Atari BASIC
Lines
99
Variables
CHOICE, TS, D$, BLANK$, T$, ME, SCORE, HANDICAP, B$, LT, SORT, SORT$, TOTAL, BEST, DISK$, BYTE, T
BASIC listing (99 lines)
10 REM GOLF HANDICAPPER
20 REM BY JERRY WHITE
30 REM (c) 1986, ANTIC PUBLISHING
100 GRAPHICS 0:POKE 752,1:GOSUB 810:GOTO 120
110 GOSUB 1020
120 POKE 82,10:POKE 752,0
130 ? :? "1 ENTER SCORES"
140 ? :? "2 DISPLAY SCORES"
150 ? :? "3 SAVE SCORES & EXIT"
160 ? :? "YOUR CHOICE";:TRAP 110:INPUT CHOICE:TRAP 40000
170 CHOICE=INT(CHOICE):POKE 82,2:? CHR$(125)
180 IF CHOICE<1 OR CHOICE>3 THEN 110
190 IF CHOICE<3 THEN POKE 710,CHOICE*80
200 ON CHOICE GOTO 210,500,680
210 TS=TS+1:IF TS>20 THEN TS=20
220 D$(TS*20-19,TS*20)=BLANK$
230 ? :? "ENTER NEW SCORE INFORMATION:"
240 ? :? "DATE (YYMMDD)";:INPUT T$
250 IF LEN(T$)<>6 THEN GOSUB 790:GOTO 240
260 FOR ME=1 TO 6:IF T$(ME,ME)<"0" OR T$(ME,ME)>"9" THEN POP :GOSUB 790:GOTO 240
270 NEXT ME
280 D$(TS*20-19,TS*20-14)=T$
290 ? :? "YOUR SCORE";:INPUT T$
300 IF LEN(T$)<2 OR LEN(T$)>3 THEN GOSUB 790:GOTO 290
310 FOR ME=1 TO LEN(T$):IF T$(ME,ME)<"0" OR T$(ME,ME)>"9" THEN POP :GOSUB 790:GOTO 290
320 NEXT ME
330 D$(TS*20-12,TS*20-13+LEN(T$))=T$:SCORE=VAL(T$)
340 ? :? "COURSE RATING";:INPUT T$
350 IF LEN(T$)<2 OR LEN(T$)>4 THEN GOSUB 790:GOTO 340
360 FOR ME=1 TO LEN(T$)
370 IF LEN(T$)<3 THEN GOTO 390
380 IF ME=3 AND T$(3,3)="." THEN GOTO 400
390 IF T$(ME,ME)<"0" OR T$(ME,ME)>"9" THEN POP :GOSUB 790:GOTO 340
400 NEXT ME
410 D$(TS*20-8,TS*20-9+LEN(T$))=T$:HANDICAP=VAL(T$)
420 ? :? "IS THE ABOVE DATA CORRECT (Y/N)";:INPUT T$
430 IF  NOT LEN(T$) THEN GOTO 420
440 IF T$(1,1)="Y" THEN B$=D$:GOTO 470
450 IF T$(1,1)="N" THEN ? CHR$(125):GOTO 220
460 GOTO 420
470 T$=STR$((SCORE-HANDICAP)*0.95):LT=LEN(T$):IF LT>5 THEN LT=5
480 D$(TS*20-4,TS*20-5+LT)=T$
490 GOTO 110
500 IF  NOT TS THEN ? "I HAVE NO SCORES TO DISPLAY":? :? "PRESS RETURN";:INPUT T$:GOTO 110
510 SORT=USR(ADR(SORT$),ADR(D$),20,TS,1,6,1)
520 POKE 82,10:? CHR$(125):POKE 752,1:TOTAL=0:BEST=0
530 ? " DATE  SCORE  RATING "
540 FOR ME=1 TO TS:? D$(ME*20-19,ME*20-14);
550 SCORE=VAL(D$(ME*20-12,ME*20-10)):IF SCORE>99 THEN ? "  ";
560 IF SCORE<100 THEN ? "   ";
570 ? D$(ME*20-12,ME*20-10);:POSITION 25,ME+1:? D$(ME*20-8,ME*20-5);
580 IF D$(ME*20-5,ME*20-5)=" " THEN ? CHR$(30);CHR$(30);".0":GOTO 600
590 ?
600 NEXT ME
610 BEST=TS/2
620 IF TS/2<>INT(TS/2) THEN BEST=INT(BEST+1)
630 B$=D$:SORT=USR(ADR(SORT$),ADR(B$),20,TS,16,5,0)
640 FOR ME=1 TO BEST:TOTAL=TOTAL+VAL(B$(ME*20-4,ME*20)):NEXT ME
650 HANDICAP=INT(TOTAL/BEST):POKE 752,0
660 ? "CURRENT HANDICAP=";HANDICAP:? " PRESS RETURN";
670 POKE 764,255:INPUT T$:GOTO 110
680 IF  NOT TS THEN 740
690 GOSUB 1020:POKE 752,1:POKE 201,6:? :? ,"SAVING ";DISK$
700 IF TS>20 THEN TS=20
710 TRAP 750:CLOSE #1:OPEN #1,8,0,DISK$
720 FOR ME=1 TO TS:? #1;D$(ME*20-19,ME*20):NEXT ME
730 CLOSE #1:? :? ,DISK$;" SAVED":POKE 752,0:POKE 201,10
740 GRAPHICS 0:END
750 ? :? "I WAS UNABLE TO SAVE YOUR DATA FILE"
760 ? :? "PLEASE CHECK YOUR DISK DRIVE THEN"
770 ? :? "PRESS RETURN TO TRY AGAIN";:INPUT T$
780 GOTO 680
790 ? :? "YOUR INPUT FORMAT IS UNACCEPTABLE":RETURN
800 GRAPHICS 0:CLOSE #1:? :? "UNACCEPTABLE DATA FILE FORMAT":END
810 GOSUB 1020:POKE 752,1
820 DIM SORT$(182),D$(400),B$(400),T$(20),BLANK$(20),DISK$(15)
830 D$=" ":D$(400)=" ":D$(2)=D$:B$=D$:T$=D$:BLANK$=D$
840 DISK$="D1:GOLFHDCP.DAT"
850 FOR BYTE=1 TO 182:READ SORT:SORT$(BYTE,BYTE)=CHR$(SORT):T=T+SORT:NEXT BYTE
860 IF T<>28229 THEN ? :? "ERROR IN DATA STATEMENTS":END
870 POKE 710,148:POKE 709,10:POKE 712,0:POKE 82,2:TS=0
880 DATA 216,104,56,233,3,133,217,104,133,204,104,133,203,104,133,215,104,133,214,104
890 DATA 133,210,104,133,209,162,0,104,104,157,0,1,232,228,217,208,246,56,165,209
900 DATA 233,2,133,209,165,210,233,0,133,210,48,108,165,209,133,211,165,210,133,212
910 DATA 165,204,133,206,133,208,165,203,133,205,24,101,214,133,207,165,208,101,215,133
920 DATA 208,160,0,185,0,1,190,2,1,134,218,190,1,1,200,200,200,132,216,168
930 DATA 136,177,205,209,207,240,12,165,218,208,4,144,16,176,46,144,44,176,10,200
940 DATA 202,208,234,164,216,196,217,208,210,198,211,169,255,197,211,208,6,166,212,240
950 DATA 11,198,212,165,208,133,206,165,207,24,144,172,165,213,240,4,134,213,208,148
960 DATA 96,134,213,160,0,177,205,170,177,207,145,205,138,145,207,200,196,214,208,241,240,203
970 TRAP 1010:CLOSE #1:OPEN #1,4,0,DISK$
980 IF TS=20 THEN 1010
990 INPUT #1;T$:IF LEN(T$)<>20 THEN GOTO 800
1000 TS=TS+1:D$(TS*20-19,TS*20)=T$:GOTO 980
1010 CLOSE #1:TRAP 40000:B$=D$:RETURN
1020 POKE 82,2:POKE 710,0:? "↰"
1030 ? :? "      GOLF HANDICAP CALCULATOR"
1040 ? :? "           by Jerry White"
1050 RETURN