Door Prize (with talking version) (DOORPRIZ.BAS)
Door Prize (with talking version) by Bill Marquardt, 59
Description
Door Prize (with talking version) by Bill Marquardt, 59
From the Antic disk of January 1987 (Vol. 5 No. 9).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.2 KB
- Dialect
- Atari BASIC
- Lines
- 95
- Variables
BRK,A$,B$,NUM$,X(,BASE,I,P0BASE,P1BASE,P2BASE,P3BASE,DL,W,J,P,START,LO,HI,X,Y
BASIC listing (95 lines)
10 REM DOOR PRIZE
20 REM BY BILL MARQUARDT
30 REM (c) 1986, ANTIC PUBLISHING
32 BRK=1:IF PEEK(53279)=5 THEN BRK=0
33 GOTO 100
35 POKE 77,0:IF BRK THEN POKE 16,112:POKE 53774,112
36 RETURN
100 DIM A$(38),B$(1),NUM$(4),X(3)
140 POKE 53251,90:POKE 53250,110
150 POKE 53249,130:POKE 53248,150
170 POKE 53256,1:POKE 53257,1
180 POKE 53258,1:POKE 53259,1
196 POKE 623,4:GOSUB 900
200 BASE=PEEK(106)-4:POKE 106,BASE
210 GRAPHICS 3+16:POKE 559,46
215 FOR I=704 TO 710:POKE I,0:NEXT I
220 GOSUB 35:POKE 708,0
240 POKE 54279,BASE
250 POKE 53277,3:GOSUB 2000
260 P0BASE=BASE*256+512
270 P1BASE=P0BASE+128:P2BASE=P0BASE+256:P3BASE=P0BASE+384
290 FOR I=0 TO 511:POKE P0BASE+I,0
310 NEXT I
320 DL=PEEK(560)+256*PEEK(561)
330 POKE DL+8,7:POKE DL+9,6
336 POKE DL+10,7
340 W=PEEK(88)+256*PEEK(89)
350 READ A$:FOR I=1 TO 14:B$=A$(I,I)
354 POKE W+I+32,ASC(B$)-32:NEXT I
358 READ A$:FOR I=1 TO 8:B$=A$(I,I)
360 POKE W+I+55,ASC(B$)+64:NEXT I
362 READ A$:FOR I=1 TO 10:B$=A$(I,I)
364 POKE W+I+74,ASC(B$)-32:NEXT I
366 DATA ANTIC MAGAZINE,presents
369 DATA DOOR PRIZE
370 FOR I=704 TO 707:POKE I,15:NEXT I:POKE 708,40:POKE 709,72:POKE 710,148:GOSUB 800
380 GOSUB 960:GOSUB 400:GOSUB 500:GOSUB 600:GOSUB 700
395 POKE 764,255
396 IF PEEK(764)=255 AND STRIG(0) THEN 396
397 GOTO 370
400 FOR J=0 TO X(3)
401 SOUND 0,1,0,14:SOUND 0,0,0,0
403 FOR I=73 TO 80
405 P=255-PEEK(START+J*8+I-72)
410 POKE P0BASE+I,P:POKE P1BASE+I,P
412 POKE P2BASE+I,P:POKE P3BASE+I,P
421 NEXT I:NEXT J:RETURN
500 FOR J=0 TO X(2)
502 SOUND 0,25,10,10:SOUND 0,0,0,0
503 FOR I=73 TO 80
505 P=255-PEEK(START+J*8+I-72)
510 POKE P0BASE+I,P:POKE P1BASE+I,P
512 POKE P2BASE+I,P
521 NEXT I:NEXT J:RETURN
600 FOR J=0 TO X(1)
601 SOUND 0,25,10,10:SOUND 0,0,0,0
603 FOR I=73 TO 80
605 P=255-PEEK(START+J*8+I-72)
610 POKE P0BASE+I,P:POKE P1BASE+I,P
621 NEXT I:NEXT J:RETURN
700 FOR J=0 TO X(0)
701 SOUND 0,25,10,10:SOUND 0,0,0,0
703 FOR I=73 TO 80
705 P=255-PEEK(START+J*8+I-72)
710 POKE P0BASE+I,P
721 NEXT I:NEXT J:RETURN
800 START=PEEK(756)*256+128
810 FOR I=0 TO 7
820 P=255-PEEK(START+I)
830 POKE P0BASE+72+I,P
840 POKE P1BASE+72+I,P
850 POKE P2BASE+72+I,P
860 POKE P3BASE+72+I,P
870 NEXT I:RETURN
900 GRAPHICS 0:GOSUB 35
915 TRAP 915:POSITION 2,9
920 ? "Enter LOWEST possible winning number."
921 POSITION 18,12:? "▔▔▔▔":REM ^M
923 POSITION 17,11:? " "
927 POSITION 17,11:INPUT LO
929 IF LO<0 OR LO>9999 THEN 923
930 POSITION 1,9
931 ? "Enter HIGHEST possible winning number."
932 TRAP 932
933 POSITION 17,11:? " "
935 POSITION 17,11:INPUT HI
950 IF HI>9999 OR HI<=LO THEN 933
952 TRAP 40000
955 RETURN
960 X=INT(RND(0)*(HI-LO+1))+LO:NUM$="0000"
970 IF X>0 THEN NUM$(4-INT(CLOG(X)),4)=STR$(X)
985 FOR Y=0 TO 3:X(Y)=VAL(NUM$(4-Y,4-Y)):NEXT Y:RETURN
2000 COLOR 1:PLOT 9,14:DRAWTO 30,14
2010 DRAWTO 30,17:DRAWTO 9,17
2020 DRAWTO 9,14:RETURN
