Sound Menu (SOUNDMEN.BAS)

Sound Menu by David Plotkin, 30

Description

Sound Menu by David Plotkin, 30

From the Antic disk of May 1987 (Vol. 6 No. 1).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.7 KB

Dialect
Atari BASIC
Lines
112
Variables
A, DUR, PITCH, ICR, V1, V2, V3, LO, HI, STP, TIME, WAIT, XX, ST, VL, TIMES, CYCLES, W
BASIC listing (112 lines)
10 REM SOUND MENU
12 REM BY DAVID PLOTKIN
14 REM (c) 1987, ANTIC PUBLISHING
16 GRAPHICS 0:? "Choose Your Sound:":? :? "1 RIFLE SHOT"
18 ? "2 BOMB":? "3 SIREN":? "4 EUROPEAN SIREN"
20 ? "5 WHISTLE & BOMB":? "6 SAWING WOOD":? "7 GENTLEMEN, START YOUR ENGINES"
30 POKE 752,0:POKE 77,0:POSITION 0,15:? "Which Sound";:INPUT A
35 POKE 752,1:? :POKE 77,128
40 ON A GOSUB 100,300,500,700,800,1000,1200
50 GOTO 30
100 REM RIFLE SHOT
110 DUR=3
120 PITCH=20:GOSUB 160
130 SOUND 1,0,0,0:SOUND 2,0,0,0
140 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:RETURN
160 SOUND 2,75,8,15
170 ICR=0.62+DUR/100
180 V1=15:V2=15:V3=15
190 SOUND 0,PITCH,8,V1
200 SOUND 1,PITCH+20,8,V2
210 SOUND 2,PITCH+50,8,V2
220 V1=V1*ICR
230 V2=V2*(ICR+0.05)
240 V3=V3*(ICR+0.08)
250 IF V3>1 THEN 190
260 SOUND 0,0,0,0:RETURN
300 REM BOMB
310 DUR=7
320 PITCH=50:GOSUB 360
330 SOUND 1,0,0,0:SOUND 2,0,0,0
340 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:RETURN
360 SOUND 2,75,8,15
370 ICR=0.8+DUR/100
380 V1=15:V2=15:V3=15
390 SOUND 0,PITCH,8,V1
400 SOUND 1,PITCH+20,8,V2
410 SOUND 2,PITCH+50,8,V2
420 V1=V1*ICR
430 V2=V2*(ICR+0.05)
440 V3=V3*(ICR+0.08)
450 IF V3>1 THEN 390
460 SOUND 0,0,0,0:RETURN
500 REM SIREN
510 DUR=10
520 LO=50:HI=35:STP=-0.5
530 FOR TIME=1 TO DUR
540 FOR PITCH=LO TO HI STEP STP
550 SOUND 0,PITCH,10,14
560 FOR WAIT=1 TO 15:NEXT WAIT
570 NEXT PITCH
580 XX=LO:LO=HI:HI=XX:STP=-STP
590 NEXT TIME
600 SOUND 0,0,0,0:RETURN
700 REM EUROPEAN SIREN
710 DUR=5
720 LO=57:HI=45:PITCH=HI
730 FOR TIME=0 TO DUR*2
740 SOUND 0,PITCH,10,14
750 FOR WAIT=1 TO 180:NEXT WAIT
760 PITCH=LO:LO=HI:HI=PITCH
770 NEXT TIME
780 SOUND 0,0,0,0:RETURN
800 REM WHISTLE AND BOMB
810 DUR=5
820 V1=4:FOR PITCH=30 TO 75
830 SOUND 0,PITCH,10,V1
840 SOUND 1,PITCH+3,10,V1*0.7
850 FOR WAIT=1 TO DUR*3:NEXT WAIT
860 V1=V1*1.03:NEXT PITCH
870 SOUND 2,35,8,12
880 V1=15:V2=15:V3=15
890 PITCH=DUR+5:ICR=0.8+DUR/100
900 SOUND 0,PITCH,8,V1
910 SOUND 1,PITCH+20,8,V2
920 SOUND 2,PITCH+50,8,V3
930 V1=V1*ICR
940 V2=V2*(ICR+0.05)
950 V3=V3*(ICR+0.08)
960 IF V3>1 THEN 900
970 SOUND 0,0,0,0:SOUND 1,0,0,0:SOUND 2,0,0,0:RETURN
1000 REM SAWING WOOD
1010 DUR=8
1020 FOR TIME=1 TO DUR
1030 ST=16:VL=12:GOSUB 1060
1040 ST=18:VL=8:GOSUB 1060
1050 NEXT TIME:RETURN
1060 FOR PITCH=ST+5 TO ST STEP -1
1070 GOSUB 1130:NEXT PITCH
1080 FOR PITCH=ST TO ST+5
1090 GOSUB 1140:NEXT PITCH
1100 SOUND 0,0,0,0:SOUND 1,0,0,0
1110 FOR WAIT=1 TO 25:NEXT WAIT
1120 RETURN
1130 SOUND 0,PITCH,4,VL
1140 SOUND 1,PITCH,8,VL*0.7
1150 FOR WAIT=1 TO 3:NEXT WAIT:RETURN
1200 REM GENTLEMEN, START YOUR ENGINES
1210 FOR TIMES=1 TO 3
1220 FOR CYCLES=1 TO 5
1230 SOUND 0,200-CYCLES*20,0,14-CYCLES
1240 FOR WAIT=1 TO 25:NEXT WAIT:NEXT CYCLES
1250 FOR CYCLES=1 TO 7
1260 SOUND 0,CYCLES*20,0,14-CYCLES
1270 FOR WAIT=1 TO 25:NEXT WAIT:NEXT CYCLES
1280 SOUND 0,0,0,0:FOR WAIT=1 TO 100:NEXT WAIT
1290 NEXT TIMES
1300 SOUND 0,100,4,8
1310 FOR WAIT=1 TO 2000:NEXT WAIT
1320 FOR W=200 TO 50 STEP -1
1330 SOUND 0,W,2,10:FOR WAIT=1 TO 10:NEXT WAIT
1340 NEXT W:SOUND 0,50,2,8
1350 FOR WAIT=1 TO 2000:NEXT WAIT:RETURN