New Owner's Column #8 (NEWOWN8C.BAS)

New Owner's Column #8 by David Plotkin, 50

Description

New Owner's Column #8 by David Plotkin, 50

From the Antic disk of December 1986 (Vol. 5 No. 8).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 3.6 KB

Dialect
Atari BASIC
Lines
109
Variables
D(, PR$, A$, BX, BY, LE, DS, N, MX, MY, PI, RH, VT, L, IB, SK, YE, XE, AX, AY, D1, D, D2, XS, YS, X0, ZZ, YY, XX, EX, EY, RA, R1, RD, ZS, XP, CX, YP, X8, Y8, X
BASIC listing (109 lines)
2 REM NEW OWNER'S COLUMN PART 8
4 REM BY DAVID PLOTKIN
6 REM (c) 1986, ANTIC PUBLISHING
8 REM LISTING 3 - FRACTAL SHAPES
10 COLOR 1
20 DIM D(64,33),PR$(1),A$(1):BX=0:BY=0
30 GRAPHICS 0:POSITION 2,5:PRINT "NUMBER OF LEVELS (3-6)":INPUT LE:IF LE>6 OR LE<3 THEN 30
35 GOSUB 1200
40 DS=2:FOR N=1 TO LE:DS=DS+2^(N-1):NEXT N
50 MX=DS-1:MY=MX/2:PI=3.14159:RH=PI*30/180:VT=RH*1.2
60 FOR N=1 TO LE:L=10000/1.8^N
70 PRINT "WORKING ON LEVEL ";N
80 IB=MX/2^N:SK=IB*2
90 GOSUB 150:REM ASSIGN HEIGHTS ALONG X IN ARRAY
100 GOSUB 220:REM ASSIGN HEIGHTS ALONG Y IN ARRAY
110 GOSUB 290:REM ASSIGN HEIGHTS ALONG DIAG. IN ARRAY
120 NEXT N
130 GOTO 640:REM DRAW
140 REM HEIGHTS ALONG X
150 FOR YE=0 TO MX-1 STEP SK
160 FOR XE=IB+YE TO MX STEP SK
170 AX=XE-IB:AY=YE:GOSUB 370:D1=D:AX=XE+IB:GOSUB 370:D2=D
180 D=(D1+D2)/2+RND(0)*L/2-L/4:AX=XE:AY=YE:GOSUB 420
190 NEXT XE
200 NEXT YE:RETURN
210 REM HEIGHTS ALONG Y
220 FOR XE=MX TO 1 STEP -SK
230 FOR YE=IB TO XE STEP SK
240 AX=XE:AY=YE+IB:GOSUB 370:D1=D:AY=YE-IB:GOSUB 370:D2=D
250 D=(D1+D2)/2+RND(0)*L/2-L/4:AX=XE:AY=YE:GOSUB 420
260 NEXT YE
270 NEXT XE:RETURN
280 REM HEIGHTS ALONG DIAGONAL
290 FOR XE=0 TO MX-1 STEP SK
300 FOR YE=IB TO MX-XE STEP SK
310 AX=XE+YE-IB:AY=YE-IB:GOSUB 370:D1=D
320 AX=XE+YE+IB:AY=YE+IB:GOSUB 370:D2=D
330 AX=XE+YE:AY=YE:D=(D1+D2)/2+RND(0)*L/2-L/4:GOSUB 420
340 NEXT YE
350 NEXT XE:RETURN
360 REM RETRIEVE DATA FROM ARRAY
370 IF AY>MY THEN 390
380 BY=AY:BX=AX:GOTO 400
390 BY=MX+1-AY:BX=MX-AX
400 D=D(ABS(INT(BX)),BY):RETURN
410 REM PUT DATA INTO ARRAY
420 IF AY>MY THEN 440
430 BY=AY:BX=AX:GOTO 450
440 BY=MX+1-AY:BX=MX-AX
450 D(BX,BY)=D:RETURN
470 RETURN
630 REM DISPLAY HERE
640 GOSUB 1110:REM SET UP SCREEN
650 XS=0.04:YS=0.04:REM SCALING FACTORS
660 FOR AX=0 TO MX:X0=-999:FOR AY=0 TO AX
670 GOSUB 370:ZZ=D:YY=AY/MX*10000:XX=AX/MX*10000-YY/2
680 GOSUB 940:NEXT AY:NEXT AX
690 FOR AY=0 TO MX:X0=-999:FOR AX=AY TO MX
700 GOSUB 370:ZZ=D:YY=AY/MX*10000:XX=AX/MX*10000-YY/2
710 GOSUB 940:NEXT AX:NEXT AY
720 FOR EX=0 TO MX:X0=-999:FOR EY=0 TO MX-EX
730 AX=EX+EY:AY=EY:GOSUB 370:ZZ=D:YY=AY/MX*10000
740 XX=AX/MX*10000-YY/2:GOSUB 940:NEXT EY:NEXT EX
750 GOTO 1130
760 REM ROTATE
770 IF XX<>0 THEN 800
780 IF YY<=0 THEN RA=-PI/2:GOTO 820
790 RA=PI/2:GOTO 820
800 RA=ATN(YY/XX)
810 IF XX<0 THEN RA=RA+PI
820 R1=RA+RH:RD=SQR(XX*XX+YY*YY)
830 XX=RD*COS(R1):YY=RD*SIN(R1)
840 RETURN
850 REM TILT DOWN
855 IF ZZ<1E-30 THEN ZZ=0
860 RD=SQR(ZZ*ZZ+XX*XX)
870 IF XX=0 THEN RA=PI/2:GOTO 900
880 RA=ATN(ZZ/XX)
890 IF XX<0 THEN RA=RA+PI
900 R1=RA-VT
910 XX=RD*COS(R1)+XX:ZZ=RD*SIN(R1)
920 RETURN
930 REM MOVE OR DRAWTO (XP,YP)
940 GOSUB 470
950 XX=XX*XS:YY=YY*YS:ZZ=ZZ*ZS
960 GOSUB 770:REM ROTATE
970 GOSUB 855:REM TILT UP
980 IF X0=-999 THEN PR$="M"
985 IF X0<>-999 THEN PR$="D"
990 XP=INT(YY)+CX:YP=INT(ZZ)
1000 GOSUB 1030
1010 RETURN
1020 REM PLOT LINE HERE
1030 XP=XP*0.625:YP=33.14-0.663*YP:POKE 77,0
1040 IF PR$="M" THEN X8=XP:Y8=YP:X0=X
1045 IF Y8>179 OR Y8<0 OR YP>179 OR YP<0 THEN RETURN
1050 PLOT X8,Y8:DRAWTO XP,YP:X8=XP:Y8=YP:RETURN
1100 REM SET UP SCREEN
1110 GRAPHICS 8:COLOR 1:POKE 710,0:RETURN
1130 POKE 764,255:PRINT "PRESS RETURN TO CONTINUE":INPUT A$
1140 GOTO 30
1200 POSITION 7,12:PRINT "PRESS:"
1210 POSITION 2,13:PRINT "1 LOW MOUNTAINS":POSITION 2,14:PRINT "2 MED MOUNTAINS"
1220 POSITION 2,15:PRINT "3 HIGH MOUNTAINS"
1230 INPUT A$:IF A$<>"1" AND A$<>"2" AND A$<>"3" THEN GRAPHICS 0:GOTO 1200
1240 IF A$="1" THEN ZS=0.04
1250 IF A$="2" THEN ZS=0.055
1260 IF A$="3" THEN ZS=0.07
1270 RETURN