The San Francisco Fogger, text analyzer (FOGGER.BAS)
The San Francisco Fogger, text analyzer by Charles Jackson, 39
Description
The San Francisco Fogger, text analyzer by Charles Jackson, 39
From the Antic disk of February 1987 (Vol. 5 No. 10).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 4.8 KB
- Dialect
- Atari BASIC
- Lines
- 123
- Variables
DEBUG,FN$,WORD$,T$,PERIOD,QMARK,EXCLAM,SEMI,WCOUNT,TOTSYL,TRISYL,SENTENCE,PRNTFLG,LTTR,LSAFE,PERFLAG,OFFSET,ATEST,LAST,NUMSYL,FOGFLAG,FINDVOW,VOWTEST,X,M,VTEST,PV,XIT,WPSENT,SYL3SENT,FOG,SMOG,FLESCH
BASIC listing (123 lines)
10 REM THE SAN FRANCISCO FOGGER
20 REM BY CHARLES JACKSON
30 REM (c) 1987, ANTIC PUBLISHING INC.
40 DEBUG=0:IF PEEK(53279)=5 THEN DEBUG=1
50 DIM FN$(18),WORD$(40),T$(2)
60 PERIOD=46:QMARK=63:EXCLAM=33:SEMI=59
70 WCOUNT=0:TOTSYL=0:TRISYL=0:SENTENCE=0
80 GRAPHICS 0:POKE 710,144:POKE 712,144:? " The San Francisco Fogger"
90 ? " by Charles Jackson"
100 TRAP 100:POSITION 2,9:? "↑File to process";:INPUT FN$
110 IF LEN(FN$)>3 THEN IF FN$(1,1)="D" AND (FN$(2,2)=":" OR FN$(3,3)=":") THEN 130
120 WORD$=FN$:FN$="D1:":FN$(4)=WORD$
130 POSITION 2,11:? "↑Hard copy (Y/N) Y←←";:INPUT T$:IF NOT (T$="Y" OR T$="N") THEN 130
140 PRNTFLG=(T$="Y"):POKE 752,1
150 CLOSE #1:OPEN #1,4,0,FN$:POSITION 2,9:? "↑↑↑↑Processing ";FN$
160 GET #1,LTTR:GOSUB 490:LSAFE=LTTR
170 POKE 77,0:IF NOT DEBUG THEN POKE 16,112:POKE 53774,112
180 GOSUB 460:IF (PERFLAG) THEN 320
190 WORD$="":OFFSET=1:TRAP 1010
200 IF NOT (ATEST) THEN 160
210 REM
220 WORD$(OFFSET,OFFSET)=CHR$(LTTR):OFFSET=OFFSET+1
230 GET #1,LTTR:GOSUB 490:LSAFE=LTTR
240 GOSUB 460:IF (PERFLAG) THEN 320
250 IF (ATEST) THEN WORD$(OFFSET,OFFSET)=CHR$(LTTR):OFFSET=OFFSET+1:GOTO 230
260 REM
270 POKE 53279,7:IF DEBUG THEN ? WORD$,
280 WCOUNT=WCOUNT+1:LAST=LEN(WORD$):GOSUB 520:TOTSYL=TOTSYL+NUMSYL:LTTR=LSAFE
290 IF NUMSYL-FOGFLAG>2 THEN TRISYL=TRISYL+1
300 GOTO 160
310 REM
320 IF LTTR=PERIOD THEN GOSUB 430
330 IF NOT ((LTTR=46 AND FINDVOW=1) OR (LTTR=33 OR LTTR=63 OR LTTR=59) AND LEN(WORD$)>1) THEN 360
340 SENTENCE=SENTENCE+1:GOTO 270
350 REM
360 WCOUNT=WCOUNT+1:POKE 53279,7:IF DEBUG THEN ? WORD$,:? 1
370 GOTO 160
380 REM
390 REM IS (LTTR) A VOWEL?
400 VOWTEST=(LTTR=65) OR (LTTR=69) OR (LTTR=73) OR (LTTR=79) OR (LTTR=85) OR (LTTR=89)
410 LTTR=LSAFE:RETURN
420 REM
430 FINDVOW=0:FOR X=1 TO LEN(WORD$):LTTR=ASC(WORD$(X,X)):GOSUB 400:IF VOWTEST=1 THEN FINDVOW=1
440 NEXT X:LTTR=LSAFE:RETURN
450 REM
460 ATEST=((LTTR>=65 AND LTTR<=90) OR (LTTR>=48 AND LTTR<=57)):RETURN
470 REM
480 REM POP EVERYTHING INTO UPPER-CASE AND CHECK FOR ! . ? AND ;
490 LTTR=USR(ADR("hhhIA♣▕)_┐T)♥┐U◆"),LTTR)
500 PERFLAG=(LTTR=46) OR (LTTR=33) OR (LTTR=63) OR (LTTR=59):RETURN
510 REM
520 FOGFLAG=0:NUMSYL=0
530 TRAP 40000
540 M=1:WORD$(LAST+1,LAST+1)=" "
550 IF M=LAST THEN 600
560 LTTR=ASC(WORD$(M,M)):GOSUB 400:VTEST=VOWTEST
570 LTTR=ASC(WORD$(M+1,M+1)):GOSUB 400
580 IF (VTEST=1 AND VOWTEST=0) THEN NUMSYL=NUMSYL+1
590 M=M+1:GOTO 550
600 IF LAST>3 THEN LTTR=ASC(WORD$(LAST,LAST)):GOSUB 400:NUMSYL=NUMSYL+VOWTEST
610 REM
620 IF NUMSYL=0 THEN NUMSYL=1
630 IF LAST<4 THEN 690
640 LTTR=ASC(WORD$(LAST-1,LAST-1)):GOSUB 400:IF NOT (VOWTEST=0 AND WORD$(LAST,LAST)="E") THEN 660
650 NUMSYL=NUMSYL-1:IF WORD$(LAST-1,LAST-1)="L" THEN GOSUB 720
660 LTTR=ASC(WORD$(LAST-2,LAST-2)):GOSUB 400
670 IF VOWTEST=0 AND (WORD$(LAST-1,LAST)="ED" OR WORD$(LAST-1,LAST)="ES") THEN GOSUB 760
680 GOSUB 890:REM IO, YI/IA RULE
690 IF DEBUG THEN ? NUMSYL
700 RETURN
710 REM LE_RULE
720 LTTR=ASC(WORD$(LAST-2,LAST-2)):T$=CHR$(LTTR):GOSUB 400
730 IF VOWTEST=1 OR LAST<3 THEN 750
740 IF NOT (T$="L" OR T$="R" OR T$="S") THEN NUMSYL=NUMSYL+1
750 RETURN
760 IF WORD$(LAST,LAST)<>"S" THEN 820
770 T$=WORD$(LAST-2,LAST-2)
780 NUMSYL=NUMSYL-( NOT (T$="C" OR T$="G" OR T$="H" OR T$="S" OR T$="X" OR T$="Z"))
790 IF LAST<5 THEN 820
800 T$=WORD$(LAST-3,LAST-3):LTTR=ASC(T$):GOSUB 400:T$=WORD$(LAST-2,LAST-2)
810 FOGFLAG=(VOWTEST=0 AND T$="L"):NUMSYL=NUMSYL+FOGFLAG
820 IF WORD$(LAST,LAST)<>"D" THEN 860
830 T$=WORD$(LAST-2,LAST-2)
840 IF NOT (T$="D" OR T$="T") THEN NUMSYL=NUMSYL-1:GOTO 860
850 FOGFLAG=1
860 LTTR=ASC(WORD$(LAST-3,LAST-3)):GOSUB 400
870 NUMSYL=NUMSYL+(VOWTEST=0 AND WORD$(LAST-2,LAST)="LED")
880 RETURN
890 M=1
900 T$=WORD$(M,M+1):IF M=LAST THEN 1000
910 IF NOT (T$="IO") THEN 980
920 IF M=1 THEN NUMSYL=NUMSYL+1:GOTO 1000
930 PV=ASC(WORD$(M-1,M-1)):XIT=0
940 IF NOT (PV=71 OR (PV>75 AND PV<79) OR PV=83 OR PV=84 OR PV=88 OR PV=90) THEN 970
950 IF CHR$(PV)<>"L" THEN XIT=1
960 IF M>2 THEN IF WORD$(M-2,M-1)="LL" THEN NUMSYL=NUMSYL-1
970 IF XIT=0 THEN NUMSYL=NUMSYL+1
980 IF T$="IA" OR T$="YI" THEN NUMSYL=NUMSYL+1
990 M=M+1:GOTO 900
1000 RETURN
1010 IF SENTENCE=0 THEN SENTENCE=1
1020 IF WCOUNT=0 THEN WCOUNT=1
1030 WPSENT=WCOUNT/SENTENCE
1040 SYL3SENT=TRISYL/SENTENCE
1050 FOG=(WPSENT+SYL3SENT)*0.4+5E-03
1060 FOG=INT(FOG*100)/100
1070 SMOG=SQR(30*SYL3SENT)+3
1080 SMOG=INT(SMOG*100)/100
1090 FLESCH=206-((WPSENT*1.015)+(0.846*(100*TOTSYL)/WCOUNT))
1100 FLESCH=INT(FLESCH*100)/100
1110 IF FLESCH<0 THEN FLESCH=0
1120 IF FLESCH>100 THEN FLESCH=100
1130 POSITION 2,9:? "↑":POSITION 2,4:? FN$:?
1140 ? :? " Fog =":POSITION (27-LEN(STR$(FOG))),7:? FOG
1150 ? :? " Smog =":POSITION (27-LEN(STR$(SMOG))),9:? SMOG
1160 ? :? " Flesch =":POSITION (27-LEN(STR$(FLESCH))),11:? FLESCH
1170 ? :? :? " Word Count =":POSITION (27-LEN(STR$(WCOUNT))),14:? WCOUNT
1180 ? :? " Sentence Count =":POSITION (27-LEN(STR$(SENTENCE))),16:? SENTENCE:? :?
1190 TRAP 40000:IF NOT (PRNTFLG) THEN 1230
1200 LPRINT "The San Francisco Fogger":LPRINT :LPRINT FN$:LPRINT
1210 LPRINT "Fog = ";FOG:LPRINT "Smog = ";SMOG:LPRINT "Flesch = ";FLESCH:LPRINT
1220 LPRINT "Word Count = ";WCOUNT:LPRINT "Sentence Count = ";SENTENCE:LPRINT "*------------------*":LPRINT
1230 POKE 752,0
