print utility (PSLABELS.BAS)
print utility by Jim Pierson-Perry, 97
Description
print utility by Jim Pierson-Perry, 97
From the Antic disk of April 1987 (Vol. 5 No. 12).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 11.8 KB
- Dialect
- Atari BASIC
- Lines
- 239
- Variables
C6,C4,C0,GNAME$,C1,C16,BL$,I,C7,I1,C8,C9,X,I2,C3,J,T$,C26,K,P$,CADR,NCHBASE,TOP8,MLOC,L,MOV,TOP0,A$,INV,C5,C2,SRADR,BADR,B$,ERRN,ROPT,SECTR,G$,CLEAR,NCH,Y,Z$,NLABELS,GADR,PG$,PT$,P,CC$,D$,MOV$,PSGD$,SR$,OLDRT,DLLO,DLHI,DLADR,MOPT,BRK
BASIC listing (239 lines)
1000 REM PSLABELS
1005 REM BY JIM PIERSON-PERRY
1010 REM (c) 1987, ANTIC PUBLISHING
1015 REM DO NOT RENUMBER THIS PROGRAM!
1017 BRK=1:IF PEEK(53279)=5 THEN BRK=0
1020 GOTO 2470
1025 IF BRK THEN POKE 16,112:POKE 53774,112
1027 POKE 77,0:RETURN
1030 CLOSE #C6:OPEN #C6,C4,C0,"K:":GNAME$(C1,C16)=BL$(C1,C16):I=C0:POKE 752,C0:POKE 764,255
1040 POSITION C7,12:? "Press ESC For Directory":POSITION 22,C7:IF I1=C8 THEN POSITION C16,C9
1050 GET #C6,X:IF (X=32) OR (X>47 AND X<58) OR (X>64 AND X<91) THEN 1110
1060 IF X=27 THEN POKE 752,C1:GOSUB 3010*(I1=C16)+3140*(I1=C8):I1=C0:RETURN
1070 IF X=155 THEN 1130
1080 IF X<>126 THEN 1050
1090 IF I=C0 THEN 1050
1100 ? CHR$(X);"_";CHR$(30);:GNAME$(I,I)=" ":I=I-C1:GOTO 1050
1110 IF I=I1 THEN 1050
1120 ? CHR$(X);:I=I+C1:GNAME$(I,I)=CHR$(X):GOTO 1050
1130 CLOSE #C6:POKE 752,C1:I2=I:POSITION C7,12:? "Press START To Continue"
1140 FOR I=C1 TO 20:NEXT I:IF PEEK(53279)<>C6 THEN 1140
1150 POSITION C0,12:? BL$(C1,39);:POKE 54286,64:RETURN
1160 POSITION C3,15:? "Please Wait - Processing Text"
1170 FOR I=C0 TO C6:J=ADR(T$(C26*I+C1,C26*I+C1)):K=ADR(P$(208*I+C1,208*I+C1)):X=USR(CADR,J,K,NCHBASE,C26):NEXT I
1180 I1=TOP8:I2=C8:GOSUB 1210:MLOC=TOP8+12
1190 L=ADR(P$):FOR X=MLOC TO 2200+MLOC STEP 40:J=USR(MOV,L,X,26):L=L+26:NEXT X
1200 I1=TOP0:I2=C0:GOSUB 1210:RETURN
1210 POKE 88,I1-256*INT(I1/256):POKE 89,INT(I1/256):POKE 87,I2:RETURN
1220 POKE 512,148:POKE 1688,138:POKE 1690,142:POKE 1701,188:POKE 54286,192:RETURN
1230 FOR X=C3 TO C16:POSITION C0,X:? BL$(C1,39);:NEXT X:RETURN
1240 A$="ENTER TEXT":POSITION C8,5:GOSUB 1290:RETURN
1250 A$="NEW FONT":POSITION 22,5:GOSUB 1290:RETURN
1260 A$="PRINT LABELS":POSITION 7,7:GOSUB 1290:RETURN
1270 A$="NEW GRAPHIC":POSITION 21,7:GOSUB 1290:RETURN
1280 A$="EXIT PROGRAM":POSITION 14,9:GOSUB 1290:RETURN
1290 FOR I=C1 TO LEN(A$):? CHR$(ASC(A$(I,I))+128*INV);:NEXT I:INV=C0:RETURN
1300 GOSUB 1230
1310 POSITION 13,C3:? " NEW GRAPHIC "
1320 POSITION C3,C5:? "Insert Graphics Disk Into Drive #1"
1330 POSITION C2,C7:? "Enter Graphic Name: ________________":I1=C16:GOSUB 1030:IF I1=C0 THEN 1300
1340 X=USR(SRADR,BADR,361,C1,C3):IF B$(C1,15)="PRINT SHOP:CLK!" THEN 1370
1350 ERRN=C1:GOSUB 2340:IF ROPT=C3 THEN POP :GOTO 2970
1360 GOSUB 1220:GOTO 1300
1370 FOR SECTR=362 TO 393:X=USR(SRADR,BADR,SECTR,C1,C3)
1380 FOR I=C0 TO 96 STEP 32:IF B$(I+C1,I+C16)=GNAME$(C1,C16) THEN POP :POP :GOTO 1410
1390 NEXT I:NEXT SECTR:ERRN=C2:GOSUB 2340:IF ROPT=C3 THEN POP :GOTO 2970
1400 GOSUB 1220:GOTO 1300
1410 SECTR=ASC(B$(I+17,I+17))+256*ASC(B$(I+18,I+18))
1420 FOR I=C0 TO 378 STEP 126:X=USR(SRADR,BADR,SECTR,C1,C3)
1430 G$(I+C1,I+126)=B$(C1,126):SECTR=ASC(B$(127,127))+256*ASC(B$(128,128)):NEXT I
1440 X=USR(SRADR,BADR,SECTR,C1,C3):G$(505,572)=B$(C1,68):GOSUB 1220
1450 POSITION C9,C1:? GNAME$(C1,C16);
1460 I1=TOP8:I2=C8:GOSUB 1210
1470 L=ADR(G$):FOR X=TOP8 TO 2050+TOP8 STEP 40:J=USR(MOV,L,X,11):L=L+11:NEXT X
1480 I1=TOP0:I2=C0:GOSUB 1210:RETURN
1490 GOSUB 1230
1500 POSITION 15,C3:? " NEW FONT ":POSITION 5,5:? "Insert Font Disk Into Drive #1:"
1510 POSITION C8,C6:? "Enter Name For Text Font"
1520 POSITION C3,C7:? "(Use Filename Format XXXXXXXX.FNT)"
1530 POSITION C7,C8:? "(Or INTERNAL For ROM Font)"
1540 POSITION C16,C9:? "________":I1=C8:GOSUB 1030:IF I1=C0 THEN 1490
1550 FOR I=I2 TO C1 STEP -C1:GNAME$(I+C3,I+C3)=GNAME$(I,I):NEXT I:GNAME$(C1,C3)="D1:"
1560 GNAME$(I2+C4,I2+C8)=".FNT"
1570 IF GNAME$(C4,11)<>"INTERNAL" THEN 1600
1580 POSITION C3,15:? "Please Wait - Relocating Text Font"
1590 GOSUB 3300:I2=11:GOTO 1650
1600 POKE 54286,64:TRAP 1610:CLOSE #C1:OPEN #C1,C4,C0,GNAME$:TRAP CLEAR:GOTO 1630
1610 TRAP CLEAR:CLOSE #C1:ERRN=C3:GOSUB 2340:IF ROPT=C3 THEN POP :GOTO 2970
1620 GOSUB 1220:GOTO 1490
1630 POKE 852,C0:POKE 853,NCH:POKE 856,C0:POKE 857,C4:POKE 850,C7
1640 X=USR(ADR("hhh*LVd"),C16):CLOSE #C1:GOSUB 1220
1650 POSITION 31,C1:? BL$(C1,C8);:POSITION 31,C1:? GNAME$(C4,I2+C3);:GOSUB 1160:RETURN
1660 GOSUB 1230
1670 POSITION C8,C3:? " ENTER TEXT EDIT KEYS"
1680 POSITION C0,C5:? " "
1690 FOR I=C6 TO 12:POSITION C0,I:? " ":POSITION 27,I:? " ":NEXT I
1700 POSITION C0,13:? " "
1710 POSITION 31,C5:? "Center":POSITION 33,C6:? "TAB"
1720 POSITION 32,C8:? "Erase":POSITION 32,C9:? "CLEAR"
1730 POSITION 31,11:? "Delete":POSITION 30,12:? "BACKSPACE"
1740 POSITION C2,14:? "Type The Label Text In The Box Above"
1750 POSITION C1,15:? "Use The Control Arrows To Move Cursor"
1760 POSITION C5,C16:? "Press ESC When Text Is Ready"
1770 J=C1:Y=C6:I=C1:T$(C1)=" ":T$(182)=" ":T$(C2)=T$
1780 CLOSE #C6:OPEN #C6,C4,C0,"K:":POKE 752,C0:POSITION J,Y
1790 GET #C6,X:IF X=27 THEN 2100
1800 IF X=125 THEN 1860
1810 IF X=126 THEN 1970
1820 IF X=127 THEN 1880
1830 IF (X>27 AND X<32) THEN 1990
1840 IF (X>-C1 AND X<27) OR (X>31 AND X<125) THEN 2080
1850 GOTO 1790
1860 FOR I2=C26*(Y-C6)+C1 TO C26*(Y-C5):T$(I2,I2)=" ":NEXT I2
1870 POSITION C1,Y:? BL$(C1,C26);:J=C1:I=C26*(Y-C6)+C1:POSITION J,Y:GOTO 1790
1880 Z$(C1,C26)=BL$(C1,C26):A$(C1,C26)=T$(C26*(Y-C6)+C1,C26*(Y-C5))
1890 FOR I2=C1 TO C26:IF A$(I2,I2)<>" " THEN POP :K=I2:GOTO 1910
1900 NEXT I2:GOTO 1790
1910 FOR I2=C26 TO C1 STEP -C1:IF A$(I2,I2)<>" " THEN POP :L=I2:GOTO 1930
1920 NEXT I2
1930 IF (C26-L)=(K-C1) THEN 1790
1940 X=INT((C26+K-L)/C2):Z$(C1,X)=BL$(C1,X):Z$(X+C1,X+C1+L-K)=A$(K,L)
1950 POSITION C1,Y:? Z$(C1,26);:T$(26*(Y-C6)+C1,26*(Y-C5))=Z$(C1,C26):J=C1:I=C26*(Y-C6)+C1
1960 POSITION J,Y:GOTO 1790
1970 IF J=C1 THEN 1790
1980 ? CHR$(X);:J=J-C1:I=I-C1:T$(I,I)=" ":GOTO 1790
1990 ON (X-27) GOTO 2000,2020,2040,2060
2000 IF Y=C6 THEN 1790
2010 ? CHR$(X);:Y=Y-C1:I=I-C26:GOTO 1790
2020 IF Y=12 THEN 1790
2030 ? CHR$(X);:Y=Y+C1:I=I+C26:GOTO 1790
2040 IF J=C1 THEN 1790
2050 ? CHR$(X);:J=J-C1:I=I-C1:GOTO 1790
2060 IF J>25 THEN 1790
2070 ? CHR$(X);:J=J+C1:I=I+C1:GOTO 1790
2080 IF J=27 THEN 1790
2090 T$(I,I)=CHR$(X):? CHR$(X);:J=J+C1:I=I+C1:GOTO 1790
2100 CLOSE #C6:POKE 752,C1:FOR I=14 TO C16:POSITION C0,I:? BL$(C1,39);:NEXT I
2110 GOSUB 1160:RETURN
2120 GOSUB 1230
2130 POSITION 12,C3:? " PRINT LABELS ":POSITION C8,C5:? "# Of Labels To Print = ";:INPUT NLABELS
2140 POSITION 11,11:? "Set-up The Printer":POSITION C9,12:? "Press START To Begin"
2150 FOR X=C1 TO 30:NEXT X:IF PEEK(53279)<>C6 THEN 2150
2160 POSITION C0,11:? BL$(C1,39);:POKE 54286,64
2170 TRAP 2180:OPEN #C2,C8,C0,"P:":TRAP CLEAR:GOTO 2200
2180 TRAP CLEAR:CLOSE #C2:ERRN=C4:GOSUB 2340:IF ROPT=C3 THEN POP :GOTO 2970
2190 GOSUB 1220:GOTO 2140
2200 FOR I=C0 TO C6:J=88*I+C1:K=208*I+C1:X=USR(GADR,ADR(G$(J,J)),ADR(PG$(J,J)),11)
2210 X=USR(GADR,ADR(P$(K,K)),ADR(PT$(K,K)),C26):NEXT I
2220 IF P=C1 THEN TRAP 2180:? #C2;"␛E␛T16":TRAP CLEAR:GOTO 2250
2230 IF P=-C1 THEN TRAP 2180:? #C2;"␛B2␛3♣":TRAP CLEAR:GOTO 2250
2240 TRAP 2180:? #C2;"␛M␛3┴":TRAP CLEAR
2250 POSITION C4,12:? "Press OPTION To Stop Printing"
2260 FOR I=C1 TO NLABELS:? #C2:? #C2:IF PEEK(53279)=C3 THEN POP :CLOSE #C2:RETURN
2270 FOR J=C0 TO C6:K=88*J+C1:L=208*J+C1
2280 IF P=C1 THEN ? #C2;"␛S0296";PG$(K,K+87);PT$(L,L+207):NEXT J:GOTO 2300
2290 ? #C2;"␛LX";CHR$(C0);PG$(K,K+87);" ␛LP";CHR$(C0);PT$(L,L+207):NEXT J
2300 NEXT I
2310 IF P=-C1 THEN ? #C2;"␛B1␛2":GOTO 2330
2320 ? #C2;"␛P␛2"
2330 CLOSE #C2:GOSUB 1220:RETURN
2340 SOUND C0,121,10,C8:SOUND C1,128,10,C8:SOUND C2,C8,C2,C2:FOR X=C1 TO 20:NEXT X
2350 FOR X=C0 TO C2:SOUND X,C0,C0,C0:NEXT X
2360 POSITION C0,C4:FOR X=C4 TO 15:POSITION C0,X:? BL$(C1,39);:NEXT X
2370 ON ERRN GOTO 2380,2390,2400,2410
2380 POSITION C5,C7:? "NOT A PRINT SHOP GRAPHICS DISK":GOTO 2420
2390 POSITION C3,C7:? "REQUESTED GRAPHIC NOT ON THIS DISK":GOTO 2420
2400 POSITION C2,C7:? "REQUESTED FONT FILE NOT ON THIS DISK":GOTO 2420
2410 POSITION C9,C7:? "PRINTER NOT RESPONDING"
2420 POSITION 12,C9:? "BASIC Error #";PEEK(195)
2430 POSITION C8,12:? "Press START For Re-Try"
2440 POSITION C9,13:? "Press OPTION To Quit"
2450 FOR X=C1 TO 30:NEXT X:ROPT=PEEK(53279):IF (ROPT=C3) OR (ROPT=C6) THEN GOSUB 1230:RETURN
2460 GOTO 2450
2470 DIM A$(26),B$(128),BL$(40),CC$(140),D$(2048),G$(616),GNAME$(16),MOV$(46),P$(1456),PG$(616)
2480 DIM PSGD$(131),PT$(1456),SR$(55),T$(183),Z$(26)
2490 RESTORE 2990:READ C0,C1,C2,C3,C4,C5,C6,C7,C8,C9,C16,C26
2500 OLDRT=PEEK(106):NCH=OLDRT-C4:POKE 106,OLDRT-C16:NCHBASE=256*NCH
2510 GRAPHICS C8+C16:POKE 752,C1:POKE 709,0:POKE 710,14
2520 DLLO=PEEK(560):DLHI=PEEK(561):DLADR=256*DLHI+DLLO
2530 TOP8=256*PEEK(89)+PEEK(88):TOP0=TOP8+2280:X=PEEK(559)
2540 POKE 559,C0:FOR I=62 TO 78:POKE DLADR+I,C2:NEXT I
2550 POKE DLADR+79,65:POKE DLADR+80,DLLO:POKE DLADR+81,DLHI:POKE 559,X
2560 RESTORE 3000:FOR I=1684 TO 1713:READ X:POKE I,X:POKE I+40,X:NEXT I
2570 POKE 1728,134:POKE 1730,142:POKE 1741,148
2580 POKE 512,148:POKE 513,C6:POKE DLADR+62,130:POKE DLADR+63,130:I1=TOP0:I2=C0
2590 GOSUB 1210:POSITION C8,C0:? "┌──────────────────────┐":POSITION C8,C1:? "|":POSITION 31,C1:? "|"
2600 POSITION C8,C2:? "| PS LABEL MAKER |"
2610 POSITION C8,C3:? "| A Print Shop Utility |"
2620 POSITION C8,C4:? "|":POSITION 31,C4:? "|":POSITION C8,C5:? "└──────────────────────┘"
2630 POSITION 19,C8:? "by":POSITION 11,11:? "Jim Pierson-Perry"
2640 GOSUB 1025:POSITION C2,14:? "Press any key to begin...":POKE 764,255
2645 IF PEEK(764)=255 THEN 2645
2650 SR$(C1)="hh▔┐┘h▔┤┘h▔▝┘h▔◣┘hh▔├┘hh*)R▔▕┘ SdJ-┘┘I├p┤◆♥Pq)♥┐U-┘┘┐T◆"
2660 PSGD$(C1)="hh┐Lh┐Kh┐Nh┐Mhh┐Q▔♣╱)♥▔┌╱)♥"♥↓♥╱Jh◆◢Pw)├"♥↓◢╱◣h◆◢Pw"♥,┌╱)♥┌M┐P┐O$O1K=♥╱p▔$P9◢╱,┌"
2670 PSGD$(81)="╱┴qM┌MfP%O┴eQ┐O%PI◢P[n┌╱h◆◢PH%K┴i├┐K♣▕fL)♥N♣╱M♣╱P1◆"
2680 CC$(C1)="Xhh┐Ph┐Oh┐N▔┐╱h┐M▔┤╱h▔♥╱hhh▔├╱▔▕╱)♥▔┘╱,┘╱1OI 0┐┴i@♣╲I◆0┘8i ┐K)♥┐L┐Q╱K&L╱K&L╱K&L%"
2690 CC$(81)="L┴m♥╱┐L$Q1K,┘╱┌MfQ%QI◢p▂%M┴m├╱┐M♣efNPan┘╱N▕╱p▔-┤╱┐M-┐╱┐N┴♣":CC$(139)=CHR$(155):CC$(140)="◆"
2695 MOV$="hh┐qh┐ph┐Uh┐Th┐oh┐n ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆":MOV=ADR(MOV$)
2700 P$(C1)="♥":P$(1456)="♥":P$(C2)=P$:B$(C1,128)=P$(C1,128):G$(C1,616)=P$(C1,616):PG$(C1,616)=P$(C1,616)
2710 PT$(C1,1456)=P$(C1,1456):T$(C1)=" ":T$(182)=" ":T$(C2)=T$:BL$(C1,40)=T$(C1,40)
2720 GNAME$(C1,C16)=T$(C1,C16)
2730 SRADR=ADR(SR$):GADR=ADR(PSGD$):CADR=ADR(CC$):BADR=ADR(B$):MOV=ADR(MOV$)
2740 POKE 764,255:GNAME$(C1,C5)="BLANK":CLEAR=40000
2750 I2=USR(MOV,57344,NCHBASE,1024)
2760 POSITION C0,C0:? "↰"
2770 POSITION 12,C3:? " SELECT PRINTER ":POSITION 10,10:? "Prowriter = START "
2780 POSITION 13,C8:? "Gemini = SELECT "
2790 POSITION 14,C6:? "Epson = OPTION ":POSITION C5,13:? "Press Button For Your Printer"
2795 GOSUB 3300:P=C1
2800 FOR I=C1 TO 10:NEXT I:X=PEEK(53279):IF X=C6 THEN 2830
2810 IF (X<>C5) AND (X<>C3) THEN 2800
2820 P=C0:PSGD$(40,40)=CHR$(128):PSGD$(46,46)=CHR$(74):IF X=C5 THEN P=-C1
2830 POSITION C0,C0:? "↰":POKE 82,C0:POKE 54286,192
2840 POSITION C1,C1:? "GRAPHIC=";GNAME$(C1,C16):POSITION C26,C1:? "FONT=INTERNAL"
2850 POSITION 0,2:? " ":POSITION 13,C3:? " EDIT OPTIONS ":POKE 702,64
2860 INV=C0:FOR MOPT=C1 TO C5:GOSUB 1230+10*MOPT:NEXT MOPT
2870 POSITION C5,12:? "Press OPTION To Pick Choice"
2880 POSITION C7,13:? "Press START To Continue"
2890 INV=C1:MOPT=C1:GOSUB 1230+10*MOPT
2900 FOR I=C1 TO 10:NEXT I:X=PEEK(53279):IF X=C6 THEN 2940
2910 IF X<>C3 THEN 2900
2920 INV=C0:GOSUB 1230+10*MOPT:MOPT=MOPT+C1:IF MOPT>C5 THEN MOPT=C1
2930 INV=C1:GOSUB 1230+10*MOPT:GOTO 2900
2940 IF MOPT=C5 THEN 2970
2950 ON MOPT GOSUB 1660,1490,2120,1300:GOSUB 1230:GOTO 2850
2960 GOTO 2900
2970 POKE 54286,64:POKE 106,OLDRT:GRAPHICS C0:POKE 752,C0:? "↰":POKE 82,C2
2980 END
2990 DATA 0,1,2,3,4,5,6,7,8,9,16,26
3000 DATA 72,138,72,162,138,169,142,141,10,212,141,23,208,142,24,208,169,188,141,0,2,169,6,141,1,2,104,170,104,64
3010 GOSUB 1230:POSITION C8,C3:? " GRAPHICS DISK DIRECTORY ":POSITION C3,C6:? "Please Wait - Reading Directory"
3020 D$(C1)=" ":D$(2048)=" ":D$(C2)=D$:K=C0:L=C0:POKE 54286,64
3030 FOR SECTR=362 TO 393:X=USR(SRADR,BADR,SECTR,C1,C3)
3040 FOR X=C0 TO 96 STEP 32:IF B$(X+20,X+20)<>"X" THEN 3060
3050 D$(C16*K+C1,C16*K+C16)=B$(X+C1,X+C16):K=K+1
3060 NEXT X:NEXT SECTR:GOSUB 1220:POSITION C0,C6:? BL$(C1,39)
3070 FOR I=C0 TO C7:POSITION C3,C5+I:? D$(C16*(L+I)+C1,C16*(L+I)+C16);" ";D$(C16*(L+I+C8)+C1,C16*(L+I+C8)+C16)
3080 NEXT I
3090 POSITION C2,14:? "Press OPTION To Continue Directory":POSITION C8,15:? "Press START To Return"
3100 FOR I=C0 TO 20:NEXT I:X=PEEK(53279):IF X=C6 THEN RETURN
3110 IF X<>C3 THEN 3100
3120 IF L+15>K THEN L=C0:GOTO 3070
3130 L=L+C16:GOTO 3070
3140 GOSUB 1230:POSITION 10,C3:? " FONT DISK DIRECTORY ":POSITION C3,C6:? "Please Wait - Reading The Directory"
3150 D$(C1)=" ":D$(2048)=" ":D$(C2)=D$:K=C0:L=C0:POKE 54286,64
3160 FOR SECTR=361 TO 368:X=USR(SRADR,BADR,SECTR,C1,C3)
3170 FOR X=C0 TO 112 STEP C16:IF B$(X+14,X+C16)<>"FNT" THEN 3210
3180 IF (B$(X+C1,X+C1)<>"B") AND (B$(X+C1,X+C1)<>"b") THEN 3210
3190 IF ASC(B$(X+C2,X+C2))<>C9 THEN 3210
3200 D$(C8*K+C1,C8*K+C8)=B$(X+C6,X+13):K=K+C1
3210 NEXT X:NEXT SECTR:GOSUB 1220:POSITION C0,C6:? BL$(C1,39)
3220 IF K=C0 THEN POSITION C0,C6:? "No Font Files On Disk":FOR X=C1 TO 100:NEXT X:RETURN
3230 FOR I=C0 TO C7:POSITION C1,C5+I:? D$(C8*(L+I)+C1,C8*(L+I)+C8);" ";D$(C8*(L+I+C8)+C1,C8*(L+I+C8)+C8);" ";
3240 ? D$(C8*(L+I+C16)+C1,C8*(L+I+C16)+C8);" ";D$(C8*(L+I+24)+C1,C8*(L+I+24)+C8):NEXT I
3250 POSITION C2,14:? "Press OPTION To Continue Directory":POSITION C8,15:? "Press START To Return"
3260 FOR I=C0 TO 20:NEXT I:X=PEEK(53279):IF X=C6 THEN RETURN
3270 IF X<>C3 THEN 3260
3280 IF L=32 THEN L=C0:GOTO 3230
3290 L=L+32:GOTO 3230
3300 I2=USR(MOV,57344,NCHBASE,1024):RETURN
