New Owner's Column #13 (NEWOWN13.BAS)

New Owner's Column #13 by David Plotkin, 18

Description

New Owner's Column #13 by David Plotkin, 18

From the Antic disk of April 1987 (Vol. 5 No. 12).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.2 KB

Dialect
Atari BASIC
Lines
52
Variables
C, LP, NDX1, NDX2, NDY1, NDY2, X, Y, LUM1, LUM2, LUM3, HOLD, WAIT
BASIC listing (52 lines)
10 REM THE NEW OWNER'S COLUMN #12
20 REM BY DAVID PLOTKIN
25 REM (c)1987, ANTIC PUBLISHING
30 GRAPHICS 7+16:REM 4 COLORS, 160x92
40 C=2:REM COLOR INDEX
50 SETCOLOR 0,5,4:SETCOLOR 1,5,8:SETCOLOR 2,5,12:REM SET THE COLORS
60 FOR LP=20 TO 30:REM DRAW LANDSCAPE
70 COLOR C:C=C+1:IF C=4 THEN C=1
80 PLOT 0,LP:DRAWTO 159,LP
90 NEXT LP
100 FOR LP=31 TO 50 STEP 2
110 COLOR C:C=C+1:IF C=4 THEN C=1
120 PLOT 0,LP:DRAWTO 159,LP:PLOT 0,LP+1:DRAWTO 159,LP+1
130 NEXT LP
140 FOR LP=51 TO 72 STEP 3
150 COLOR C:C=C+1:IF C=4 THEN C=1
160 PLOT 0,LP:DRAWTO 159,LP:PLOT 0,LP+1:DRAWTO 159,LP+1:PLOT 0,LP+2:DRAWTO 159,LP+2
180 NEXT LP:COLOR C
190 FOR LP=75 TO 79
200 PLOT 0,LP:DRAWTO 159,LP
210 NEXT LP
220 COLOR 0:PLOT 79,20:C=2
230 FOR LP=1 TO 10
240 NDX1=79-LP:NDX2=79+LP:NDY1=20+LP-1:NDY2=20+LP
250 COLOR C:C=C+1:IF C=4 THEN C=1
260 PLOT NDX1,NDY1:DRAWTO NDX1,NDY2:DRAWTO NDX2,NDY2:DRAWTO NDX2,NDY1
270 NEXT LP
280 FOR LP=11 TO 32 STEP 2
290 NDX1=79-LP:NDX2=79+LP:NDY1=20+LP-1:NDY2=20+LP
300 COLOR C:C=C+1:IF C=4 THEN C=1
310 PLOT NDX1,NDY1:DRAWTO NDX1,NDY2:DRAWTO NDX2,NDY2:DRAWTO NDX2,NDY1
320 PLOT NDX1-1,NDY1+1:DRAWTO NDX1-1,NDY2+1:DRAWTO NDX2+1,NDY2+1:DRAWTO NDX2+1,NDY1+1
330 NEXT LP
340 FOR LP=33 TO 58 STEP 3
350 NDX1=79-LP:NDX2=79+LP:NDY1=20+LP-1:NDY2=20+LP+1
360 COLOR C:C=C+1:IF C=4 THEN C=1
370 PLOT NDX1,NDY1:DRAWTO NDX1,NDY2:DRAWTO NDX2,NDY2:DRAWTO NDX2,NDY1
380 PLOT NDX1-1,NDY1+1:DRAWTO NDX1-1,NDY2+1:DRAWTO NDX2+1,NDY2+1:DRAWTO NDX2+1,NDY1+1
390 PLOT NDX1-2,NDY1+2:DRAWTO NDX1-2,NDY2+2:DRAWTO NDX2+2,NDY2+2:DRAWTO NDX2+2,NDY1+2
400 NEXT LP
500 FOR LP=1 TO 20
510 X=RND(0)*159:Y=RND(0)*18
520 COLOR RND(0)*3+1
530 PLOT X,Y
540 NEXT LP
600 REM THE ROTATION ROUTINE
610 LUM1=4:LUM2=8:LUM3=12:HOLD=0:WAIT=20
620 SETCOLOR 0,5,LUM1:SETCOLOR 1,5,LUM2:SETCOLOR 2,5,LUM3
630 HOLD=LUM3:LUM3=LUM2:LUM2=LUM1:LUM1=HOLD
640 FOR LP=1 TO WAIT:NEXT LP
650 WAIT=WAIT-(STICK(0)=14 AND WAIT>1)+(STICK(0)=13 AND WAIT<40)
660 GOTO 620