graphics utility (RSMAP.BAS)
graphics utility by Jim Pierson-Perry, 60
Description
graphics utility by Jim Pierson-Perry, 60
From the Antic disk of December 1986 (Vol. 5 No. 8).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 7.3 KB
- Dialect
- Atari BASIC
- Lines
- 167
- Variables
BREAK,Z,X,Y,C5,J,C0,SY,X1,SX,B$,C1,C63,BL$,I,C2,CON,OPTION,Z1,K,Z2,SZ,CLEAR,C$,C4,C6,C(,F$,CR1,CR2,CR4,C3,C10,C67,SELECT,START,X2,Y1,Y2,ZLO,ZHI,C8,BRK,A,B,PI,E
BASIC listing (167 lines)
1000 REM RSMAP
1010 REM BY JIM PIERSON-PERRY
1020 REM (c) 1986, ANTIC PUBLISHING
1025 REM DO NOT RENUMBER THIS PROGRAM
1030 BREAK=1:IF PEEK(53279)=5 THEN BREAK=0
1040 DEG :GOTO 1240
1050 Z=SQR(X^2+Y^2)
1060 RETURN
1080 REM COMPUTE FUNCTION, PLOT MAP
1090 FOR J=C0 TO 40:Y=Y-SY:X=X1-SX:B$(C1,C63)=BL$(C1,C63):IF J/C5=INT(J/C5) THEN B$(C1,C1)="*":B$(C63,C63)="*"
1100 TRAP 2810:FOR I=C2 TO 62:X=X+SX
1110 IF PEEK(CON)=OPTION THEN POP :POP :GOTO 2410
1120 GOSUB 1050
1130 IF Z<Z1 THEN K=C1:GOTO 1160
1140 IF Z>Z2 THEN K=51:GOTO 1160
1150 K=INT((Z-Z1)/SZ)+C1
1160 TRAP CLEAR:B$(I,I)=C$(K,K):NEXT I
1165 POSITION C5,19:? " *** Plotting *** ":POKE 712,50
1170 ? #C2;B$(C1,C63);BL$(C1,C4);C$(J+C6,J+C6):GOSUB 1210:POKE 712,160
1175 POSITION C5,19:? " --- Thinking --- "
1180 NEXT J
1190 RETURN
1200 REM DISABLE BREAK KEY
1210 POKE 77,0:IF BREAK THEN POKE 16,112:POKE 53774,112
1220 RETURN
1230 REM START OF MAIN PROGRAM
1240 DIM B$(63),BL$(67),C$(51),F$(80),C(51)
1250 GRAPHICS 0:CR1=PEEK(709):CR2=PEEK(710):CR4=PEEK(712):POKE 709,172:POKE 710,160:POKE 712,160
1255 POKE 559,( NOT (BREAK))*34
1260 GOSUB 1210:C0=0:C1=1:C2=2:C3=3:C4=4:C5=5:C6=6:C10=10:C63=63:C67=67:CLEAR=40000:CON=53279
1270 OPTION=C3:SELECT=C5:START=C6:PI=3.14159:E=2.71828179:BL$(C1)=" ":BL$(C67)=" ":BL$(C2)=BL$
1280 C$="A,B.C,D.E,F.G,H.I,J.K,L.M,N.O,P.Q,R.S,T.U,V.W,X.Y,Z"
1290 POKE 752,C1
1300 REM INTRO
1310 ? "↰":POSITION C6,C4:? "┌──────────────────────────┐"
1320 POSITION C6,C5:? "| RSMAP |"
1330 POSITION C6,C6:? "| Response Surface Mapping |"
1340 POSITION C6,7:? "└──────────────────────────┘":POSITION 19,10:? "by"
1350 POSITION 11,12:? "Jim Pierson-Perry":POSITION 7,14:? "(c) 1986 Antic Publishing"
1355 POSITION 10,16:? "ALL RIGHTS RESERVED":POKE 559,34
1360 FOR I=C1 TO 700:NEXT I
1620 REM ENTER FUNCTION
1630 ? "↰":POSITION 9,C0:? " PLOT FUNCTION INPUT "
1640 POSITION C3,C2:? "Type in the plotting function. Use valid BASIC syntax. The function can"
1650 POSITION C0,C4:? "use up to 2 independent variables: X and/or Y."
1660 POSITION C3,7:? "Press BACKSPACE To Erase Typos"
1670 POSITION C3,9:? "Press RETURN When Finished"
1680 POSITION C0,13:? "Z=";:FOR I=C1 TO 78:? "_";:NEXT I
1690 POKE 752,C0:POSITION C2,13:F$="":F$(C1,C2)="Z=":I=C3
1700 CLOSE #C6:OPEN #C6,C4,C0,"K:":GOSUB 1210
1710 GET #C6,X:IF X=155 THEN CLOSE #C6:GOTO 1780
1720 IF X=126 AND I>3 THEN ? CHR$(X);"_";CHR$(30);:I=I-C1:F$(I,I)=" ":GOTO 1710
1730 IF I=81 THEN 1710
1740 IF (X>39 AND X<44) OR (X>44 AND X<58) OR (X>64 AND X<91) OR X=94 THEN 1760
1750 GOTO 1710
1760 F$(I,I)=CHR$(X):? CHR$(X);:I=I+C1:GOTO 1710
1770 REM INSTALL FUNCTION
1780 POKE 559,( NOT (BREAK))*34:POKE 752,C1:? "↰":? :? :? "1050 ";F$:?
1790 ? "CONT":POSITION C0,C0:POKE 842,13:STOP
1800 TRAP 2570:POKE 842,12:TRAP CLEAR
1810 ? "↰":POSITION 8,C0:? " PLOT PARAMETER INPUT ":POKE 559,34
1820 REM GET PLOT AXES BOUNDARIES
1830 POSITION C0,C2:? "ENTER VALUES FOR:"
1840 POSITION C3,C4:? "X-axis minimum= ";:INPUT X1
1850 POSITION C10,C5:? "maximum= ";:INPUT X2
1860 IF X2<X1 THEN GOSUB 2660:POSITION C0,C4:? BL$(C1,38):? BL$(C1,38):GOTO 1840
1870 POSITION C3,7:? "Y-axis minimum= ";:INPUT Y1
1880 POSITION C10,8:? "maximum= ";:INPUT Y2
1890 IF Y2<Y1 THEN GOSUB 2660:POSITION C0,7:? BL$(C1,38):? BL$(C1,38):GOTO 1870
1900 REM ESTIMATE RESPONSE RANGE OVER PLOT AXES
1910 POSITION C0,10:? "PLEASE WAIT- ESTIMATING RESPONSE RANGE"
1920 SX=(X2-X1)/C10:SY=(Y2-Y1)/C10:TRAP 2810
1930 X=X1:Y=Y1
1940 GOSUB 1050
1950 ZLO=Z:ZHI=Z
1960 FOR Y=Y1 TO Y2 STEP SY
1970 FOR X=X1 TO X2 STEP SX
1980 GOSUB 1050
1990 IF Z<ZLO THEN ZLO=Z
2000 IF Z>ZHI THEN ZHI=Z
2010 NEXT X
2020 NEXT Y
2030 TRAP CLEAR
2040 POSITION C0,C10:? BL$(C1,38):POSITION C0,C10:? "ESTIMATED RESPONSE (Z) RANGE:"
2050 POSITION C3,11:? "Z mimimum= ";ZLO
2060 POSITION C5,12:? "maximum= ";ZHI
2070 POSITION C0,20:? "Press START To Use These Values"
2080 POSITION C0,21:? "Press OPTION To Enter Response Range"
2090 IF PEEK(CON)=START THEN Z1=ZLO:Z2=ZHI:GOTO 2170
2100 IF PEEK(CON)=OPTION THEN 2120
2110 GOTO 2090
2120 FOR I=C10 TO 21:POSITION C0,I:? BL$(C1,39):NEXT I
2130 POSITION 8,C10:? "Z minimum= ";:INPUT Z1
2140 POSITION C10,11:? "maximum= ";:INPUT Z2
2150 IF Z2<Z1 THEN GOSUB 2660:POSITION C0,C10:? BL$(C1,38):? BL$(C1,38):GOTO 2130
2160 REM SET PRINTER - START MAPPING
2170 ? "↰":POSITION C5,C0:? " RESPONSE SURFACE MAP OUTPUT ":POKE CON,7
2180 POSITION 9,C2:? "Prepare your printer:"
2190 POSITION C10,C4:? "-Power on"
2200 POSITION C10,C6:? "-Set paper at top of page":GOSUB 1210
2210 POSITION C5,20:? "Press START to continue."
2220 POSITION C5,21:? "Press OPTION to abort."
2230 IF PEEK(CON)<>START THEN 2230
2240 TRAP 2720:CLOSE #C2:OPEN #C2,C8,C0,"P:":TRAP CLEAR
2250 POSITION C5,19:? " *** Plotting *** "
2251 POSITION C5,20:? " "
2260 SX=(X2-X1)/60:SY=(Y2-Y1)/40:SZ=(Z2-Z1)/50:C(C1)=Z1
2270 FOR I=C2 TO 51:C(I)=C(I-C1)+SZ:NEXT I
2280 TRAP 2720:? #C2:? #C2:I=40-LEN(F$)/C2:? #C2;BL$(C1,I);F$:? #C2:? #C2:TRAP CLEAR
2290 ? #C2:? #C2:? #C2;BL$(C1,15);"X-axis range= ";X1;" to ";X2
2300 ? #C2;BL$(C1,15);"Y-axis range= ";Y1;" to ";Y2
2310 FOR I=C1 TO C4:? #C2;BL$(C1,C67);C$(I,I);"=";C(I):NEXT I
2320 B$(C1,C63)=BL$(C1,C63):FOR I=C2 TO 62 STEP C5:B$(I,I)="*":NEXT I
2330 ? #C2;B$(C1,62);BL$(C1,C5);C$(C5,C5);"=";C(C5)
2340 REM
2350 Y=Y2+SY
2360 REM CALL THE MAPPING SUBROUTINE
2370 POSITION C5,19:? " --- Thinking --- ":GOSUB 1090
2380 B$(C1,C63)=BL$(C1,C63):FOR I=C2 TO 62 STEP C5:B$(I,I)="*":NEXT I
2390 ? #C2;B$(C1,62);BL$(C1,C5);C$(47,47);"=";C(47)
2400 FOR I=48 TO 51:? #C2;BL$(C1,C67);C$(I,I);"=";C(I):NEXT I
2410 ? #C2;CHR$(12):CLOSE #C2
2420 REM MAP COMPLETE - ALLOW RERUNS
2430 ? "↰":POSITION C5,C0:? " RESPONSE SURFACE MAP OUTPUT "
2440 POSITION C5,C3:? "Response Map Output Completed"
2450 POSITION 15,C6:? " OPTIONS: ":POSITION 15,7:? "=========="
2460 POSITION C5,9:? " START - Remap same function with":POSITION 15,10:? "new plot parameters"
2470 POSITION C5,12:? " OPTION - Exit program"
2480 POSITION 7,15:? "Please Make Your Selection"
2490 IF PEEK(CON)=OPTION THEN 2530
2500 IF PEEK(CON)=START THEN 1810
2510 GOTO 2490
2520 REM ALL DONE - EXIT TO BASIC
2530 GRAPHICS 0:POKE 709,CR1:POKE 710,CR2:POKE 712,CR4:POKE 82,C2:POKE 752,C0
2550 ? "Program RSMAP done.":END
2560 REM HANDLE BASIC SYNTAX ERRORS IN THE PLOT FUNCTION
2570 ? "↰":GOSUB 2860
2580 POSITION 8,C5:? "There is a syntax error":POSITION 7,7:? "in your plotting function."
2590 POSITION 12,C10:? "BASIC Error #";PEEK(195)
2600 POSITION C5,20:? "Press START To Re-enter Function"
2610 POSITION C5,21:? "Press OPTION To Exit Program"
2620 IF PEEK(CON)=START THEN POKE 712,160:GOTO 1630
2630 IF PEEK(CON)=OPTION THEN POKE 712,160:GOTO 2530
2640 GOTO 2620
2650 REM ERROR HANDLING CODE TO HANDLE UNREAL PLOT AXIS BOUNDS (MINIMUM GREATER THAN MAXIMUM)
2660 GOSUB 2860
2670 POSITION C0,20:? "The minimum must be less"
2680 POSITION C0,21:? "than the maximum value. Try again.↰↰↰"
2690 FOR I=C1 TO 300:NEXT I:POSITION C0,20:? BL$(C1,38):? BL$(C1,38)
2700 POKE 712,160:RETURN
2710 REM HANDLE PRINTER ERRORS
2720 GOSUB 2860
2730 POSITION 9,C10:? "Printer Error Detected":POSITION 11,12:? "BASIC Error #";PEEK(195)
2740 POSITION 13,14:? "Please Correct"
2750 IF PEEK(CON)=OPTION THEN POKE 712,160:GOTO 2530
2760 IF PEEK(CON)=START THEN 2780
2770 GOTO 2750
2780 FOR I=C10 TO 14:POSITION C0,I:? BL$(C1,38):NEXT I
2790 POKE 712,160:GOTO 2230
2800 REM HANDLE ERRORS IN FUNCTION EVALUATION
2810 GOSUB 2860
2820 ? "↰":POSITION C5,C0:? " RESPONSE SURFACE MAP OUTPUT "
2830 POSITION 7,C2:? "BASIC Error #";PEEK(195);" Occurred":POSITION C4,C3:? "During Plot Function Evaluation"
2840 FOR I=C1 TO 500:NEXT I:POKE 712,160:GOTO 2450
2850 REM ERROR SOUND
2860 POKE 712,50:SOUND C0,121,10,8:SOUND C1,128,10,8:SOUND C2,8,C2,C2:FOR I=C1 TO 20:NEXT I
2870 FOR I=C0 TO C2:SOUND I,C0,C0,C0:NEXT I:RETURN
