Word Finder (WORD.BAS)
Word Finder, game by Kevin Peck, 70 (BASIC, puzzle files)
Description
Word Finder, game by Kevin Peck, 70 (BASIC, puzzle files)
From the Antic disk of March 1987 (Vol. 5 No. 11).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 6.7 KB
- Dialect
- Atari BASIC
- Lines
- 164
- Variables
BRK,WORD$,GRID$,L$,CL$,BYTE(,X,DX,L,WIDTH,Y,DY,HEIGHT,EX,SX,EY,SY,P,GX,GY,EX1,EY1,Z,I,STARTROW,STARTCOL,MISS,CFLAG,COUNT,FLASH,SFLG,NY,NX,STMP,FND,LINE,H,P0,P1,P2,PMB,FOUND
BASIC listing (164 lines)
2 REM WORD FINDER
4 REM BY KEVIN PECK
6 REM (c) 1987, ANTIC PUBLISHING
8 BRK=1:IF PEEK(53279)=5 THEN BRK=0
10 GRAPHICS 0:POKE 710,96:DIM WORD$(25),GRID$(576),L$(14),CL$(14),BYTE(8)
20 TRAP 25:READ WIDTH:RESTORE :GOSUB 1510:GOTO 30:REM DO INITIALIZATION
25 ? :? :? :? :? " I can't find any puzzle data!":? :? :? :END
30 GOTO 270:REM LOOK FOR 1ST. LETTER
40 REM FIND REST OF WORD
80 IF X+(DX*L)<0 OR X+(DX*L)>WIDTH+1 THEN 235
90 IF Y+(DY*L)<0 OR Y+(DY*L)>HEIGHT+1 THEN 235
100 EX=SX+DX:EY=SY+DY:P=2:GX=X+DX:GY=Y+DY
105 EX1=EX:EY1=EY
110 LOCATE EX,EY,Z:Z=Z+128:COLOR Z:PLOT EX,EY
120 IF WORD$(P,P)<>GRID$((GY-1)*WIDTH+GX,(GY-1)*WIDTH+GX) THEN 210
130 P=P+1:IF P>L THEN POP :GOTO 1370
140 EX=EX+DX:EY=EY+DY:GX=GX+DX:GY=GY+DY:GOTO 110
150 REM
160 POSITION 17,7:? "W↓←O↓←R↓←D":GOTO 235
210 LOCATE EX,EY,Z:Z=Z-128:COLOR Z:PLOT EX,EY
220 P=P-1:IF P=1 THEN 235
230 EX=EX-DX:EY=EY-DY:GOTO 210
235 RETURN
240 REM ----------
270 I=1
280 READ WORD$:L=LEN(WORD$)
290 IF L<13 THEN POSITION 26+INT((12-L)/2),10:? WORD$:GOTO 320
300 POSITION 26,10:? WORD$(1,12):POSITION 26,11:IF L<25 THEN ? WORD$(13,L):GOTO 320
310 ? WORD$(13,24)
320 IF L<=WIDTH OR L<=HEIGHT THEN 490
330 POSITION 26,14:? "This word is"
340 POSITION 26,15:? " too LONG"
350 POSITION 26,16:? "for puzzle!!"
360 GOTO 820
370 REM
420 POKE 106,PEEK(740):POKE 53277,0:POKE 559,34:FOR I=0 TO 2:POKE 53248+I,0:NEXT I:GRAPHICS 0:END
430 REM
490 Y=1
495 SY=Y+STARTROW-1
500 X=1
505 SX=X+STARTCOL-1
510 LOCATE SX,SY,Z:Z=Z+128:COLOR Z:PLOT SX,SY
520 IF WORD$(1,1)<>GRID$((Y-1)*WIDTH+X,(Y-1)*WIDTH+X) THEN 700
530 REM
590 DX=-1:POKE 77,0:IF BRK THEN POKE 16,112:POKE 53774,112
595 DY=-1
600 IF DX=0 AND DY=0 THEN 620
610 GOSUB 80
620 IF DY<1 THEN DY=DY+1:GOTO 600
625 IF DX<1 THEN DX=DX+1:GOTO 595
630 FOUND=1
700 LOCATE SX,SY,Z:Z=Z-128:COLOR Z:PLOT SX,SY
710 IF X<WIDTH THEN X=X+1:GOTO 505
711 IF Y<HEIGHT THEN Y=Y+1:GOTO 495
720 FOUND=0
790 POSITION 27,14:? "Word could"
800 POSITION 26,15:? "NOT be found"
810 POSITION 27,16:? "in puzzle!"
820 POKE 710,48:POKE 712,48:GOSUB 1050
830 MISS=MISS+1
840 POSITION 35,5:IF MISS<10 THEN POSITION 36,5
850 ? MISS
860 IF CFLAG=3 THEN 420
870 IF I<COUNT THEN I=I+1:GOTO 280
880 REM
930 POSITION 26,10:? CL$:POSITION 26,11:? CL$:POKE 710,0:POKE 712,0
940 POSITION 28,15:? "FINISHED":FLASH=0:GOSUB 1060
950 IF CFLAG=6 THEN 930
960 GOTO 420
970 REM
1050 POSITION 27,19:? "START␛→Cont"
1060 POSITION 27,21:? "OPTION␛→End":SFLG=0
1070 NY=EY1-DY:NX=EX1-DX
1072 IF (FOUND) THEN LOCATE NX,NY,Z:COLOR (Z+FLASH):PLOT NX,NY
1073 STMP=PEEK(53279):IF STMP<7 THEN SFLG=STMP
1074 IF NX<>EX OR NY<>EY THEN NY=NY+DY:NX=NX+DX:GOTO 1072
1075 IF (SFLG=0 OR Z>128) THEN 1070
1080 CFLAG=3:IF SFLG=6 THEN CFLAG=6
1090 REM
1130 POSITION 26,10:? CL$:POSITION 26,11:? CL$:POKE 710,96:POKE 712,96
1140 POSITION 26,14:? CL$:POSITION 26,15:? CL$:POSITION 26,16:? CL$
1150 POSITION 26,19:? CL$:POSITION 26,21:? CL$:SFLG=0:RETURN
1160 REM
1210 IF PEEK(195)<>6 THEN 1270
1220 POSITION 26,14:? "Unexpectedly"
1230 POSITION 26,15:? "out of words"
1240 POSITION 28,16:? "in DATA!":POKE 710,48:POKE 712,48
1250 GOSUB 1060:IF CFLAG=6 THEN 1220
1260 GOTO 420
1270 POSITION 27,14:? "Unexpected"
1280 POSITION 26,15:? "ERROR # ";PEEK(195):POKE 710,48:POKE 712,48
1290 POSITION 26,16:? "in LINE ";PEEK(186)+256*PEEK(187)
1300 GOSUB 1060:IF CFLAG=6 THEN 1270
1310 GOTO 420
1320 REM
1370 POSITION 27,14:? "Word FOUND"
1380 POSITION 26,15:? "at indicated"
1390 POSITION 28,16:? "location"
1400 POKE 710,192:POKE 712,192
1410 FND=FND+1
1420 POSITION 35,4:IF FND<10 THEN POSITION 36,4
1430 ? FND
1440 GOSUB 1050:IF CFLAG=3 THEN 420
1450 GOSUB 210:GOTO 870
1460 REM
1510 POKE 752,1:GOSUB 160:TRAP 1520:READ WIDTH,HEIGHT:GOTO 1570
1520 POSITION 2,10
1530 IF PEEK(195)<>8 THEN 1560
1540 ? "First DATA statement must contain WIDTH and HEIGHT of grid. One or"
1550 ? "both of these numbers are missing!":END
1560 ? "ERROR #";PEEK(195);" in LINE ";PEEK(186)+256*PEEK(187):END
1570 IF WIDTH>24 OR WIDTH<0 THEN POSITION 2,10:? "Improper WIDTH value in DATA!":END
1580 IF HEIGHT>24 OR HEIGHT<0 THEN POSITION 2,10:? "Improper HEIGHT value in DATA!":END
1590 LINE=0:FOR I=1 TO WIDTH*HEIGHT STEP WIDTH:LINE=LINE+1
1600 READ WORD$:L=LEN(WORD$):IF L=WIDTH THEN 1640
1610 POSITION 2,10:? "Width of GRID DATA element #";LINE
1620 IF L<WIDTH THEN ? "is too short!":END
1630 ? "is too long!":END
1640 GRID$(I,I+WIDTH-1)=WORD$:NEXT I
1650 TRAP 1660:READ COUNT:GOTO 1750
1660 POSITION 2,10:? "DATA statement following GRID DATA":? "statements does not contain the"
1670 ? "number of WORDS to search for. Please check number of GRID DATA and"
1680 ? "check for possible missing WORD COUNT DATA statement.":END
1690 REM
1750 H=PEEK(106)-8:POKE 106,H:GRAPHICS 0:POKE 752,1:POKE 710,96:GOSUB 160:POSITION 14,10:? "FINDER"
1755 GOSUB 160:POSITION 14,10:? "FINDER":POSITION 12,13:? "BY KEVIN":POSITION 16,12:? "P↓↓←C↓←K"
1760 BYTE(0)=0:BYTE(1)=128:BYTE(2)=192:BYTE(3)=224:BYTE(4)=240:BYTE(5)=248:BYTE(6)=252:BYTE(7)=254:BYTE(8)=255
1770 STARTCOL=INT((24-WIDTH)/2+0.5):FLASH=128
1780 STARTROW=INT((24-HEIGHT)/2+0.5)
1790 P0=WIDTH:IF P0>8 THEN P0=8
1800 P1=WIDTH-8:IF P1>8 THEN P1=8
1810 IF P1<0 THEN P1=0
1820 P2=WIDTH-16:IF P2<0 THEN P2=0
1830 POKE 54279,H:POKE 559,46:POKE 53277,3
1840 POKE 53256,3:POKE 53257,3:POKE 53258,3
1850 POKE 704,145:POKE 705,145:POKE 706,145:POKE 712,96
1860 PMB=H*256+512:POKE 623,1
1870 FOR I=PMB TO PMB+15+(STARTROW*4):POKE I,0:POKE I+128,0:POKE I+256,0:NEXT I
1880 FOR X=I TO I+(HEIGHT*4)-1:POKE X,BYTE(P0):POKE X+128,BYTE(P1):POKE X+256,BYTE(P2):NEXT X
1890 FOR I=X TO PMB+127:POKE I,0:POKE I+128,0:POKE I+256,0:NEXT I
1900 X=48+(STARTCOL*4)
1910 POKE 53248,X:POKE 53249,X+32:POKE 53250,X+64
1920 REM
1970 ? "↰":POKE 82,STARTCOL:POSITION STARTCOL,STARTROW
1980 LINE=1:FOR I=1 TO LEN(GRID$) STEP WIDTH
1990 ? GRID$(I,I+WIDTH-1);:IF LINE<24 THEN ?
2000 LINE=LINE+1:NEXT I
2010 REM
2060 POSITION 25,0:POKE 82,25
2070 L$="| |"
2080 CL$="├────────────┤"
2090 ? "┌────────────┐"
2100 ? "| COMPUTER |"
2110 ? "| WORD FIND |":? CL$
2120 ? "| # FOUND 0 |"
2130 ? "| # MISS 0 |":? CL$
2140 ? "|SEARCH WORD|"
2150 ? CL$:? L$:? L$:? L$:? L$:? CL$
2160 ? L$:? L$:? L$:? CL$:? L$:? L$
2170 ? L$:? L$:? L$
2180 ? "└────────────┘";
2190 POKE 82,2:FND=0:MISS=0:TRAP 1210
2200 CL$=" ":REM 12 SPACES
2210 RETURN
