New Owner's Column #8 (NEWOWN8A.BAS)
New Owner's Column #8 by David Plotkin, 50
Description
New Owner's Column #8 by David Plotkin, 50
From the Antic disk of December 1986 (Vol. 5 No. 8).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 1.2 KB
- Dialect
- Atari BASIC
- Lines
- 23
- Variables
SCORE(,AVG,STUDENT,SCORE,LOOP,HIGHSCORE,HIGHSTUDENT
BASIC listing (23 lines)
10 REM NEW OWNER'S COLUMN PART 8
11 REM BY DAVID PLOTKIN
12 REM (c) 1986, ANTIC PUBLISHING
20 REM LISTING 1: STUDENT TEST SCORES
30 DIM SCORE(30):AVG=0:REM MAX. OF 30 TEST SCORES
40 STUDENT=1:REM INITIALIZE THE STUDENT ID NUMBER
50 READ SCORE:REM GET THE SCORE FROM THE DATA STATEMENT
60 IF SCORE=-1 THEN GOTO 100:REM A SCORE OF -1 IS IMPOSSIBLE, SO WE USE -1 TO FLAG THE END OF DATA
70 SCORE(STUDENT)=SCORE:REM PUT THE SCORE INTO SINGLY SUBSCRIPTED VARIABLE "SCORE".
80 STUDENT=STUDENT+1:GOTO 50:REM GO AROUND FOR ANOTHER SCORE.
100 STUDENT=STUDENT-1:REM WE DID NOT USE THE LAST STUDENT (SCORE=-1).
110 GRAPHICS 0:POSITION 8,2:PRINT "STUDENT TEST SCORES":REM PRINT HEADING
120 POSITION 8,3:PRINT "TOTAL STUDENTS: ";STUDENT
130 POSITION 3,4:PRINT "STUDENT ID #";:POSITION 25,4:PRINT "TEST SCORE";
140 FOR LOOP=1 TO STUDENT:REM LOOP THRU THE NUMBER OF STUDENTS
150 POSITION 9,LOOP+4:PRINT LOOP:POSITION 28,LOOP+4:PRINT SCORE(LOOP):AVG=AVG+SCORE(LOOP)
160 NEXT LOOP
170 POSITION 2,LOOP+4:PRINT "AVERAGE SCORE IS:";INT(AVG/STUDENT)
180 HIGHSCORE=0:FOR LOOP=1 TO STUDENT:REM FIND THE HIGH SCORE
190 IF SCORE(LOOP)>HIGHSCORE THEN HIGHSCORE=SCORE(LOOP):HIGHSTUDENT=LOOP
200 NEXT LOOP
210 POSITION 2,LOOP+5:PRINT "HIGH SCORE WAS ";HIGHSCORE;" BY STUDENT ";HIGHSTUDENT
250 DATA 91,56,77,89,88,98,56,72,75,81,78,93,66,-1
