Wages and Hours (WAGES.BAS)

Wages and Hours by Hal Boyer, 41

Description

Wages and Hours by Hal Boyer, 41

From the Antic disk of March 1987 (Vol. 5 No. 11).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 4.9 KB

Dialect
Atari BASIC
Lines
107
Variables
NBRDGT, DECPLS, N, BP, BP$, NUMBER$, OTP, OTP$, TP, TP$, YR, YR$, WORK$, BLANK$, DECPNT, J, NBRLTH, K, L$, HRS, LOUD, E, EMP$, BASE, R$, R, LINEFEED, PLINE$, OT, ROW, COL, L, SLINE$, GO$
BASIC listing (107 lines)
10 REM WAGES AND HOURS
20 REM BY HAL BOYER
25 REM (c) 1987, ANTIC PUBLISHING
26 REM IMPORTANT: SEE PRINTER CODES IN LINES 350 & 370 IF YOU DON'T OWN
27 REM AN EPSON-COMPATIBLE PRINTER!
30 CLR :GOSUB 1040:GOTO 455
50 REM GOSUB ROUTINES
70 NBRDGT=6:DECPLS=2:N=BP:GOSUB 110:BP$=NUMBER$(1,NBRDGT):RETURN
80 NBRDGT=6:DECPLS=2:N=OTP:GOSUB 110:OTP$=NUMBER$(1,NBRDGT):RETURN
90 NBRDGT=7:DECPLS=2:N=TP:GOSUB 110:TP$=NUMBER$(1,NBRDGT):RETURN
100 NBRDGT=8:DECPLS=2:N=YR:GOSUB 110:YR$=NUMBER$(1,NBRDGT):RETURN
110 WORK$=STR$(N)
120 NUMBER$=BLANK$
130 DECPNT=LEN(WORK$)+1
140 FOR J=1 TO LEN(WORK$)
150 IF WORK$(J,J)="." THEN DECPNT=J:J=NBRDGT
160 NEXT J
170 NBRLTH=DECPNT+DECPLS
180 NUMBER$(NBRDGT-NBRLTH+1,NBRDGT)=WORK$
190 NUMBER$(NBRDGT-DECPLS,NBRDGT-DECPLS)="."
200 FOR J=NBRDGT-DECPLS+1 TO NBRDGT
210 IF NUMBER$(J,J)=" " THEN NUMBER$(J,J)="0"
220 NEXT J
230 RETURN
240 POSITION 4,22:? "  RETURN=CONTINUE  ESC=QUIT  "
245 CLOSE #1:OPEN #1,4,0,"K:":GET #1,K:CLOSE #1:IF K<>155 AND K<>27 THEN 245
250 POSITION 0,22:? CHR$(156):RETURN
260 L$(1,1)="|":L$(6)=STR$(HRS):L$(11)="|":L$(16)="$":L$(17)=BP$
270 L$(28)="|":L$(33)="$":L$(34)=OTP$:L$(49)="|"
280 L$(54)="$":L$(55)=TP$:L$(67)="|":L$(70)="$":L$(71)=YR$:L$(80)="|"
290 RETURN
300 L$(1,1)="|":L$(2)=STR$(HRS):L$(6)="|":L$(8)=BP$:L$(14)="|":L$(16)=OTP$:L$(22)="|"
310 L$(23)=TP$:L$(30)="|":L$(31)=YR$:L$(39)="|"
320 RETURN
330 FOR LOUD=14 TO 0 STEP -1:SOUND 0,50,10,LOUD:SOUND 1,60,10,LOUD:NEXT LOUD:RETURN
340 POSITION 0,5:FOR E=1 TO 20:? "↑";:NEXT E:RETURN
350 LPRINT "␛▂":REM PRINTER CODE FOR ONE LINE OF EXPANDED PRINT
360 LPRINT "            *WAGES & HOURS*"
370 LPRINT :LPRINT :LPRINT "␛▖":REM PRINTER CODE FOR CONDENSED PRINT
390 LPRINT "NAME: ";EMP$:LPRINT
400 LPRINT "BASE RATE= $";BASE;"                                                      52 WKS"
410 LPRINT "|   HRS   |   BASE PAY     |   OVERTIME PAY     |   WEEKLY PAY    | YEARLY PAY |"
420 RETURN
440 REM MAIN PROGRAM INPUT
455 GRAPHICS 0:POKE 709,0:POKE 710,8:POKE 712,118
460 POKE 752,0:? "↰":POSITION 11,1:? "  WAGES & HOURS  "
470 POSITION 11,2:? "================="
480 TRAP 480:POSITION 5,4:? "Enter Base Rate..";:INPUT BASE
490 IF BASE<=0 OR BASE>20 THEN GOSUB 330:POSITION 5,4:? "      Input out of range ↰↰":GOTO 460
500 TRAP 500:POSITION 5,6:? "Enter Name..";:INPUT EMP$
510 IF EMP$="" THEN 10
520 IF LEN(EMP$)>12 THEN GOSUB 330:POSITION 5,6:? "  Limit Name to 12 Characters  ↰↰↰":GOTO 460
530 TRAP 530:POSITION 3,8:? "Send Output to Printer or Screen ";:INPUT R$
540 TRAP 40000
550 IF R$="" THEN 10
560 IF R$(1,1)<>"P" AND R$(1,1)<>"S" THEN GOSUB 330:GOTO 530
570 IF R$="S" THEN 890
590 REM PRINT ROUTINE
610 POKE 752,1:POSITION 8,10:? "  PRINTING IN PROGRESS  "
620 TRAP 740
630 GOSUB 350
640 FOR R=1 TO 51
650 IF R=24 OR R=48 THEN FOR LINEFEED=1 TO 8:LPRINT :NEXT LINEFEED:GOSUB 350
660 HRS=HRS+0.5:POKE 77,0
670 L$=BLANK$
680 GOSUB 780
690 LPRINT PLINE$
700 LPRINT L$
710 NEXT R
720 LPRINT "------------------------------------------------------------------------------"
730 POKE 752,0:GOSUB 330:GOTO 10
740 POSITION 12,21:? " Check Printer ":GOSUB 240:TRAP 40000:GOTO 10
760 REM FORMULAS AND JUSTIFY
780 BP=BASE*40:BP=INT(BP*100+0.5)/100:GOSUB 70
790 OT=HRS-40:IF OT<=0 THEN OT=0
800 OTP=OT*BASE*1.5:OTP=INT(OTP*100+0.5)/100:GOSUB 80
810 TP=BP+OTP:TP=INT(TP*100+0.5)/100:GOSUB 90
820 YR=TP*52:YR=INT(YR*100+0.5)/100:GOSUB 100
830 IF R$(1,1)="P" THEN GOSUB 260:GOTO 850
840 GOSUB 300
850 RETURN
870 REM SCREEN DISPLAY ROUTINE
890 ROW=5:COL=0:POKE 752,1:? "↰"
900 POSITION 11,1:? "  WAGES & HOURS  "
910 POSITION 2,2:? "Name..";EMP$
920 POSITION 22,2:? "Base Rate..";"$";BASE
930 POSITION 0,4:? "|HRS BASE PAY  OT PAY  WEEKLY  YEARLY |"
940 FOR L=1 TO 51
950 HRS=HRS+0.5
960 L$=BLANK$(1,40):GOSUB 780
970 POSITION COL,ROW:? L$;:ROW=ROW+1
975 IF ROW>20 THEN GOSUB 330:GOSUB 240:IF K=27 THEN POP :GOTO 10
978 IF ROW>20 THEN GOSUB 340:ROW=5
980 NEXT L
990 POSITION COL,ROW:? " -------------------------------------"
1000 GOSUB 330:GOSUB 240:POKE 752,0:GOTO 10
1020 REM SETUP ROUTINE
1040 DIM L$(80),BP$(20),OTP$(20),TP$(20),YR$(20),NUMBER$(80),PLINE$(80),EMP$(20),SLINE$(40),R$(10),GO$(10)
1050 DIM BLANK$(80),WORK$(20)
1060 PLINE$="-":PLINE$(80)="-":PLINE$(2)=PLINE$
1070 PLINE$(1,1)="|":PLINE$(11,11)="|":PLINE$(28,28)="|":PLINE$(49,49)="|":PLINE$(67,67)="|":PLINE$(80,80)="|"
1080 SLINE$="-":SLINE$(39)="-":SLINE$(2)=SLINE$
1090 SLINE$(1,1)="|":SLINE$(7,7)="|":SLINE$(15,15)="|":SLINE$(23,23)="|":SLINE$(31,31)="|":SLINE$(39,39)="|"
1100 BLANK$=" ":BLANK$(80)=" ":BLANK$(2)=BLANK$
1110 HRS=39.5
1120 POKE 82,0
1130 RETURN