graphics demo (HOP.BAS)
graphics demo by Douglas Skrecky, 21
Description
graphics demo by Douglas Skrecky, 21
From the Antic disk of May 1987 (Vol. 6 No. 1).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.6 KB
- Dialect
- Atari BASIC
- Lines
- 51
- Variables
X,LEFT,RIGHT,Y,TOP,BOTTOM,SCALE,XX,MX,CX,CY,CH,CLEAR,SKEY,SPACEBAR,ESCAPE,NAME$,LKEY,CKEY,IO,FILENAME$,D,SDMCTL
BASIC listing (51 lines)
2 REM HOPPER (ATARI VERSION)
4 REM BY DOUGLAS SKRECKY
6 REM (c) 1987 ANTIC PUBLISHING
10 GOSUB 600:REM INITIALIZATION
20 TRAP 20:GOSUB 100
30 IF X>LEFT AND X<RIGHT AND Y>TOP AND Y<BOTTOM THEN PLOT SCALE*(X-LEFT),SCALE*(Y-TOP)
40 XX=Y+SGN(X)*(MX*X-CX):Y=CY-X:X=XX:IF PEEK(CH)=CLEAR THEN 30
50 IF PEEK(CH)=SKEY THEN GOSUB 300
60 IF PEEK(CH)=SPACEBAR THEN GOSUB 500
70 IF PEEK(CH)<>ESCAPE THEN POKE CH,CLEAR:GOTO 30
80 GOTO 20
100 REM MAIN MENU
110 GRAPHICS 0:POKE 710,128:? " MENU "
120 IF SCALE<>0 THEN ? " PARAMETERS USED ARE: ";NAME$:? " ";LEFT;",";RIGHT;",";TOP;",";CY;",";MX;",";CX
130 ? :? " Press L to Load fractal picture":? :? " Press C to Create fractal picture"
140 POKE 752,1:? :? :? " (Press ESCAPE to return to MENU)":POKE 752,0:SCALE=0
150 IF PEEK(CH)=LKEY THEN GOSUB 400:FOR X=1 TO 1000:NEXT X:GOTO 100
160 IF PEEK(CH)<>CKEY THEN 150
170 ? "↰ CREATE A FRACTAL IMAGE "
175 ? :? " Try Parameters:":? " :-1.5,1.5,-1,-.2,.2,.2":? " :-15,16,-12,-1.1,.9,-1"
180 POKE CH,CLEAR:? :? " LEFT BORDER =";:INPUT LEFT
190 ? " RIGHT BORDER =";:INPUT RIGHT:IF RIGHT<=LEFT THEN ? "↰↑↑";:GOTO 190
200 ? " TOP BORDER =";:INPUT TOP:BOTTOM=TOP+(RIGHT-LEFT)*191/319:? " BOTTOM BORDER=";BOTTOM
210 ? " CY =";:INPUT CY:? " MX =";:INPUT MX:? " CX =";:INPUT CX:X=0:Y=0
220 SCALE=319/(RIGHT-LEFT):? :? "Press SPACEBAR to turn screen on/off":? :POKE 752,1
230 ? :? " Press S To Save Image To Disk":? :? :? :? " Press any key to continue"
231 ? "or ESC to return to Main Menu."
232 POKE CH,CLEAR
233 IF PEEK(CH)=28 THEN 100
234 IF PEEK(CH)=CLEAR THEN 233
240 GRAPHICS 8+16:POKE 710,0:COLOR 1:POKE CH,CLEAR:RETURN
300 REM SCREEN SAVE ROUTINE
302 POKE CH,CLEAR:GRAPHICS 8+32:POKE 710,0
303 ? "SAVE filename";:IO=8
304 INPUT NAME$:GOSUB 640:GRAPHICS 8+8*IO-16:POKE 710,0
310 CLOSE #1:OPEN #1,IO,0,FILENAME$
320 POKE 850,IO+3:POKE 852,PEEK(88):POKE 853,PEEK(89):POKE 856,0:POKE 857,30
330 D=USR(ADR("hhh*LVd"),16):IF IO=8 THEN ? #1;"♥(J♥";
340 CLOSE #1:RETURN
400 REM SCREEN LOAD ROUTINE
410 POKE CH,CLEAR:? :? "File to Load";:IO=4:GOTO 304
500 REM TOGGLE SCREEN ON/OFF
510 IF PEEK(SDMCTL)=34 THEN POKE SDMCTL,0:RETURN
520 POKE SDMCTL,34:RETURN
600 REM INITIALIZATION
610 DIM NAME$(19),FILENAME$(19):FILENAME$="D1:":SDMCTL=559
630 CH=764:ESCAPE=28:CLEAR=255:SPACEBAR=33:SKEY=62:LKEY=0:CKEY=18:RETURN
640 IF LEN(NAME$)<3 THEN NAME$(LEN(NAME$)+1)=" "
650 IF NAME$(1,1)="D" AND (NAME$(2,2)=":" OR NAME$(3,3)=":") THEN FILENAME$=NAME$:GOTO 660
660 FILENAME$(4)=NAME$
670 RETURN
