130XE Bank Switching Demo (SLIDES.BAS)
130XE Bank Switching Demo by Bill Marquardt, 26
Description
130XE Bank Switching Demo by Bill Marquardt, 26
From the Antic disk of February 1987 (Vol. 5 No. 10).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.0 KB
- Dialect
- Atari BASIC
- Lines
- 74
- Variables
F1$,F2$,F3$,F4$,F5$,F6$,F7$,F8$,F$,PORTB,DL,MODE,BANK0,BANK1,BANK2,BANK3,I,HI,NUSCR,TIME,P,DELAY,IO,X
BASIC listing (74 lines)
100 REM 130XE BANK SWITCHING DEMO
110 REM BY BILL MARQUARDT
120 REM (c) 1987, ANTIC PUBLISHING
130 GRAPHICS 0
140 DIM F1$(15),F2$(15)
150 DIM F3$(15),F4$(15)
160 DIM F5$(15),F6$(15)
170 DIM F7$(15),F8$(15)
180 F1$="D:F1":F2$="D:F2"
190 F3$="D:F3":F4$="D:F4"
200 F5$="D:F5":F6$="D:F6"
210 F7$="D:F7":F8$="D:F8"
220 DIM F$(15)
230 GRAPHICS 15+16
240 PORTB=54017
250 DL=PEEK(560)+PEEK(561)*256
260 MODE=0
270 BANK0=0:BANK1=4
280 BANK2=8:BANK3=12
290 POKE PORTB,193+MODE+BANK0
300 POKE DL+4,16:POKE DL+5,64
310 FOR I=6 TO 196
320 POKE DL+I,14:NEXT I
330 POKE DL+107,78
340 POKE DL+108,0
350 POKE DL+109,80
360 F$=F1$:HI=64:GOSUB 740
370 F$=F2$:HI=96:GOSUB 740
380 POKE PORTB,193+MODE+BANK1
390 F$=F4$:HI=64:GOSUB 740
400 F$=F3$:HI=96:GOSUB 740
410 POKE PORTB,193+MODE+BANK2
420 F$=F5$:HI=64:GOSUB 740
430 F$=F6$:HI=96:GOSUB 740
440 POKE PORTB,193+MODE+BANK3
450 F$=F8$:HI=64:GOSUB 740
460 F$=F7$:HI=96:GOSUB 740
470 POKE PORTB,193+MODE+BANK0
480 NUSCR=16384:HI=64:GOSUB 630
490 NUSCR=NUSCR+8192
500 HI=96:GOSUB 630
510 POKE PORTB,193+MODE+BANK1
520 GOSUB 630
530 NUSCR=16384
540 HI=64:GOSUB 630
550 POKE PORTB,193+MODE+BANK2
560 GOSUB 630
570 NUSCR=NUSCR+8192
580 HI=96:GOSUB 630
590 POKE PORTB,193+MODE+BANK3
600 GOSUB 630
610 NUSCR=16384
620 HI=64:GOSUB 630:GOTO 470
630 REM SET COLOR REGISTERS
640 POKE 712,PEEK(NUSCR+7680+16)
650 POKE 708,PEEK(NUSCR+7681+16)
660 POKE 709,PEEK(NUSCR+7682+16)
670 POKE 710,PEEK(NUSCR+7683+16)
680 POKE DL+5,HI
690 POKE DL+109,HI+16
700 TIME=100:P=PADDLE(0)
710 IF P<>228 THEN TIME=P*10
720 FOR DELAY=1 TO TIME:NEXT DELAY
730 RETURN
740 IO=848:REM FILE LOADER
750 OPEN #1,4,0,F$
760 POKE IO+2,7
770 POKE IO+4,16
780 POKE IO+5,HI
790 POKE IO+8,4
800 POKE IO+9,30
810 X=USR(ADR("hhh*LVd"),16)
820 CLOSE #1
830 RETURN
