Multi-AUTORUNs with Atari DOS, disk utility (MULTIAUT.BAS)
Multi-AUTORUNs with Atari DOS, disk utility by Bill Bodenstein, 13
Description
Multi-AUTORUNs with Atari DOS, disk utility by Bill Bodenstein, 13
From the Antic disk of March 1987 (Vol. 5 No. 11).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 1.5 KB
- Dialect
- Atari BASIC
- Lines
- 34
- Variables
A$,SASALO,SASAHI,CLSELO,CLSEHI,SASA,LOMEM,N
BASIC listing (34 lines)
10 REM MULTI-AUTORUNS WITH ATARI DOS
20 REM BY BILL BODENSTEIN
30 REM (c) 1987, ANTIC PUBLISHING
40 DIM A$(1)
50 IF PEEK(5498)=76 AND PEEK(5496)=166 THEN 70
60 ? "Please boot an Atari DOS 2.0 or 2.5":? "disk before running this program.↰":GOTO 430
70 GRAPHICS 0:POKE 712,66
80 ? :? " This program permanently modifies your DOS.SYS file, ";
85 ? "permitting you to run several AUTORUN.SYS files at boot-time."
86 ? :? :? "Continue Y (Y/N)←←←←←←←←";:INPUT A$:POKE 712,0
88 IF A$<>"Y" THEN ? :? "Aborted!":GOTO 430
90 ? :? "Make sure your DOS disk is in drive 1.":? "Press RETURN";:INPUT #16,A$:? "↑↑"
100 SASALO=PEEK(1804):SASAHI=PEEK(1805):CLSELO=PEEK(5499):CLSEHI=PEEK(5500)
110 SASA=SASALO+SASAHI*256:LOMEM=PEEK(743)+PEEK(744)*256
150 ? "Modifying DOS..."
160 RESTORE :TRAP 300
170 READ N
180 SASA=SASA+1:LOMEM=LOMEM+1
190 IF N<0 THEN POKE SASA-1,CLSELO:READ N:IF N<0 THEN N=CLSEHI:GOTO 180
200 IF N>=512 THEN N=SASAHI+N-512
210 IF N>=256 THEN N=SASALO+N-256
220 POKE SASA-1,N:GOTO 170
300 POKE 5499,SASALO:POKE 5500,SASAHI
310 SASAHI=INT(SASA/256):SASALO=SASA-SASAHI*256
320 POKE 1804,SASALO:POKE 1805,SASAHI
330 POKE 744,INT(LOMEM/256):POKE 743,LOMEM-PEEK(744)*256:TRAP 40000
400 ? "Writing modified DOS..."
410 CLOSE #1:OPEN #1,8,0,"D1:DOS.SYS":CLOSE #1
420 ? "DOS modified!↰"
430 END
500 DATA 152,72,32,-1,-1,104,16,4,201,136,208,16
510 DATA 238,302,512,169,292,141,84,3,169,512,141,85,3,76,114,21
520 DATA 169,48,141,302,512,76,-1,-1
530 DATA 68,49,58,65,85,84,79,82,85,78,48,46,83,89,83,155
