game (CITADEL.BAS)
game by Heath Lawrence, 37
Description
game by Heath Lawrence, 37
From the Antic disk of June 1987 (Vol. 6 No. 2).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 4.5 KB
- Dialect
- Atari BASIC
- Lines
- 59
- Variables
BD,H,Y,BFLAG(,P,Z,S,SX,SHI$,V,SK,SC,X,SCO,IMP,N,MA1(,D,MA2(,ST,I,Q$,A$,MOV,JNK,B
BASIC listing (59 lines)
10 REM CITADEL
20 REM BY HEATH LAWRENCE
30 REM (c) 1987, ANTIC PUBLISHING
40 GOSUB 470:GOSUB 360
50 GOSUB 400
60 BD=BD+1:ON BD=37 GOSUB 240
70 H=INT(RND(0)*36)+2:Y=1:ON BFLAG(H)=0 GOTO 70:BFLAG(H)=0:P=0
80 REM MOVE BOMB
90 FOR Z=1 TO 2:S=STICK(0):SX=SX-1*(S=11)+1*(S=7):SX=SX-1*(SX>35)+1*(SX<0):POSITION SX,19:? SHI$:NEXT Z:POKE 77,0
100 V=INT(RND(0)*3)-1:IF Y>(SK+14) THEN V=0
110 ON (Y=19 AND PEEK(SC+H+40*Y)=101) GOTO 120:POKE SC+H+40*Y,P
120 H=H+V:Y=Y+1:SOUND 1,Y+10,10,8:IF H<1 THEN H=1
130 IF H>37 THEN H=37
140 P=PEEK(SC+H+40*Y):ON P=101 GOTO 290:ON Y>19 GOTO 320:POKE SC+H+40*Y,97:GOTO 90
150 REM GAME OVER
160 POSITION 11,10:? "CITADEL DESTROYED!":POSITION SX+1,18:? " "
170 FOR X=100 TO 200 STEP 8:SOUND 1,X,8,8:POSITION 0,20:? "iiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiiii"
180 POSITION 0,20:? "kkkkkkkkkkkkkkkkkkkkkkkkkkkkkkkkkkkkkkk":NEXT X:SOUND 1,0,0,0:POSITION 0,20
190 ? "fffffffffffffffffffffffffffffffffffffff":POSITION 7,12:? "PRESS START TO PLAY AGAIN"
200 ON PEEK(53279)<>6 GOTO 200:GOTO 50
210 REM UPDATE STATS
220 POSITION 2,0:? "SCORE:";SCO:POSITION 27,0:? "IMPACTS:";IMP:ON IMP=5 GOTO 160:RETURN
230 REM RACK CLEARED
240 POSITION 12,0:? "WAVE COMPLETE!":SCO=SCO+25:GOSUB 220:FOR N=1 TO 9 STEP 2:SOUND 1,MA1(N),10,8
250 FOR D=1 TO MA1(N+1):NEXT D:NEXT N:FOR N=1 TO 9 STEP 2:SOUND 1,MA2(N),10,8:FOR D=1 TO MA2(N+1):NEXT D:NEXT N
260 FOR N=1 TO 9 STEP 2:SOUND 1,MA1(N),10,8:SOUND 2,MA2(N),10,8:FOR D=1 TO MA1(N+1):NEXT D:NEXT N:POSITION 12,0
270 ? " ":SOUND 1,0,0,0:SOUND 2,0,0,0:GOSUB 440:RETURN
280 REM SHIELD HIT
290 SCO=SCO+5:POSITION H,Y:? " ":GOSUB 220:FOR X=30 TO 70:POSITION SX+1,19:? "pp":POSITION SX+1,19:? "qq"
300 SOUND 1,X,12,8:NEXT X:SOUND 1,0,0,0:POSITION SX+1,19:? " ":GOTO 60
310 REM CITY HIT
320 IMP=IMP+1:GOSUB 220:FOR X=100 TO 200 STEP 8:SOUND 1,X,8,8:POKE 710,67:POSITION H,Y:? "k":POKE 710,67
330 POSITION H,Y:? "k":POKE 710,69:POSITION H,Y:? "i":POKE 710,65:POSITION H,Y:? "f":NEXT X:SOUND 1,0,0,0
340 POKE 710,0:GOTO 60
350 REM SELECT LEVEL
360 GRAPHICS 18:POKE 712,82:POSITION 2,5:? #6;"skill level->":SK=1
370 S=STICK(0):SK=SK+1*(S=14)-1*(S=13):SK=SK+1*(SK<1)-1*(SK>3):POSITION 16,5:? #6;SK:FOR D=1 TO 35:NEXT D
380 ON STRIG(0)<>0 GOTO 370:RETURN
390 REM PLAYFIELD
400 GRAPHICS 0:POKE 559,0:POKE 756,ST/256:POKE 752,1:POKE 710,0:SC=PEEK(88)+256*PEEK(89):SCO=0:IMP=0:SX=17
410 FOR X=0 TO 38:POSITION X,21:? "b":POSITION X,22:? "b":NEXT X:POSITION 0,20
420 ? "dcd dc c cdd c dc dc ddc d cdc cdc dc":FOR X=1 TO 80:POSITION INT(RND(0)*39),INT(RND(0)*19):? "j":NEXT X
430 POSITION 10,9:? "lm↓←←no↓→●":GOSUB 220:POKE 559,34:FOR X=35 TO 0 STEP -1
440 SOUND 1,10,4,8:POSITION X,1:? "hga":FOR D=1 TO 15:NEXT D:NEXT X:FOR I=2 TO 37:BFLAG(I)=1:NEXT I
450 POSITION 0,1:? " ":BD=0:POKE 16,112:POKE 53774,112:RETURN
460 REM REDEFINE C-SET
470 DIM MA1(10),MA2(10),SHI$(10),BFLAG(37),Q$(2),A$(136):SHI$=" ee ":POKE 106,PEEK(740)-5
480 Q$(1,1)=CHR$(34):Q$(2,2)=Q$:GRAPHICS 17:POKE 712,66
490 MOV=ADR("hh┐qh┐ph┐Uh┐Th┐oh┐n ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆")
500 A$(1,68)="♥:kkkk:♥n=m_←qg\<◀g▶B◀B◀◀<<◀B◀fCUUU♥♥♥♥♥♥♥♣,jU+W|┤┤◀├↰├◀♥♥├╲◣◀@◀♥─@┤"
510 A$(69,136)=" ◢@♥♥♥♥♣♥♥♥♥hA◢ ├$♥#♥♥┘▖→???♥♥@px|||???→▖┘♥♥|||xp@♥♥##UU◢◢♥♥◢◢UU##♥♥"
520 A$(88,88)=Q$:A$(121,122)=Q$:A$(133,134)=Q$
530 POSITION 6,5:? #6;"CITADEL":POSITION 1,7:? #6;"BY HEATH LAWRENCE":POSITION 2,9:? #6;"(c)1987, ANTIC"
540 ST=(PEEK(106)+1)*256:JNK=USR(MOV,57344,ST,1024):FOR X=1 TO 300:NEXT X
550 JNK=USR(MOV,ADR(A$),776+ST,136)
560 FOR X=1 TO 10:READ Z:MA1(X)=Z:NEXT X:FOR X=1 TO 10
570 READ Z:MA2(X)=Z:NEXT X:RETURN
580 REM TUNE DATA
590 DATA 50,30,46,30,42,30,46,30,50,50,70,30,66,30,62,30,66,30,70,75
