Spell Blaster (SPELLB.BAS)

Spell Blaster, game by Matthew Ratcliff, 88

Description

Spell Blaster, game by Matthew Ratcliff, 88

From the Antic disk of December 1986 (Vol. 5 No. 8).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 10.7 KB

Dialect
Atari BASIC
Lines
280
Variables
A$, B$, AD, BD, C0, C1, C2, C3, C4, C5, C6, C8, C9, C10, C15, C50, C255, CGET, C127, C256, C$, CD, I, X, B, A, CR(, ALPH(, LW, C, WORD$, PASS, KEY, DED, SPELL, SEL, DISP, Y, K, TRG0, STK0, S0, W, RD, BLANK$, GUES, OK, SCR, TGES, HSCR, BLNK, LINES, TOK, BGR, L, TW, LINE, BEGLIN, CC, J, AV, S, CONSOL, TOPICS, STKA, IO, IOCB, CMND, ADRHI, ADDRESS, ADRLO, NMHI, NMBR, NMLO, ERR
BASIC listing (280 lines)
2 REM SPELL BLASTER
3 REM BY MATTHEW RATCLIFF
4 REM (c) 1986, ANTIC PUBLISHING
10 GRAPHICS 23:DIM A$(410),B$(45):AD=ADR(A$):BD=ADR(B$)
19 C0=0:C1=1:C2=2:C3=3:C4=4:C5=5:C6=6:C8=8:C9=9:C10=10:C15=15:C50=50:C255=255:CGET=7:C127=127:C256=256
100 DIM C$(354):CD=ADR(C$)
110 GOSUB 5000:GOSUB 6000
170 REM TEXT
180 C0=0:RESTORE 190:FOR I=C0 TO 21:READ X:POKE 1536+I,X:NEXT I:GOTO 1000
190 DATA 169,0,133,212,162,8,70,186,144,3,24,101,187,106,102,212,202,208,243,133,213,96
200 B=C0:FOR I=C1 TO C4
210 A=INT(26*RND(C0))+C1:IF A=B THEN 210
220 B=A:CR(I)=ALPH(A):NEXT I
230 A=INT(LW*RND(C0))+C1:B=INT(C4*RND(C0))+C1:C=ASC(WORD$(A,A))
240 FOR I=C1 TO C4:IF CR(I)=C THEN 260
250 NEXT I:CR(B)=C
260 IF CR(C2)<>77 AND CR(C2)<>87 THEN GOTO 290
270 A=CR(C1):IF A<>77 AND A<>87 THEN CR(C1)=CR(C2):CR(C2)=A:GOTO 290
280 A=CR(C3):IF A<>77 AND A<>87 THEN CR(C3)=CR(C2):CR(C2)=A
290 RETURN
300 PASS=C0:POKE KEY,C255:DED=C0:COLOR C2:PLOT C50,44:PLOT 56,C50:PLOT C50,56:PLOT 44,C50:COLOR C1
310 SPELL=C0:SEL=C0:DISP=35:FOR Y=45 TO 55:PLOT 45,Y:DRAWTO 55,Y:NEXT Y
320 A=USR(CD,CR(C1),C1,47,44-DISP)
330 A=USR(CD,CR(C2),C2,C50+DISP,48)
340 A=USR(CD,CR(C3),C3,46,52+DISP)
350 A=USR(CD,CR(C4),C2,42-DISP,46)
360 IF PEEK(KEY)<>C255 THEN SPELL=C1:GET #C1,K:RETURN
370 IF  NOT PEEK(TRG0) THEN PASS=C1:RETURN
380 A=PEEK(STK0):SEL=(A=14)+C2*(A=7)+C3*(A=13)+4*(A=11)
390 IF SEL THEN RETURN
400 POKE S0,DISP*C2+40
410 DISP=DISP-C1:IF DISP>C5 THEN 320
420 FOR W=C15 TO C0 STEP -0.15
430 SOUND C0,PEEK(RD),C8,W:SETCOLOR C4,W,C10
440 NEXT W
450 SETCOLOR C4,C0,C0:DED=C1:RETURN
460 X=C8*(C10-LW):A=USR(AD,ADR(BLANK$),C,LW,C0,X):RETURN
500 COLOR C2:PLOT 97,C10:DRAWTO 97,95
510 A=USR(AD,ADR("SCR"),C6,C3,C15,112)
520 A=USR(AD,ADR("GES"),C5,C3,45,112)
530 A=USR(AD,ADR("OK"),C10,C2,65,128)
540 B$=STR$(GUES):A=USR(AD,BD,C5,LEN(B$),55,128)
550 B$=STR$(OK):A=USR(AD,BD,C10,LEN(B$),75,128)
560 B$=STR$(SCR):I=C1:Y=30:B$(LEN(B$)+C1)=" "
570 FOR X=112 TO 112+C8*(LEN(B$)-C1) STEP C8
580 A=USR(CD,ASC(B$(I,I)),C3,X,Y)
590 I=I+C1:NEXT X
595 RETURN
600 FOR I=7 TO 87 STEP C8
610 A=USR(AD,ADR("      "),C0,C6,I)
620 NEXT I
630 RETURN
640 A=USR(AD,ADR("      "),C0,C6,87,C0)
650 RETURN
1000 TRG0=644:STK0=632:KEY=764:RD=53770:TGES=C0:GUES=C0:SCR=C0:HSCR=C0:BLNK=ASC("-")
1010 DIM CR(C4),ALPH(26),WORD$(C10),BLANK$(C10):FOR I=C1 TO 26:ALPH(I)=I+64:NEXT I
1020 RESTORE 20000:READ LINES:S0=53760:OK=C0:TOK=C0:BGR=100
1030 OPEN #C1,C4,C0,"K:"
1040 GRAPHICS 23:SETCOLOR C0,C10,C10:SETCOLOR C1,12,C8:SETCOLOR C2,C4,C10
1050 B$="SPELLblast":SOUND C0,C0,C8,C10:GOSUB 6000
1060 FOR Y=C0 TO 80:A=USR(AD,BD,C5,LEN(B$),Y,C0):POKE S0,Y*2:NEXT Y
1070 FOR Y=80 TO 20 STEP -C1:A=USR(AD,BD,C15,LEN(B$),Y,C0)
1080 SOUND C0,Y,C10,C10:SOUND C1,Y+C4,C10,C10
1090 NEXT Y
1100 POKE KEY,C255
1110 A=USR(AD,ADR("FROM ANTIC"),C10,C10,C50,C0)
1120 A=USR(AD,ADR("PRESS"),C15,C5,70,40)
1130 A=USR(AD,ADR("BUTTON"),C5,C6,80,40)
1140 SOUND C0,60,C10,C5:SOUND C1,64,C10,C5
1150 FOR I=C5 TO C15 STEP C5:C=PEEK(RD)/2:POKE KEY,C255
1160 A=USR(AD,BD,I,LEN(B$),20,C0)
1170 POKE S0,C:POKE S0+C2,C5*I
1180 IF (PEEK(KEY)<>C255 OR PEEK(TRG0)=C0) THEN 1200
1190 NEXT I:GOTO 1150
1200 SOUND C0,C0,C0,C0:SOUND C1,C0,C0,C0:GRAPHICS C0:SETCOLOR C2,C15,C0:POKE 752,C1:GOSUB 6000
1210 ? :? :GOSUB 1400
1220 B$="    USE JOYSTICK TO PLAY":? :GOSUB 1400
1230 B$="POINT HANDLE IN DIRECTION":? :GOSUB 1400
1240 B$="OF LETTER THAT YOU THINK":GOSUB 1400
1250 B$="WILL FIT IN THE WORD AT TOP":GOSUB 1400
1260 B$="PRESS FIRE BUTTON TO PASS":? :GOSUB 1400
1270 B$="IF LETTERS WON'T FIT OR":GOSUB 1400
1280 B$="ARE ALREADY CHOSEN":GOSUB 1400
1290 B$="TO TRY SPELLING THE WORD, PRESS":? :GOSUB 1400
1300 B$="SPACE BAR (FOR MORE POINTS)":GOSUB 1400
1310 B$="PRESS  Q  KEY TO QUIT THE GAME":? :GOSUB 1400
1320 B$="AND SEE TOTALS":GOSUB 1400
1330 B$="PRESS  BUTTON  TO START":? :? :GOSUB 1400
1340 POKE KEY,C255
1350 IF  NOT (PEEK(KEY)<>C255 OR PEEK(TRG0)=C0) THEN 1350
1360 GOTO 2800
1400 A=38-LEN(B$):L=INT(A/C2)
1410 FOR I=C1 TO L:? " ";:NEXT I
1420 ? B$
1430 RETURN
1500 TGES=TGES+GUES:GUES=C0:TOK=TOK+OK:OK=C0:TW=TW-C1:IF TW=C0 THEN GOTO 2300
1510 LINE=INT(LINES*RND(C0))+BEGLIN:RESTORE LINE:BLANK$=WORD$
1520 A=INT(C5*RND(C0))+C1
1530 FOR I=C1 TO A:READ WORD$:NEXT I:LW=LEN(WORD$)
1540 IF BLANK$=WORD$ THEN 1510
1550 BLANK$="----------"
1560 GRAPHICS 23:SETCOLOR C0,C4,C10:SETCOLOR C1,9,C10:SETCOLOR C2,12,C10:POKE 77,C0
1570 C=C10:GOSUB 6000:GOSUB 460
1580 GOSUB 500
1590 GOSUB 200
1600 SOUND C0,C0,C8,C8:GOSUB 300
1610 IF PASS THEN GOSUB 600:GOTO 1570
1620 IF  NOT DED THEN 1750
1630 GRAPHICS 23:SETCOLOR C1,C4,C10
1640 SETCOLOR C2,9,C10:SETCOLOR C3,12,C10:GOSUB 6000
1650 BLANK$=WORD$:C=C5:GOSUB 460
1660 C=C10*LW:SCR=SCR-C
1670 A=USR(AD,ADR("LOSE"),C10,C4,40,48)
1680 B$=STR$(C):A=USR(AD,BD,C5,LEN(B$),60,C8*(C10-LEN(B$)))
1690 A=USR(AD,ADR("POINTS"),C15,C6,80,32)
1700 FOR W=C15 TO C0 STEP -0.1
1710 SOUND C0,C15*W,C6,W
1720 SOUND C1,C15*W,12,W
1730 NEXT W
1740 GOTO 1500
1750 IF  NOT SPELL THEN 2030
1760 GRAPHICS 23:SETCOLOR C1,C10,C10:SETCOLOR C2,14,C10:GOSUB 6000
1770 IF K=ASC("Q") THEN 2300
1780 POKE (KEY),C255:C=C15:GOSUB 460
1790 CC=C5:FOR I=C10 TO 82 STEP C8:A=USR(AD,ADR("          "),CC,C10,I,C0):CC=CC+C1
1792 IF CC>C15 THEN CC=C5
1794 NEXT I
1800 FOR I=C1 TO LW:A=ASC(BLANK$(I,I))
1810 IF A<>BLNK THEN 1900
1820 A=USR(AD,ADR(" "),CC,C1,C0,16*(I-C1)+X)
1830 CC=CC+C1:IF CC>C255 THEN CC=C1
1840 IF PEEK(KEY)=C255 THEN 1820
1850 SOUND C0,C0,C0,C0:SOUND C1,C0,C0,C0:GET #C1,K:IF CHR$(K)<>WORD$(I,I) THEN 1980
1860 SCR=SCR+C10:GUES=GUES+C1:BLANK$(I,I)=WORD$(I,I):OK=OK+C1
1870 FOR J=80 TO C0 STEP -C2
1880 A=USR(AD,ADR(WORD$)+I-C1,J+C5,C1,J,16*(I-C1)+X)
1890 SOUND C0,J*2,C10,C5:SOUND C1,J*2+C4,C10,C5:NEXT J
1900 SOUND C0,C0,C0,C0:SOUND C1,C0,C0,C0:NEXT I
1910 FOR I=C8 TO 88 STEP C8:A=USR(AD,ADR("          "),C0,C10,I,C0):NEXT I
1920 GOSUB 500:B$="*CORRECT*"
1930 FOR I=C1 TO LEN(B$)
1940 A=USR(CD,ASC(B$(I,I)),C1,C8*I,C4*I+20)
1950 NEXT I
1960 A=USR(AD,ADR("PRESS"),C15,C5,70,C0):A=USR(AD,ADR("A KEY"),C10,C5,80,C0)
1970 IF  NOT (PEEK(KEY)<>C255 OR PEEK(TRG0)=C0) THEN 1970
1971 IF PEEK(TRG0)=C0 THEN 1978
1975 GET #C1,A:IF A=ASC("Q") THEN 2300
1978 GOTO 1500
1980 FOR W=C15 TO C0 STEP -0.25
1990 SOUND C0,PEEK(RD),C6,W
2000 A=USR(AD,ADR("*WRONG*"),W,7,20,16)
2010 NEXT W
2020 GOTO 1560
2030 IF  NOT SEL THEN 3000
2040 ON SEL GOTO 2050,2060,2070,2080
2050 COLOR C3:PLOT C50,45:DRAWTO C50,51-DISP:GOTO 2090
2060 COLOR C1:PLOT 55,C50:DRAWTO 51+DISP,C50:GOTO 2090
2070 COLOR C2:PLOT C50,55:DRAWTO C50,51+DISP:GOTO 2090
2080 COLOR C1:PLOT 45,C50:DRAWTO 49-DISP,C50
2090 FOR W=C15 TO C0 STEP -C3
2100 A=INT(PEEK(RD)/1.25):SOUND C0,A,12,W:SOUND C1,A+C8,C8,W
2110 NEXT W
2120 B$=CHR$(CR(SEL)):C=C0:GUES=GUES+C1
2130 FOR I=C1 TO LW
2140 IF B$=BLANK$(I,I) THEN GOSUB 600:GOTO 1570
2150 IF B$<>WORD$(I,I) THEN 2180
2160 BLANK$(I,I)=WORD$(I,I):SCR=SCR+C2:C=C+C1:OK=OK+C1
2165 FOR A=40 TO 30 STEP -C2:SOUND C0,A,C10,C10:SOUND C1,A+C4,C10,C10:NEXT A
2167 SOUND C0,C0,C0,C0:SOUND C1,C0,C0,C0:C=C10:GOSUB 460
2170 IF BLANK$(C1,LW)=WORD$(C1,LW) THEN 2210
2180 NEXT I
2190 IF C=C0 THEN SCR=SCR-C2
2200 GOSUB 600:GOTO 1570
2210 GRAPHICS 23:SETCOLOR C1,C10,C10:SETCOLOR C2,14,C10:GOSUB 6000
2220 C=C5:GOSUB 460
2230 SCR=SCR+C10:GOTO 1910
2300 GRAPHICS 23:SETCOLOR C0,C4,C10:SETCOLOR C1,12,C8:SETCOLOR C2,9,C10:POKE KEY,C255:GOSUB 6000
2305 TGES=TGES+GUES:TOK=TOK+OK
2310 A=USR(AD,ADR("SPELLblast"),C5,C10,C0,C0):C=C1:CC=C1
2320 B$="Final Score ":B$(LEN(B$)+C1)=STR$(SCR):Y=C10:GOSUB 2700
2330 B$="High Score ":IF SCR>HSCR THEN HSCR=SCR
2340 B$(LEN(B$)+C1)=STR$(HSCR):Y=20:GOSUB 2700
2350 B$="Total Correct LTRS":Y=30:GOSUB 2700
2360 B$=STR$(TOK):Y=38:GOSUB 2700
2370 B$="Total Guesses":Y=C50:GOSUB 2700
2380 B$=STR$(TGES):Y=58:GOSUB 2700:IF TOK=C0 THEN TOK=C1
2390 B$="AVG of ":AV=(INT(TGES*C10/TOK))/C10
2400 IF AV<BGR THEN BGR=AV
2410 B$(LEN(B$)+C1)=STR$(AV):B$(LEN(B$)+C1)=" GES/LTR"
2420 Y=70:GOSUB 2700
2430 B$="Best AVG is ":B$(LEN(B$)+C1)=STR$(BGR):Y=80:GOSUB 2700
2440 POKE S0,PEEK(RD)
2450 IF  NOT (PEEK(KEY)<>C255 OR PEEK(TRG0)=C0) THEN 2320
2460 SOUND C0,C0,C0,C0:GOTO 2800
2700 CC=CC+C1:IF CC>C15 THEN CC=C1
2710 POKE 77,C0:A=USR(AD,ADR("SPELLblast"),CC,C10,C0,C0)
2720 L=LEN(B$):S=C8*((21-L)/C2):I=C1
2730 FOR X=S TO S+C8*(L-C1) STEP C8
2740 A=USR(CD,ASC(B$(I,I)),C,X,Y):I=I+C1
2750 SOUND C0,C5*CC+X,C10,C4:SOUND C1,C5*CC+X+C4,C10,C4
2755 IF (PEEK(KEY)<>C255 OR PEEK(TRG0)=C0) THEN RETURN
2760 NEXT X
2770 C=INT(C3*RND(C0))+C1
2780 RETURN
2800 GRAPHICS C0:POKE 752,C1:SOUND C0,C0,C0,C0:SOUND C1,C0,C0,C0:POKE 710,C0:GOSUB 6000
2810 TW=C10:SEL=C1:CONSOL=53279
2820 TOPICS=C3
2830 POKE 766,1:POSITION C2,C1:? " ← → =";TW;" WORDS/GAME BUTTON=BEGIN"
2840 POSITION C8,C3:? " ↑ ↓ =SUBJECT":POKE 766,0
2850 POSITION C6,C5:? "1. ANIMALS, FISH & FOWL"
2860 POSITION C6,C6:? "2. MUSICAL INSTRUMENTS"
2870 POSITION C6,7:? "3. COMPUTER TERMINOLOGY"
3000 POKE 766,1:POSITION C2,C1:? " ← → =";TW;" WORDS/GAME":POKE 766,0
3010 A=PEEK(CONSOL):STKA=PEEK(STK0)
3020 POSITION C4,SEL+C4:? "*";:FOR I=C1 TO C10:NEXT I:POSITION C4,SEL+C4:? " ";
3030 IF  NOT (A=C3 OR STKA=11 OR STKA=7) THEN 3070
3040 TW=TW+(4.5-STKA/2)*C5:IF TW>C50 THEN TW=C10
3045 IF TW<C10 THEN TW=C50
3050 FOR W=C15 TO C0 STEP -C1:SOUND C0,60,C10,W:NEXT W
3060 GOTO 3000
3070 IF  NOT (A=C5 OR STKA=14 OR STKA=13) THEN 3110
3080 SEL=SEL+(27-2*STKA)*C1:IF SEL>TOPICS THEN SEL=C1
3085 IF SEL<1 THEN SEL=TOPICS
3090 FOR W=C15 TO C0 STEP -C1:SOUND C0,40,C10,W:NEXT W
3100 GOTO 3000
3110 IF  NOT (A=C6 OR PEEK(TRG0)=0) THEN 3000
3120 RESTORE 20000:FOR W=C15 TO C0 STEP -C1:SOUND C0,120,C10,W:NEXT W
3130 FOR I=C1 TO SEL
3140 READ BEGLIN,LINES
3150 NEXT I
3160 TGES=C0:GUES=C0:TOK=C0:OK=C0:SCR=C0
3170 TW=TW-C1:GOTO 1500
5000 A$(1,81)="%H┐_)├┐^%T┐e%U┐c%V┐d&W)◣◆┐♣◢)●◆╲♣▕)(┐ohp0*h┐Uh┐TJp1hh┐_Jp*hh┐^Jp#hh┐eJp▎h┐dh┐cJp┼"
5010 A$(82,163)="hhJP♠┴♣▝)↰L$v)♥┐c┐d%e┐i%o┐l)♥┐f"◢◣&f╱i♣╲┴el♣▕ffJPo┐e%X┐X%Y┐Y%e┴eX┐X%feY┐Y"├%WI▗0╲""
5020 A$(164,244)="▕J0▕"┘%cedp▌FdfcJp┐FcJP♠fi┴%ceX┐X♣▕fY%X┐◆%Y┐a)♥┐b"♥)♥▄Zh%_▄Z◣◣◣◣h▄Z┐[h▄Z$b1T"♥╱jI"
5030 A$(245,326)="♥♣┤)▶Fj*┐l◆◆0▔)@◆ ♣▕)◆┴el┐l)◢┐i)♥┐W"◢◣&W╱i♣╲┴el♣▕fWJPo┐V┴-t▕eW┐W ♥┤k ◢┤n┴♣┘┴♣)$k1V"
5040 A$(327,410)="fkEj┐h)♥┐m)┤┐g)♥┐i ▕╱h&i◢Py&i5Z$m┌XfmFgPe┴%Xeo┐X♣▕fYFnPDF^P├◆fb┴%◆i┤┐◆♣▕fa┐X%a┐Y┴♣&◆"
5060 C$(1,82)="hp◣I┤p▔*hhJP♠)▎┐9L@9h┐ChI♥♣┤)▶FC*▔▎╱◆◆0▖)@◆ ♣▕)◆┴m▎╱▔▎╱hh▔┬╱hh▔┴╱I┤♣┐8i┤0w┐VI♥p╲)┤"
5062 C$(83,164)="8eV┐VN┴╱N┴╱╱V┴hh▔▌╱┐:&W)◣◆┘p◢)●◆┐p▕)(┐O┐;%X┐K%Y┐L ♥╱┴-┴╱eK┐K♣▕fL┴%KeT┐K%LeU┐L-▎╱┐;"
5064 C$(165,246)=")◢┐: ♥╱%T┐M-t▕eU┐N ♥"◢)♥┐Q┐P1MECHh◣H♣◢┴-┬╱┐P┐P◆├p◢╱P&Q╱P&QJPdh┴H ♥┤W┤T&VpX8&WJPz1K"
5066 C$(247,328)="┐WEW┌K%WI▶┐WHH1K┐WEW┌K&V╱Q&TJPy ♥┴1KeT┌K)◢8eV*┤TFPfTJPyp▕P╲ ▕┴1KeT┌K┴%PeQ ├┌K┴♣▗%Q"
5068 C$(329,354)="┌KH%P┌Kh(┴%KeO┐K♣▕fLH@◢PN◆"
5070 RETURN
6000 POKE 77,0:POKE 16,112:POKE 53774,112:RETURN
10000 DATA CAT,DOG,MOUSE,GIRAFFE,COW
10001 DATA RAT,WHALE,AARDVARK,OWL,KITTEN
10002 DATA BEAR,CUB,TIGER,PANTHER,FISH
10003 DATA ANTELOPE,ANTEATER,GOAT,RAM,OX
10004 DATA HORSE,DONKEY,MULE,LEOPARD,SNAKE
10005 DATA COBRA,FOX,ZEBRA,MOCCASIN,SWAN
10006 DATA MONKEY,CHIMPANZEE,GORILLA,MINK,CHINCHILLA
10007 DATA SKUNK,SQUIRREL,CHIPMUNK,WOODPECKER,LAMB
10008 DATA BASS,SHARK,CATFISH,BLUEGILL,TUNA
10009 DATA CHICKEN,ROOSTER,CARDINAL,BLUEJAY,SPARROW
10010 DATA THRUSH,QUAIL,YAK,PANDA,RACCOON
10011 DATA BEAVER,OSTRICH,OTTER,RHINOCEROS,RABBIT
10012 DATA DEER,MOOSE,WREN,DUCK,TURTLE
10013 DATA COUGAR,SEAL,WALRUS,PYTHON,ELEPHANT
10014 DATA PACHYDERM,JAGUAR,HYENA,KOALA,BAT
10015 DATA KANGAROO,GRIZZLY,HAMSTER,BULLFROG,TOAD
10016 DATA LIZARD,SALMON,TROUT,TUNA,MONGOOSE
10017 DATA BUFFALO,BISON,CAMEL,STEER,WEASEL
10020 DATA GUITAR,VIOLA,VIOLIN,UKELELE,PIANO
10021 DATA FLUTE,SAXOPHONE,OBOE,TROMBONE,TRUMPET
10022 DATA DRUM,BUGLE,TUBA,KETTLEDRUM,XYLOPHONE
10023 DATA ZITHER,LYRE,HARP,LUTE,CLARINET
10024 DATA PICCOLO,CELLO,ACCORDION,ALTHORN,BAGPIPE
10025 DATA BALALAIKA,BANJO,CASTANETS,CLAVICHORD,CONCERTINA
10027 DATA MANDOLIN,MARIMBA,ORGAN,HARMONICA,WOODWIND
10030 DATA BYTE,MODEM,BOOLEAN,PROGRAM,BASIC
10031 DATA ANTIC,BINARY,LOGO,EQUATION,GRAPHICS
10032 DATA ARRAY,DOS,INPUT,ROUTINE,MONITOR
10033 DATA MOUSE,PARALLEL,PRINTER,SOFTWARE,ROM
10034 DATA JOYSTICK,FORTRAN,FILE,BUFFER,ASCII
10035 DATA BOOT,SERIAL,OPUS,XMODEM,SPRITE
10036 DATA MEMORY,COMMAND,STACK,FORMAT,PARITY
10037 DATA PARSER,ENIAC,REGISTER,INTERRUPT,LOOP
19990 REM BEGINNING LINE & TOTAL LINES
19991 REM FOR EACH TOPIC START IN DATA HERE
20000 DATA 10000,18,10020,8,10030,8