New Owner's Column #12 (NEWOWN12.BAS)

New Owner's Column #12 by David Plotkin and Charles Jackson, 20

Description

New Owner's Column #12 by David Plotkin and Charles Jackson, 20

From the Antic disk of March 1987 (Vol. 5 No. 11).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.4 KB

Dialect
Atari BASIC
Lines
49
Variables
TEMP, X, GMODE, WIDTH, HEIGHT, MAXKLR, K, FACT, FACT2, Y1, Y2
BASIC listing (49 lines)
10 REM THE NEW OWNERS COLUMN #12
20 REM BY DAVE PLOTKIN
25 REM (DEMO PROGRAM BY CHARLES JACKSON)
30 REM (c) 1986, ANTIC PUBLISHING
35 POKE 704,50:POKE 705,180:POKE 706,30:POKE 707,146
40 GRAPHICS 1+16
50 POSITION 5,4:? #6;"ThIs Is"
60 POSITION 3,8:? #6;"GrApHiCs OnE"
65 POSITION 2,15:? #6;"PrEsS aNy KeY";CHR$(129):POKE 764,255
70 TEMP=PEEK(711):POKE 711,PEEK(710):X=SIN(4)
80 POKE (710),PEEK(709):X=SIN(4):POKE 709,PEEK(708):X=SIN(4)
90 POKE 708,TEMP:X=SIN(4):IF PEEK(764)=255 THEN 70
100 POKE 764,255:GRAPHICS 2+16
110 POSITION 4,4:? #6;"GrApHiCs 2"
120 GOSUB 1000:GRAPHICS 2+32:? CHR$(125);"(HERE'S THE TEXT WINDOW)"
130 ? :? " -> Press any key <- "
140 GOSUB 1000:GRAPHICS 2+16+32:IF PEEK(764)=255 THEN 120
145 REM NOW LET'S SEE GR. 3-11
150 GMODE=3:WIDTH=39:HEIGHT=19:MAXKLR=4:GOSUB 800
160 GMODE=4:WIDTH=79:HEIGHT=39:MAXKLR=2:GOSUB 800
170 GMODE=5:WIDTH=79:HEIGHT=39:MAXKLR=4:GOSUB 800
180 GMODE=6:WIDTH=159:HEIGHT=79:MAXKLR=2:GOSUB 800
190 GMODE=7:WIDTH=159:HEIGHT=79:MAXKLR=4:GOSUB 800
200 GMODE=8:WIDTH=319:HEIGHT=159:MAXKLR=2:GOSUB 800
210 GMODE=9:WIDTH=79:HEIGHT=191:MAXKLR=16:GOSUB 800
220 GMODE=10:WIDTH=79:HEIGHT=191:MAXKLR=9:GOSUB 800
230 GMODE=11:WIDTH=79:HEIGHT=191:MAXKLR=16:GOSUB 800
240 END
799 REM RANDOMLY SELECT TWO SINE WAVES AND DRAW A LINE BETWEEN CORRESPONDING POINTS
800 GRAPHICS GMODE:K=1:DEG :IF GMODE>8 THEN K=8
810 COLOR K:IF GMODE>8 THEN 820
812 ? "↰GRAPHICS ";GMODE;"   (";WIDTH+1;" x ";HEIGHT+1;", ";MAXKLR;
815 ? " colors)":? :? "      Drawing in COLOR ";K
820 FACT=INT(RND(0)*180):POKE 764,255
830 FACT2=INT(RND(0)*180)
840 FOR X=(HEIGHT*-1) TO HEIGHT STEP 2+INT(RND(0)*GMODE)
850 Y1=ABS(SIN(FACT+X)*WIDTH)
860 Y2=ABS(SIN(FACT2+X)*WIDTH)
870 PLOT Y1,ABS(X):DRAWTO Y2,HEIGHT-ABS(X)
880 NEXT X:SOUND 0,75,14,14:GOSUB 1000:SOUND 0,0,0,0:POKE 77,0
890 IF GMODE<9 THEN ? "↰Press [SELECT] to change GR. modes.":? :? "Press [START]  to continue."
900 ON (PEEK(53279)) GOTO 900,900,900,900,920,910,900
910 K=INT(RND(0)*MAXKLR):IF MAXKLR=16 AND K/2<>INT(K/2) THEN 910
915 GOTO 810
920 RETURN
999 END
1000 POKE 20,0:REM GENERIC TIMER ROUTINE
1010 IF PEEK(20)<50 THEN 1010
1020 RETURN