Atari Rogue (AROGUE.BAS)
Atari Rogue, game by Robert Jung, 134 (BASIC, character set)
Description
Atari Rogue, game by Robert Jung, 134 (BASIC, character set)
From the Antic disk of May 1987 (Vol. 6 No. 1).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 15.1 KB
- Dialect
- Atari BASIC
- Lines
- 234
- Variables
CON$,WP$,AR$,PT$,MZ$,Z$,L$,D(,N$,CIO$,X$,YN,IOCB,A,I,SE,BY,F,X,T
BASIC listing (234 lines)
1 REM ATARI ROGUE
2 REM BY ROBERT JUNG
5 REM (c) 1987, ANTIC PUBLISHING
6 REM DO NOT RENUMBER THIS PROGRAM!
10 DIM CON$(32),WP$(100),AR$(100),PT$(70),MZ$(100),Z$(100),L$(40),D(30),N$(20),CIO$(7),X$(1)
20 POKE 82,0:CLOSE #1:CLOSE #2:OPEN #2,4,0,"K:":CIO$="hhh*LVd":YN=2000
100 POKE 106,PEEK(106)-8:GRAPHICS 0:POKE 16,64:POKE 53774,64
110 CLOSE #1:OPEN #1,4,0,"D:AROGUE.FNT"
112 IOCB=848:POKE IOCB+4,0:POKE IOCB+5,PEEK(106)+4:POKE IOCB+8,0:POKE IOCB+9,4:POKE IOCB+2,7
114 A=USR(ADR(CIO$),16):CLOSE #1:POKE 756,PEEK(106)+4:POKE 709,15:POKE 710,0
1000 WP$="dagger handaxe mace sword mace +1 sword +1 scythe +1 sai +2 mace +2 sword +2 "
1002 AR$="leather padded ring mail scale mailchain mailbronze banded splint field plate mail"
1004 PT$="green black purple red crystal blue mauve "
1020 ? "↰↓↓↓↓↓▕|AtariROGUE|▎":? :?
1022 ? "Your name";:INPUT N$:IF LEN(N$)<20 THEN N$(LEN(N$)+1,20)=" "
1025 IF N$=" " THEN 1022
1030 ? "Load a game? ";:GOSUB YN:IF L$="Y" THEN GOSUB 1650
1040 FOR I=1 TO 5:SE=INT(RND(0)*7):BY=INT(RND(0)*7):MZ$=PT$(SE*10+1,SE*10+10):L$=PT$(BY*10+1,BY*10+10)
1042 PT$(SE*10+1,SE*10+10)=L$:PT$(BY*10+1,BY*10+10)=MZ$:NEXT I
1044 D(1)=15:D(2)=1:D(3)=2:D(4)=2:D(5)=1:D(7)=0:D(10)=1:D(11)=1
1046 D(12)=1:D(13)=60:D(14)=60:D(15)=15:D(16)=0
1050 L$="♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥♥":SE=INT(RND(0)*32)+1:? :? :? "Descending the stairs..."
1052 CON$=L$:MZ$=L$:GOTO 1062
1060 SE=INT(RND(0)*32)+1:IF L$(SE,SE)="♥" THEN 1060
1062 BY=INT(RND(0)*4):I=2:F=8:IF BY=0 THEN BY=-8:I=1:F=4
1064 IF BY=2 THEN BY=8:I=4:F=1
1066 IF BY=3 THEN BY=-1:I=8:F=2
1068 IF ((SE/8=INT(SE/8)) AND BY=1) OR ((SE=1 OR SE=9 OR SE=17 OR SE=25) AND BY=-1) THEN 1062
1069 IF (SE<9 AND BY=-8) OR (SE>24 AND BY=8) THEN 1062
1070 IF L$(SE+BY,SE+BY)="├" THEN 1080
1072 L$(SE,SE)="├":L$(SE+BY,SE+BY)="├":MZ$(SE,SE)=CHR$(ASC(MZ$(SE))+I):MZ$(SE+BY,SE+BY)=CHR$(ASC(MZ$(SE+BY))+F)
1074 SE=SE+BY:GOTO 1062
1080 IF L$<>"├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├├" THEN 1060
1082 FOR I=1 TO 32:F=(RND(0)<0.4):MZ$(I,I)=CHR$(ASC(MZ$(I))+128*F):NEXT I
1084 I=INT(RND(0)*32)+1:IF ASC(MZ$(I))<128 THEN 1084
1086 D(25)=I:BY=INT(RND(0)*32)+1:D(6)=BY:IF ABS(BY-I)<25 THEN 1084
1088 CON$="NNNNNNNNNNNNNNNNNNNNNNNNNNNNNNNN":DATA W,A,M,P
1090 FOR SE=1 TO 2:RESTORE 1088:FOR I=1 TO 4:READ Z$:IF RND(0)>0.6 THEN F=INT(RND(0)*32)+1:CON$(F,F)=Z$
1091 NEXT I:NEXT SE
1092 IF RND(0)>0.45 THEN FOR I=1 TO INT(RND(0)*2)+1:F=INT(RND(0)*32)+1:CON$(F,F)="F":NEXT I
1094 FOR I=1 TO INT(RND(0)*5)+5:F=INT(RND(0)*32)+1:CON$(F,F)="G":NEXT I
1098 X=D(25):CON$(X,X)="S":GOSUB 1900:I=D(6):GOTO 1212
1100 X=D(6):IF D(2)=24 AND CON$(X,X)="S" THEN 1500
1101 POKE 702,64:POKE 694,0:GET #2,A:L$=CHR$(A):D(14)=D(13)
1102 IF L$="↑" OR L$="-" OR L$="_" OR L$="↓" OR L$="=" OR L$="|" OR L$="←" OR L$="+" OR L$="\" THEN 1200
1104 IF L$="→" OR L$="^" OR L$="*" THEN 1200
1106 IF L$="I" OR L$="R" OR L$="D" OR L$="C" OR L$="Q" OR L$="S" OR L$="Q" OR L$="L" OR L$="E" THEN 1110
1108 GOTO 1100
1110 IF (L$="E" AND D(3)=0) OR (L$="D" AND CON$(D(6),D(6))<>"S") THEN 1100
1115 IF L$<>"R" THEN GOSUB 1942:GOSUB 1905
1120 IF L$<>"I" THEN 1130
1122 ? "Health [";D(15);"]:";D(1);" Food:";D(3);" Gold:";D(7)
1124 X=D(5):? "Armr:";AR$((X-1)*10+1,X*10);" Wp:";
1125 X=D(4):IF D(16) THEN ? "Cursed ";
1126 ? WP$((X-1)*10+1,X*10)
1128 ? "Heal:";D(10);" Teleport:";D(11);" Fireball:";D(12):? "↑↑↑";:GOSUB 1945:GOTO 1100
1130 IF L$<>"R" THEN 1140
1132 GOSUB 1941:D(1)=D(1)+1:D(13)=D(13)-1:GOSUB 1960:IF RND(0)<0.05 THEN 1350
1134 GOSUB 1945:GOTO 1100
1140 IF L$<>"C" THEN 1160
1142 IF D(10)=0 AND D(11)=0 AND D(12)=0 THEN ? "You have no spells!":? "↑";:GOSUB 1945:GOTO 1100
1144 GOSUB 1470:? "↑↑↑";
1146 IF L$="F" THEN ? "The fireball dissipates.":? "↑";:GOSUB 1945:GOTO 1100
1147 IF L$="T" THEN I=1:GOTO 1270
1148 IF L$="H" THEN I=2:GOTO 1272
1160 IF L$<>"E" THEN 1170
1162 IF D(3)=0 THEN ? "You have no food.":GOTO 1168
1164 L$=">HIC!< >Munch< McRation? ":D(3)=D(3)-1:D(13)=D(13)+105:D(1)=D(1)+11
1166 X=INT(RND(0)*3)+1:? L$((X-1)*10+1,X*10)
1168 ? "↑";:GOSUB 1960:GOSUB 1945:GOTO 1100
1170 IF L$<>"D" THEN 1180
1172 X=D(6):IF CON$(X,X)<>"S" THEN ? "There are no stairs.":? "↑";:GOSUB 1945:GOTO 1100
1174 D(2)=D(2)+1:D(1)=D(1)+3:D(15)=12+3*D(2):GOSUB 1960:GOTO 1050
1180 IF L$="S" THEN 1600
1182 IF L$="L" THEN GOSUB 1650:? "↑";:GOSUB 1945:GOTO 1100
1184 ? "Quit! Are you sure? ";:GOSUB YN:IF L$="Y" THEN 1515
1186 ? "↑↑";:GOSUB 1945:GOTO 1100
1200 GOSUB 1920:I=0:F=-8:IF L$="→" OR L$="*" OR L$="^" THEN I=1:F=1
1202 IF L$="↓" OR L$="=" OR L$="|" THEN I=2:F=8
1204 IF L$="←" OR L$="+" OR L$="\" THEN I=3:F=-1
1206 IF D(20+I)=0 THEN 1100
1210 D(13)=D(13)-1:I=D(6)+F:D(6)=I
1212 IF ASC(CON$(I))>127 THEN GOSUB 1930:CON$(I,I)=CHR$(ASC(CON$(I))-128)
1214 POKE 752,0:GOSUB 1940:IF D(13)>15 AND INT(D(13)/3)=D(13)/3 THEN D(1)=D(1)+1:GOSUB 1960
1220 X=D(6):IF RND(0)<0.12 OR (D(2)=24 AND CON$(X,X)="S") THEN 1350
1230 Z$=CON$(I,I):IF Z$="N" OR Z$="S" THEN GOSUB 1960:GOTO 1100
1240 GOSUB 1941:GOSUB 1905:X=D(6):CON$(X,X)="N":IF Z$<>"F" THEN 1250
1242 ? "You find a ration of food.":D(3)=D(3)+1:GOTO 1320
1250 IF Z$<>"G" THEN 1260
1252 F=INT(RND(0)*(D(2)+1))*3+4*D(2):? "You find ";F;" pieces of gold.":D(7)=D(7)+F:GOTO 1320
1260 IF Z$<>"P" THEN 1280
1261 I=INT(RND(0)*7)+1:IF I=6 AND D(3)=0 THEN 1261
1262 L$=PT$((I-1)*10+1,I*10):GOSUB 1950
1263 ? "You find a ";L$;" potion.":? "Do you drink it? ";:GOSUB YN
1264 IF L$<>"Y" THEN GOSUB 1955:GOTO 1320
1266 IF I<>7 THEN 1270
1267 DATA Choice of a New Generation.,Real Thing.,UnPotion.
1268 RESTORE 1267:X=INT(RND(0)*3)+1:FOR I=1 TO X:READ L$:NEXT I:? "It's The ";L$:GOTO 1320
1270 IF I=1 THEN GOSUB 1945:D(6)=INT(RND(0)*32)+1:I=D(6):GOTO 1212
1272 IF I=2 THEN ? "You feel much healthier.":D(1)=D(15):D(13)=D(13)+45:GOTO 1320
1274 IF I=3 THEN ? "*PAIN* wracks your body!":D(1)=D(1)-INT(RND(0)*15)-5:GOSUB 1960:GOTO 1320
1276 IF I=4 THEN 1350
1277 IF I=5 THEN ? "Your endurance has increased!":D(15)=D(15)+3:GOTO 1320
1278 F=INT(RND(0)*3)+1:IF F>D(3) THEN 1278
1279 ? "Your food rots!":D(3)=D(3)-F:GOTO 1320
1280 IF Z$<>"W" THEN 1290
1282 I=INT(D(2)/3.1)+1:I=INT(RND(0)*3)+I:L$=WP$((I-1)*10+1,I*10):GOSUB 1950
1283 D(25)=0:X=LEN(L$):IF L$(X-2,X-2)=" " THEN L$=L$(1,X-3):D(25)=1
1284 ? "You find a ";L$:X=D(4):? "You have a ";WP$((X-1)*10+1,X*10):? "Do you take it? ";:GOSUB YN
1285 IF L$<>"Y" THEN GOSUB 1955:GOTO 1320
1286 D(4)=I:D(16)=0:? :IF RND(0)>0.8 AND D(25) THEN ? "↑It's *CURSED*!":D(16)=1
1288 GOTO 1320
1290 IF Z$<>"A" THEN 1300
1292 I=INT(D(2)/3.1)+1:I=INT(RND(0)*3)+I:L$=AR$((I-1)*10+1,I*10):GOSUB 1950:X=0
1294 ? "You find a ";L$;" suit of armor":X=D(5):? "You are wearing ";AR$((X-1)*10+1,X*10)
1295 ? "Do you take it? ";:GOSUB YN
1296 IF L$<>"Y" THEN GOSUB 1955:GOTO 1320
1298 D(5)=I:? "It fits.":GOTO 1320
1300 I=INT(RND(0)*3)+1:? "You find a ";:IF I=1 THEN ? "heal";:D(10)=D(10)+1
1302 IF I=2 THEN ? "teleport";:D(11)=D(11)+1
1304 IF I=3 THEN ? "fireball";:D(12)=D(12)+1
1306 ? " spell."
1320 GOSUB 1945:GOSUB 1960:GOTO 1100
1350 GOSUB 1945:GOSUB 1920:? "?←";
1352 F=INT(RND(0)*5)+D(2):RESTORE 1360:FOR I=1 TO F:READ Z$,SE,BY,X:NEXT I
1354 D(28)=SE:D(29)=BY:X=(X-1)*13:D(30)=X+INT(RND(0)*15):IF D(30)<10 THEN D(30)=10
1356 ? CHR$(ASC(Z$)+128);"←";:GOSUB 1905:? :? :? "A ";Z$;" attacks!":GOTO 1370
1360 DATA snake,6,2,1,weasel,6,2,1,bat,8,1,1,giant worm,2,2,2,Stirge,7,3,2,Blob,1,3,2,la-mi'raj,6,3,3
1361 DATA grue,4,3,3,yellow mold,2,4,4
1362 DATA goblin,4,5,3,brass falcon,7,5,4,Wox,4,5,4,Quaggoth,5,5,4,firebat,7,7,5,Basilisk,6,5,6,Vulching,3,6,5
1363 DATA spectre,8,5,6,Norker,4,6,6
1364 DATA rock lizard,3,7,7,Gargoyle,5,8,7,troll,3,6,7,Manticore,8,6,7,Zygom,3,7,8,cockatrice,8,6,8,Barood,5,7,8
1365 DATA Dire Wrath,4,8,9,Fire Dragon,7,8,9,Todram,8,8,9
1370 ? "H:";D(1);" Attk/Wthdw/Cast >";
1372 POKE 702,64:POKE 694,0:GET #2,A:L$=CHR$(A):IF L$<>"A" AND L$<>"W" AND L$<>"C" THEN 1372
1373 IF L$="C" AND D(10)=0 AND D(11)=0 AND D(12)=0 THEN 1372
1374 ? L$:IF L$<>"C" THEN 1390
1376 ? "↑↑";:GOSUB 1470
1390 ? "↑↑↑↑↑↑↑↓";:IF L$<>"W" THEN 1400
1392 X=INT(RND(0)*4)+1:IF D(19+X)=0 THEN ? "The ";Z$;" blocks your way!":GOTO 1422
1394 L$="↑→↓←":L$=L$(X,X):? "You escaped!":? "↑";:GOSUB 1945:GOTO 1200
1400 IF L$="T" THEN I=1:GOTO 1270
1402 IF L$="H" THEN ? "Your health returns!":D(1)=D(15):D(13)=D(13)+45:GOTO 1422
1404 IF L$="F" THEN D(25)=INT(RND(0)*10)+15:GOTO 1410
1405 IF L$<>"A" THEN 1410
1406 F=D(1)/D(15):D(25)=0:IF RND(0)<F-0.05 THEN T=D(4)*2:D(25)=INT(RND(0)*T)+1
1407 IF RND(0)>0.95 THEN D(25)=16+INT(RND(0)*5)
1408 IF INT(RND(0)*12)+1<D(28) OR D(16) THEN D(25)=0
1410 D(30)=D(30)-D(25):IF D(30)>0 THEN 1420
1412 GOTO 1414+2*INT(RND(0)*3)
1414 ? "The ";Z$;" curses you and":? " expires!":GOTO 1419
1416 ? "The ";Z$;" dies in a cloud of":? " greasy black smoke!":GOTO 1419
1418 ? ">Splat!< Now you smell as bad as the":? " ";Z$;" did!"
1419 ? "--*--*--":GET #2,A:GOSUB 1905:GOSUB 1945:GOTO 1230
1420 SE=0:GOSUB 1460
1422 D(25)=0:IF RND(0)<0.25+D(30)*0.01 THEN T=D(29)*2:D(25)=INT(RND(0)*T)+1
1424 D(25)=D(25)-INT(D(5)*1.2):IF D(25)<1 THEN D(25)=0
1426 IF D(2)>3 AND RND(0)>0.95 THEN D(25)=INT(RND(0)*20)+1
1428 D(1)=D(1)-D(25):SE=1:GOSUB 1460:IF D(1)>0 THEN 1370
1430 D(1)=0:? " ...and you die!":GOTO 1500
1450 DATA nick,hit,strike,pound,whack,slam,crack,CLOBBER,PULVERIZE,DEVASTATE
1460 IF D(25)=0 AND SE THEN ? "The ";Z$;" misses.":RETURN
1462 IF D(25)=0 THEN ? "You missed.":RETURN
1464 X=INT(D(25)/2.2)+1:RESTORE 1450:FOR I=1 TO X:READ L$:NEXT I
1466 IF SE THEN ? "The ";Z$;" ";L$;"s you!":RETURN
1468 ? "You ";L$;" the ";Z$;"!":RETURN
1470 ? "Heal:";D(10);" Telep:";D(11);" Fireb:";D(12);" >◀";
1472 POKE 702,64:POKE 694,0:GET #2,A:L$=CHR$(A):IF L$<>"H" AND L$<>"T" AND L$<>"F" THEN 1472
1474 X=10+(L$="T")+2*(L$="F"):IF D(X)<1 THEN 1472
1476 D(X)=D(X)-1:? L$:RETURN
1500 IF D(13)<1 THEN D(1)=0:? "You have starved to death."
1502 IF D(2)<>24 OR D(1)<1 THEN 1510
1504 GOSUB 1905:? "You've found the Jewel!":D(2)=100
1506 FOR I=0 TO 15:SETCOLOR 2,15-I,I:SETCOLOR 4,15-I,I:SOUND 0,200-I*10,8,I:SOUND 1,205-I*10,12,I
1508 FOR X=1 TO 15:NEXT X:NEXT I:FOR I=1 TO 100:NEXT I:SOUND 0,0,0,0:SOUND 1,0,0,0:POKE 710,0:POKE 712,0
1510 ? "Total gold found : ";D(7)
1515 ? :? "Another game? ";:GOSUB YN:IF L$="Y" THEN 1000
1520 POKE 106,PEEK(106)+8:GRAPHICS 0:END
1600 GOSUB 1905:? "Saving your game...":TRAP 1612:CLOSE #1:OPEN #1,12,0,"D:ARSAVE"
1602 TRAP 1615:NOTE #1,SE,BY:INPUT #1,Z$
1604 IF Z$=N$ OR Z$="THIS ACCOUNT IS FREE" THEN 1610
1606 INPUT #1,Z$:INPUT #1,Z$:INPUT #1,Z$:FOR I=1 TO 15:GET #1,F:NEXT I:GOTO 1602
1610 POINT #1,SE,BY:GOTO 1620
1612 CLOSE #1:OPEN #1,8,0,"D:ARSAVE":GOTO 1620
1615 CLOSE #1:OPEN #1,9,0,"D:ARSAVE"
1620 ? #1;N$:? #1;MZ$:? #1;CON$:? #1;PT$
1622 FOR I=1 TO 6:PUT #1,D(I):NEXT I:FOR I=10 TO 16:PUT #1,D(I):NEXT I
1624 SE=INT(D(7)/256):BY=D(7)-SE*256:PUT #1,SE:PUT #1,BY:CLOSE #1
1626 ? "|Game Saved|":GOTO 1515
1650 ? "Loading game...";:TRAP 1680:CLOSE #1:OPEN #1,12,0,"D:ARSAVE"
1652 NOTE #1,SE,BY:INPUT #1,Z$:IF Z$=N$ THEN 1660
1654 INPUT #1,Z$:INPUT #1,Z$:INPUT #1,Z$:FOR I=1 TO 15:GET #1,F:NEXT I:GOTO 1652
1660 INPUT #1,MZ$:INPUT #1,CON$:INPUT #1,PT$
1662 FOR I=1 TO 6:GET #1,F:D(I)=F:NEXT I
1664 FOR I=10 TO 16:GET #1,F:D(I)=F:NEXT I:GET #1,X:GET #1,I:D(7)=X*256+I
1666 POINT #1,SE,BY:? #1;"THIS ACCOUNT IS FREE":CLOSE #1
1670 GOSUB 1900:D(25)=D(6)
1672 FOR I=1 TO LEN(CON$):IF ASC(CON$(I,I))<128 THEN D(6)=I:GOSUB 1930
1674 NEXT I:D(6)=D(25):GOSUB 1945:GOTO 1100
1680 CLOSE #1:? "↑↰ No Game Saved! ":RETURN
1900 ? "↰␛↑/␛↓/␛←/␛→ Move Inventory Rest Level ";D(2):? "Down Stairs Cast Eat Save/Load/Quit":?
1902 D(8)=0:D(9)=0:RETURN
1905 POKE 752,1:POSITION D(8),15:? "↑↑↑↑↑";:D(8)=0:RETURN
1920 X=ASC(MZ$(D(6))):IF X>127 THEN X=X-128
1922 D(20)=(X/2<>INT(X/2)):D(23)=(X>7):D(22)=(X-D(23)*8>3):D(21)=(X-D(23)*8-D(22)*4>1):RETURN
1930 BY=INT((I-1)/8):SE=I-BY*8:POSITION SE*3,BY*3+3:GOSUB 1920
1932 L$=" ↓←←← # ↓←←← ":X$="#":IF MZ$(I,I)>"♥" THEN L$="▗▄▖↓←←←▌ ▌↓←←←▝▄▘":X$=" "
1933 IF CON$(I,I)="S" OR CON$(I,I)="S" THEN L$(9,9)="%"
1934 DATA 2,10,16,8
1936 RESTORE 1934:FOR F=0 TO 3:READ BY:IF D(20+F) THEN L$(BY,BY)=X$
1938 NEXT F:POKE 752,1:? L$;:D(8)=D(8)+3:D(9)=D(9)+2:RETURN
1940 I=D(6):BY=INT((I-1)/8):SE=I-BY*8-1:POSITION SE*3+4,BY*3+4:? "→←";:RETURN
1941 GOSUB 1940:X$=" ":IF ASC(MZ$(I))<128 THEN X$="#"
1942 IF CON$(I,I)="S" THEN X$="%"
1943 IF CON$(I,I)="S" AND D(2)=24 THEN X$="◆"
1944 GOTO 1948
1945 GOSUB 1940:X$=" ":IF ASC(MZ$(I))<128 THEN X$="#"
1946 IF CON$(I,I)="S" THEN X$="%"
1947 IF CON$(I,I)="S" AND D(2)=24 THEN X$="◆"
1948 POKE 752,0:? X$;"←";:RETURN
1950 IF L$(LEN(L$))=" " THEN L$=L$(1,LEN(L$)-1):GOTO 1950
1952 RETURN
1955 ? "↑↑↑It disappears with a >Poof!<":RETURN
1960 IF D(1)>D(15) THEN D(1)=D(15)
1961 IF D(13)>154 THEN D(13)=154
1962 IF D(1)<1 OR D(13)<1 THEN D(1)=0:POP :POP :GOSUB 1905:? "You've died!":GOTO 1500
1963 IF D(13)>14 AND D(14)>14 THEN RETURN
1964 IF D(13)<15 AND D(14)>14 THEN POSITION 0,2:? "You're getting hungry.":? "↑";:GOSUB 1945
1965 IF D(13)<7 AND D(14)>6 THEN POSITION 0,2:? "◀◀◀◀◀◀◀◀You're starving!":? "↑";:GOSUB 1945
1966 IF D(13)>14 AND D(14)<15 THEN POSITION 0,2:? "◀◀◀◀◀◀◀◀◀◀◀◀◀◀◀◀◀◀◀◀◀◀◀◀";:GOSUB 1945
1968 RETURN
2000 POKE 764,255:POKE 702,64:POKE 694,0:GET #2,A:IF A<>78 AND A<>89 THEN 2000
2002 L$=CHR$(A):IF L$="N" THEN ? "No":RETURN
2004 ? "Yes":RETURN
