game (VECTRON.BAS)
game by Heath Lawrence, 50
Description
game by Heath Lawrence, 50
From the Antic disk of March 1987 (Vol. 5 No. 11).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 6.0 KB
- Dialect
- Atari BASIC
- Lines
- 78
- Variables
BRK,PY,LY,PX,PT,V,SC,PP,D,X,S1,S2,NA,LJK,DT,LP,LX,Y1,Y2,TR,SV,CX,CY,CP,H,W,Z,P,DE,ST,Y,MOVE,Q,K
BASIC listing (78 lines)
5 REM VECTRON
6 REM BY HEATH LAWRENCE
7 REM (c) 1987, ANTIC PUBLISHING
8 BRK=1:IF PEEK(53279)=5 THEN BRK=0
10 GOSUB 560
20 GOSUB 500:GOTO 120
30 REM MOVE PROJECTILE
40 POKE 77,0:PY=LY:PX=2+34*(PT=2):V=2+2*(PT=2):POKE SC+PX+40*PY,10
50 POKE SC+PX+40*PY,0:PY=PY+(V=3)-(V=1):PX=PX+(V=2)-(V=4):PP=PEEK(SC+PX+40*PY):POKE SC+PX+40*PY,10
60 FOR D=1 TO 10:NEXT D:IF PP=12 OR PP=13 THEN GOSUB 340:RETURN
70 ON (PP<>4 AND PP<>5 AND PP<>6 AND PP<>7 AND PP<>8 AND PP<>9) GOTO 50:POKE 710,67:POKE SC+PX+40*PY,83
80 FOR X=1 TO 200 STEP 3:SOUND 1,X,8,10:NEXT X:SOUND 1,0,0,0:POKE 710,35
90 V=1*(PP=6)+2*(PP=4 OR PP=8)+3*(PP=7)+4*(PP=5 OR PP=9):S1=S1+(PT=1):S2=S2+(PT=2):GOSUB 400
100 NA=NA-(PP<>8 AND PP<>9):ON NA=0 GOTO 420:GOSUB 400:GOTO 50
110 REM MAIN ROUTINE
120 LJK=28:GOSUB 610:PT=1:DT=36:GOSUB 200:LP=8:LX=1:LY=Y1:GOSUB 160:Y1=LY
130 LJK=0:GOSUB 610:PT=2:DT=36:GOSUB 200:LP=9:LX=37:LY=Y2:GOSUB 160:Y2=LY
140 GOTO 120
150 REM MOVE LAUNCHERS
160 TR=STRIG(0)*(PT=1)+STRIG(1)*(PT=2):ON TR=0 GOTO 40:SV=STICK(0)*(PT=1)+STICK(1)*(PT=2)
170 ON SV<>13 AND SV<>14 GOTO 160:POKE SC+LX+40*LY,0:LY=LY+1*(SV=13)-1*(SV=14):LY=LY+1*(LY<1)-1*(LY>19)
180 POKE SC+LX+40*LY,LP:FOR D=1 TO 15:NEXT D:GOTO 160
190 REM SET UP A DEFLECTOR
200 POKE SC+1+40*Y1,8:POKE SC+37+40*Y2,9:POSITION 9,0:? "DEFLECTOR TYPE> ";CHR$(DT)
210 TR=STRIG(0)*(PT=1)+STRIG(1)*(PT=2):IF TR=0 THEN FOR D=1 TO 200:NEXT D:GOTO 250
220 SV=STICK(0)*(PT=1)+STICK(1)*(PT=2):ON SV<>14 AND SV<>13 AND SV<>7 AND SV<>11 GOTO 200
230 DT=36*(SV=7)+37*(SV=11)+38*(SV=14)+39*(SV=13):GOTO 200
240 REM MOVE CURSOR
250 POSITION 9,0:? ",,,,,,,,,,,,,,,,,,":CX=20:CY=10:CP=PEEK(SC+CX+40*CY):POKE SC+CX+40*CY,DT+96
260 TR=STRIG(0)*(PT=1)+STRIG(1)*(PT=2)
270 IF TR=0 AND CP<>0 THEN SOUND 1,42,2,12:FOR D=1 TO 50:NEXT D:SOUND 1,0,0,0:GOTO 260
280 IF TR=0 AND CP=0 THEN POSITION CX,CY:? CHR$(DT):FOR D=1 TO 200:NEXT D:NA=NA+1:GOSUB 400:RETURN
290 SV=STICK(0)*(PT=1)+STICK(1)*(PT=2):ON SV=15 GOTO 260:POKE SC+CX+40*CY,CP
300 CX=CX-1*(SV=9 OR SV=10 OR SV=11)+1*(SV=5 OR SV=6 OR SV=7)
310 CY=CY-1*(SV=6 OR SV=10 OR SV=14)+1*(SV=5 OR SV=9 OR SV=13)
320 CX=CX+1*(CX<3)-1*(CX>35):CY=CY-1*(CY>19)+1*(CY<1):CP=PEEK(SC+CX+40*CY):POKE SC+CX+40*CY,DT+96:GOTO 260
330 REM GUTTER BALL
340 ON PP=13 GOTO 370:FOR H=PX TO 0 STEP -1:POKE SC+H+40*PY,11:SOUND 1,H+50,10,8:FOR D=1 TO 15:NEXT D
350 FOR H=PX TO 0 STEP -1:POKE SC+H+40*PY,11:SOUND 1,H+50,10,8:FOR D=1 TO 15:NEXT D:POKE SC+H+40*PY,12
360 POKE SC+H+40*PY,12:NEXT H:SOUND 1,0,0,0:RETURN
370 FOR H=PY TO 1 STEP -1:POKE SC+PX+40*H,14:SOUND 1,H+50,10,8:FOR D=1 TO 15:NEXT D:POKE SC+PX+40*H,13:NEXT H
380 SOUND 1,0,0,0:RETURN
390 REM UPDATE STATS
400 POSITION 9,21:? S1:POSITION 37,21:? S2:POSITION 25,21:? NA;" ":RETURN
410 REM GAME OVER/PLAY AGAIN?
420 GRAPHICS 17:POSITION 5,2:? #6;"game over":POSITION 5,3:? #6;"=========":POSITION 4,5:? #6;"PLAYER 1>";S1
430 POSITION 4,7:? #6;"PLAYER 2>";S2:IF S1=S2 THEN POSITION 5,10:? #6;"tie game!":GOTO 450
440 W=1+(S2>S1):POSITION 3,10:? #6;"player ";W;" wins"
450 POSITION 3,14:? #6;"PRESS <START>":POSITION 3,15:? #6;"TO PLAY AGAIN"
460 FOR Z=1 TO 2:RESTORE 650:FOR X=1 TO 8:READ P:READ D:SOUND 1,P,10,8:SOUND 2,P+10,10,6:FOR DE=1 TO D:NEXT DE
470 SOUND 1,0,0,0:SOUND 2,0,0,0:NEXT X:NEXT Z
480 ON PEEK(53279)<>6 GOTO 480:GOTO 20
490 REM PLAYFIELD
500 GRAPHICS 0:POKE 752,1:POKE 756,ST/256:POKE 710,35:SC=PEEK(88)+256*PEEK(89):S1=0:S2=0:Y1=10:Y2=10
505 POKE 77,0:IF BRK THEN POKE 16,112:POKE 53774,112
510 COLOR 45:PLOT 0,1:DRAWTO 0,19:PLOT 38,1:DRAWTO 38,19
511 COLOR 44:PLOT 0,0:DRAWTO 38,0:PLOT 0,20:DRAWTO 39,20
520 NA=0:POSITION 0,21:? "PLAYER 1: TARGETS LEFT: PLAYER 2:":Y1=10:Y2=10
530 Y=INT(RND(0)*19)+1:X=INT(RND(0)*33)+3:V=INT(RND(0)*4)+4:IF PEEK(SC+X+40*Y)<>0 THEN 530:POKE SC+X+40*Y,V
540 POKE SC+X+40*Y,V:NA=NA+1:GOSUB 400:ON NA<>50 GOTO 530:RETURN
550 REM REDEFINE
560 POKE 106,PEEK(740)-5:GRAPHICS 17:POSITION 6,7:? #6;"VECTRON":POSITION 6,8:? #6;"-------":POSITION 8,10
565 POKE 77,0:IF BRK THEN POKE 16,112:POKE 53774,112
570 ? #6;"by:":POSITION 3,13:? #6;"heath lawrence":POSITION 2,17:? #6;"PRESS TRIGGER...":ST=(PEEK(106)+1)*256
575 MOVE=ADR("hh┐qh┐ph┐Uh┐Th┐oh┐n ♥1p┌TfTP▕fUfpP▕fqFnPjFo♣f◆")
576 REM X=USR(MOVE,FROM_ADDRESS,TO_ADDRESS,AMOUNT)
580 X=USR(MOVE,57344,ST,1024)
581 Q=ADR("┴▘╱▶▶╱▘┴┴0◆▶▶◆0┴┴<◀[▌┴┴┴┴┴┴▌[◀<┴→▶┘♠♠┘▶→y▶A__A▶y♥┴<◀◀<┴♥▶┴<◀◀<┴▶▶♥♥♥♥♥♥▶├├├├├├├├├▌=▶▶=▌├")
585 X=USR(MOVE,Q,ST+32,88)
590 IF (STRIG(0) AND STRIG(1)) THEN 590
600 RETURN
610 FOR K=(LJK=28)*28 TO (LJK=0)*28 STEP (2*(LJK=0)-1)
615 SOUND 2,(-2.179*K+121),14,14
620 POSITION K,22:? " ======== ";:SOUND 2,0,0,0:NEXT K
630 POKE 77,0:IF BRK THEN POKE 16,112:POKE 53774,112
635 RETURN
640 REM TUNE DATA
650 DATA 62,20,58,20,54,20,48,30,48,30,54,20,58,20,62,50
