Stepper Motor Driver Program (STEPPER.BAS)

Stepper Motor Driver Program by Scott Kilbourne, Bill Hall and Jon Holcomb, 51

Description

Stepper Motor Driver Program by Scott Kilbourne, Bill Hall and Jon Holcomb, 51

From the Antic disk of December 1986 (Vol. 5 No. 8).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 6.2 KB

Dialect
Atari BASIC
Lines
183
Variables
BRK, ANS, TP, L, P, R, A, B, C, D, E, F, G, H, PORTA, PACTL, CONSOL, TXTROW, TXTCOL, BL$, DELAY, S, PAUSE, Q, WLOOP, X, DUR, LO, HI, NT, TIME, WT
BASIC listing (183 lines)
10 REM STEPPER MOTOR DRIVER PROGRAM
20 REM BY SCOTT KILBOURNE, BILL HALL         AND JON HOLCOMB
30 REM (c) 1986, ANTIC PUBLISHING
40 BRK=1:IF PEEK(53279)=5 THEN BRK=0
50 GOTO 150
60 REM GET ANSWER ROUTINE
70 TRAP 350:CLOSE #1:OPEN #1,4,0,"K:":GOSUB 1730:GET #1,ANS:CLOSE #1
80 IF ANS<48 OR ANS>57 THEN 70
90 RETURN
100 REM REFRESH CURRENT SETTINGS
110 POKE 752,1:POSITION 0,0:? "    ╱▔▔▔▔▔▔▔▔╲    TOP-----";TP:? "    ▎DISPLAY ▕    BOTTOM--";L
120 ? "    ▎SETTINGS▕    PRESENT-";P:? "    ╲▂▂▂▂▂▂▂▂╱    SPEED---";R;
130 RETURN
140 REM INITIALIZE ALL VARIABLES
150 A=5:REM STEP 1 PHASE
160 B=6:REM STEP 2 PHASES
170 C=10:REM STEP 3 PHASES
180 D=9:REM STEP 4 PHASES
190 E=7:REM HALFSTEP BETWEEN PHASES 1 AND 2
200 F=14:REM HALFSTEP PHASES 2 AND 3
210 G=11:REM HALFSTEP PHASES 3 AND 4
220 H=13:REM HALFSTEP PHASES 4 AND 1
230 PORTA=54016:REM JOYSTICK PORT 1
240 PACTL=54018:REM PORTA CONTROLLER
250 CONSOL=53279:REM CONSOLE KEYS
260 TXTROW=656:TXTCOL=657
270 DIM BL$(120):BL$=" ":BL$(120)=BL$:BL$(2)=BL$
280 DELAY=5:REM DELAY VALUE
290 TP=100:REM TOP VALUE TO MOVE TO
300 L=100:REM LOWEST VALUE TO MOVE TO
310 POKE PACTL,56:POKE PORTA,255:POKE PACTL,60
320 P=L
330 GOSUB 1540
340 REM MAIN PROGRAM
350 REM MASTER MENU
360 DELAY=50:R=50:GRAPHICS 1:POKE 710,0:GOSUB 110:GOSUB 1730
370 POSITION 0,0:? #6;"master menu"
380 ? #6
390 POKE PORTA,255:REM TURNS OFF ALL PHASES
400 ? #6;"1-SET TOP OF TRAVEL"
410 ? #6;"2-SET BOTTOM "
420 ? #6;"3-PROGRAMMED MOVE"
430 ? #6;"4-SET SPEED"
440 ? #6;"5-GO UP FAST"
450 ? #6;"6-GO DOWN FAST"
460 ? #6;"7-MOVE TO TOP"
470 ? #6;"8-MOVE TO BOTTOM"
480 ? #6;"▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔▔"
490 POSITION 0,11:? #6;BL$
500 POSITION 0,12:? #6;" your choice";CHR$(159)
510 GOSUB 70:REM GET ANSWER
520 TRAP 350:IF ANS<49 OR ANS>56 THEN 350
530 POSITION 1,ANS-47:? #6;CHR$(30)
540 S=ANS-48:ON S GOSUB 560,660,750,930,1020,1120,1290,1400
550 GOTO 370
560 POSITION 0,11:? #6;"start=move stage up":? #6;"stage continues up  as you hold start."
570 IF PEEK(CONSOL)<>6 THEN 570
580 ? #6:? #6;"select=menu";
590 POKE PACTL,56:POKE PORTA,255:POKE PACTL,60
600 POKE PORTA,D:POKE CONSOL,7
610 POKE PORTA,C:POKE PORTA,B:POKE PORTA,A:P=P+1
620 POKE TXTROW,0:POKE TXTCOL,28:? P;" ":POKE TXTROW,2:POKE TXTCOL,28:? P;" ";
630 IF PEEK(CONSOL)=6 THEN 600
640 IF PEEK(CONSOL)=5 THEN 370
650 TP=P:GOTO 630
660 POSITION 0,11:? #6;"start=move stage dn":? #6;"stage continues downas you hold start"
670 IF PEEK(CONSOL)<>6 THEN 670
680 ? #6:? #6;"select=menu"
690 POKE PORTA,A:POKE CONSOL,7
700 POKE PORTA,B:POKE PORTA,C:POKE PORTA,D:P=P-1
710 POKE TXTROW,1:POKE TXTCOL,28:? P;" ":POKE TXTROW,2:POKE TXTCOL,28:? P;" ";
720 IF PEEK(CONSOL)=6 THEN 690
730 IF PEEK(CONSOL)=5 THEN RETURN
740 L=P:GOTO 720
750 POSITION 0,12:? #6;"start=begin move     ":REM MOVE BOTTOM TO TOP
760 IF PEEK(CONSOL)<>6 THEN 760
770 ? #6:? #6;"press SELECT to quit"
780 IF P=TP THEN 910
790 POKE PORTA,H:GOSUB 1510
800 POKE PORTA,D:GOSUB 1510
810 POKE PORTA,G:GOSUB 1510
820 POKE PORTA,C:GOSUB 1510
830 IF PEEK(CONSOL)=5 THEN 920:REM LEAVE SUBROUTINE
840 POKE PORTA,F:GOSUB 1510
850 POKE PORTA,B:GOSUB 1510
860 POKE PORTA,E:GOSUB 1510
870 POKE PORTA,A:GOSUB 1510
880 P=P+1+((P>TP)*-2)
890 POKE TXTROW,2:POKE TXTCOL,28:? P;" ";:POKE CONSOL,7
900 IF P<>TP THEN 780
910 GOSUB 1750:POSITION 0,15:? #6;"move done!               ":FOR PAUSE=1 TO 150:NEXT PAUSE:GOSUB 1730
920 RETURN
930 POSITION 0,12:? #6;"choose speed       ":REM SET SPEED OF TRAVEL
940 ? #6:? #6;"10=slow  99=fast"
950 GOSUB 70
960 R=ANS-48:? #6:? #6;R;
970 GOSUB 70
980 ? #6;ANS-48:R=R*10+(ANS-48)
990 POKE TXTROW,3:POKE TXTCOL,28:? R;" ";
1000 DELAY=100-R
1010 RETURN
1020 POSITION 0,12:? #6;"start=up      ":REM GO UP FAST
1030 IF PEEK(CONSOL)<>6 THEN 1030
1040 POKE PORTA,D:POKE CONSOL,7
1050 POKE PORTA,C
1060 POKE PORTA,B
1070 POKE PORTA,A
1080 P=P+1
1090 POKE TXTROW,2:POKE TXTCOL,28:? P;" ";
1100 IF PEEK(CONSOL)=6 THEN 1040
1110 RETURN
1120 POSITION 0,12:? #6;"start=down     ":REM GO DOWN FAST
1130 IF PEEK(CONSOL)<>6 THEN 1130
1140 POKE PORTA,A:POKE CONSOL,7
1150 POKE PORTA,B
1160 POKE PORTA,C
1170 POKE PORTA,D
1180 P=P-1
1190 POKE TXTROW,2:POKE TXTCOL,28:? P;" ";
1200 IF PEEK(CONSOL)=6 THEN 1140
1210 RETURN
1220 REM DISPLAY SETTINGS
1230 POSITION 12,0:? TP;:POSITION 12,1:? L;:POSITION 12,2:? P;
1240 POSITION 12,3:? R;:RETURN
1250 POKE PORTA,255:REM TURN OFF ALL THE PHASES
1260 ? "PRESS START TO KEEP RUNNING,"
1270 IF PEEK(CONSOL)<>6 THEN 1270
1280 GOTO 370
1290 POSITION 0,12:? #6;"working...         ":REM MOVE TO TOP
1300 IF P=TP THEN 1380
1310 POKE PORTA,D:POKE CONSOL,7
1320 POKE PORTA,C
1330 POKE PORTA,B
1340 POKE PORTA,A
1350 P=P+1+((P>TP)*-2)
1360 POKE TXTROW,2:POKE TXTCOL,28:? P;" ";
1370 IF P<>TP THEN 1300
1380 ? #6:? #6;"move done         ":FOR PAUSE=1 TO 150:NEXT PAUSE
1390 RETURN
1400 POSITION 0,12:? #6;"working...             "
1410 IF P=L THEN 1490
1420 POKE PORTA,A:POKE CONSOL,7
1430 POKE PORTA,B
1440 POKE PORTA,C
1450 POKE PORTA,D
1460 P=P-1+((P<L)*2)
1470 POKE TXTROW,2:POKE TXTCOL,28:? P;" ";
1480 IF P<>L THEN 1410
1490 ? #6;"move done         ":FOR PAUSE=1 TO 150:NEXT PAUSE
1500 RETURN
1510 FOR Q=1 TO DELAY
1520 IF PEEK(CONSOL)=6 THEN WLOOP=2
1530 NEXT Q:GOSUB 1730:RETURN
1540 GRAPHICS 17:REM TITLE SCREEN
1550 FOR X=1 TO 3:? #6;"       ":NEXT X
1560 ? #6;"   ◣*◣*◣*◣*◣*◣*◣*"
1570 ? #6;"   * microscope ◣"
1580 ? #6;"   ◣stage driver*"
1590 ? #6;"   *◣*◣*◣*◣*◣*◣*◣"
1600 FOR X=1 TO 5:? #6;" ":NEXT X
1610 ? #6;"":? #6;"":? #6;" "
1620 ? #6;"         BY"
1630 ? #6;"  SCOTT KILBOURNE"
1640 ? #6;"    WILLIAM HALL"
1650 ? #6;"    JON HOLCOMB"
1660 ? #6;"":? #6;"◢c▗┌▌┴▎▘ antic"
1670 ? #6;""
1680 ? #6;"←←←←←←←←←PRESS START";
1690 FOR WLOOP=0 TO 1 STEP 0
1700 GOSUB 1710:NEXT WLOOP:RETURN
1710 POKE 708,0:POKE 709,15:GOSUB 1510
1720 POKE 708,15:POKE 709,0:GOSUB 1510:RETURN
1730 POKE 77,0:POKE 764,255:IF BRK THEN POKE 16,64:POKE 53774,64
1740 RETURN
1750 DUR=1:LO=57:HI=45:NT=HI
1760 FOR TIME=0 TO DUR*2
1770 SOUND 0,NT,10,14
1780 FOR WT=1 TO 18
1790 IF PEEK(CONSOL)=6 THEN WLOOP=1
1800 NEXT WT
1810 NT=LO:LO=HI:HI=NT
1820 NEXT TIME
1830 SOUND 0,0,0,0:RETURN