V-Graph, graphics utility (VGRAPH.BAS)
V-Graph, graphics utility by Alfred Filskov, 26
Description
V-Graph, graphics utility by Alfred Filskov, 26
From the Antic disk of November 1986 (Vol. 5 No. 7).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 10.5 KB
- Dialect
- Atari BASIC
- Lines
- 199
- Variables
BRK,A$,F$,G$,T$,XL$,M$,TL$,YL$,K$,CL$,Y(,A(,B(,PTS(,A,FILES,YMAX,YMIN,B,C,GH,VL,LOW,HI,DIV,SCALE,X,Y,XLABEL,PTS,LL,T,U,V,W,COLS,START,E1,E3,CHARSET,E2,F,POWER
BASIC listing (199 lines)
10 REM V-GRAPH
20 REM BY ALFRED FILSKOV
30 REM (c) 1986, ANTIC PUBLISHING
35 BRK=1:IF PEEK(53279)=5 THEN BRK=0
40 DIM A$(20),F$(15),G$(37),T$(40),XL$(300),M$(72),TL$(40),YL$(20),K$(25)
50 DIM CL$(1),Y(100,2),A(100),B(100,2),PTS(3)
60 M$="JANFEBMARAPRMAYJUNJULAUGSEPOCTNOVDEC":M$(37)=M$:CL$=CHR$(125)
70 GRAPHICS 0:POKE 82,2:POKE 83,39:CLOSE #1:OPEN #1,4,0,"K:":GOSUB 1930
80 ? CL$:POSITION 17,1:? "V-GRAPH":? " by Alfred H. Filskov, III"
90 ? :? "This program will plot graphs with up to 100 points based on data from disk files."
100 ? :? "Do you want a disk directory (Y/N)?";
110 GOSUB 1280:IF NOT A THEN 140
120 ? CL$:TRAP 310:CLOSE #2:OPEN #2,6,0,"D:*.*"
130 INPUT #2,A$:? A$;" ";:IF A$(5,9)<>"FREE " THEN 130
140 CLOSE #2:? :? :? "How many files do you want to graph at once (1-3)?";
150 GET #1,FILES:FILES=FILES-48:IF FILES<1 OR FILES>3 THEN 150
160 ? FILES:? :A=0:YMAX=0:YMIN=900000:G$=" ":G$(36)=" ":G$(2)=G$
170 REM LOAD FILES
180 A=A+1:? "Enter filename ";A;". D:";:INPUT #16;A$
190 F$="D:":F$(3)=A$:TRAP 310:CLOSE #2:OPEN #2,4,0,F$:B=0:TRAP 250
200 INPUT #2,C:IF C>900000 THEN ? "DATA TOO LARGE!":GOTO 100
210 IF C<0 THEN ? "DATA LESS THAN 0!":GOTO 100
220 B=B+1:Y(B,A-1)=C:IF YMAX<C THEN YMAX=C
230 IF YMIN>C THEN YMIN=C
240 IF B<100 THEN 200
250 IF B=0 THEN A=A-1:? "BAD LOAD FILE!":GOTO 180
260 PTS(A)=B:G$(A*12-11)=A$:IF A<FILES THEN 180
270 IF FILES=1 THEN 320
280 IF FILES=2 AND PTS(1)=PTS(2) THEN 320
290 IF FILES=3 AND PTS(1)=PTS(2) AND PTS(2)=PTS(3) THEN 320
300 ? "FILES DID NOT HAVE THE SAME NUMBER OF DATA POINTS!":GOTO 100
310 ? :? "DISK ERROR #";PEEK(195):GOTO 100
320 GOSUB 1530:REM SET SCALE
330 GOSUB 1800:REM SET LABELS
340 REM MENU
350 TRAP 40000:POKE 702,64:GRAPHICS 0:GOSUB 1930:POKE 82,11:? :? :? " M E N U":? " ---------"
360 ? :? "1. BARGRAPH":? "2. LINE GRAPH":? "3. POINT GRAPH"
370 ? "4. CHANGE SCALE":? "5. CHANGE LABELS":? "6. NEW DATA":? "7. END PROGRAM"
380 ? :? " YOUR CHOICE?";:POKE 82,2
390 GET #1,A:GH=A-48:IF GH<1 OR GH>7 THEN 390
400 ? GH:IF GH=4 THEN GOSUB 1530:GOTO 350
410 IF GH=5 THEN GOSUB 1800:GOTO 350
420 IF GH=6 THEN RUN
430 IF GH=7 THEN ? CL$:END
440 IF GH>1 THEN ? :? :? " DO YOU WANT VERTICAL LINES (Y/N)?";:GOSUB 1280:VL=A
450 REM DRAW GRAPH
460 GRAPHICS 8+16:GOSUB 1930:COLOR 1
470 PLOT 56,8:DRAWTO 56,155:DRAWTO 319,155
480 FOR A=LOW TO HI STEP (HI-LOW)/DIV:C=155-(A-LOW)*SCALE
490 PLOT 50,C:DRAWTO 55,C:T$=STR$(A)
500 X=6-LEN(T$):Y=C-3:GOSUB 740
510 FOR B=59 TO 317 STEP 3:PLOT B,C:NEXT B
520 NEXT A
530 IF TL$<>"" THEN T$=TL$:X=20-INT(LEN(T$)/2):Y=0:GOSUB 740
540 IF YL$<>"" THEN FOR A=1 TO LEN(YL$):T$=YL$(A,A):X=0:Y=72-LEN(YL$)*4+A*8:GOSUB 740:NEXT A
550 IF XLABEL=5 THEN 600
560 A=1:FOR B=1 TO PTS:A$=XL$(A,A+LL-1)
570 FOR C=1 TO LL:T$=A$(C,C):X=A(B)/8:Y=149+C*7:GOSUB 740:NEXT C
580 A=A+LL:IF A>LEN(XL$) THEN A=1
590 NEXT B
600 IF FILES>1 THEN ON FILES-1 GOSUB 840,900:REM PRINT KEY
610 IF VL AND GH>1 THEN FOR A=1 TO PTS:FOR B=154 TO 9 STEP -5:PLOT A(A),B:NEXT B:NEXT A:REM VERTICAL LINES
620 ON GH GOSUB 980,1040,1040:REM PLOT BARS OR POINTS
630 T$="(M)enu":X=0:Y=160:GOSUB 740:T$="(P)rint":X=0:Y=168:GOSUB 740
640 GET #1,A:IF A<>77 AND A<>80 THEN 640
650 IF A=77 THEN 350
660 COLOR 0:FOR A=0 TO 55:PLOT A,160:DRAWTO A,174:NEXT A:COLOR 1:TRAP 630
670 REM PUT GR.8+16 DUMP ROUTINE HERE
680 TRAP 1960:T=PEEK(88)+PEEK(89)*256:CLOSE #3:OPEN #3,8,0,"P:":? #3;CHR$(27);"A";CHR$(8)
690 FOR U=0 TO 39:? #3;CHR$(27);"L";CHR$(128);CHR$(1);
700 FOR V=191 TO 0 STEP -1:W=PEEK(T+U+V*40):? #3;CHR$(W);CHR$(W);
710 NEXT V:? #3:NEXT U:CLOSE #3
720 TRAP 40000:GOTO 630
730 REM PRINT IN GR.8
740 X=INT(X):Y=INT(Y):COLS=40:START=(PEEK(89)*256+PEEK(88))+Y*COLS+X
750 FOR E1=1 TO LEN(T$):E3=ASC(T$(E1))
760 IF E3<32 OR (E3>127 AND E3<160) THEN E3=E3+64:GOTO 780
770 IF E3>31 AND E3<96 THEN E3=E3-32
780 CHARSET=PEEK(756)*256+E3*8
790 FOR E2=7 TO 1 STEP -1
800 POKE START+E2*COLS,PEEK(CHARSET+E2):NEXT E2
810 X=X+1:IF X>=COLS THEN START=START+COLS*8:X=0
820 START=START+1:NEXT E1:RETURN
830 REM TWO FILES IN KEY
840 T$="Key: - -":T$(9)=K$(1,8):T$(21)=K$(9,16):X=7:Y=182:GOSUB 740
850 IF GH>1 THEN X=108:Y=185:F=1:GOSUB 1110:X=204:F=2:GOSUB 1110:RETURN
860 FOR A=106 TO 110:PLOT A,182:DRAWTO A,188:NEXT A
870 PLOT 202,188:DRAWTO 202,182:DRAWTO 206,182:DRAWTO 206,188:DRAWTO 202,188:PLOT 203,185:DRAWTO 205,185
880 RETURN
890 REM THREE FILES IN KEY
900 T$="Key: - - -":T$(9)=K$(1,8):T$(21)=K$(9,16):T$(33)=K$(17,24)
910 X=0:Y=182:GOSUB 740
920 IF GH>1 THEN X=52:Y=185:F=1:GOSUB 1110:X=148:F=2:GOSUB 1110:X=244:F=3:GOSUB 1110:RETURN
930 FOR A=50 TO 54:PLOT A,182:DRAWTO A,188:NEXT A
940 PLOT 146,188:DRAWTO 146,182:DRAWTO 150,182:DRAWTO 150,188:DRAWTO 146,188:PLOT 147,185:DRAWTO 149,185
950 PLOT 242,188:DRAWTO 242,182:DRAWTO 246,182:DRAWTO 246,188:PLOT 244,183:DRAWTO 244,188
960 RETURN
970 REM BARGRAPH
980 FOR A=1 TO PTS
990 IF FILES=1 THEN B=-2:GOSUB 1180
1000 IF FILES=2 THEN B=-4:GOSUB 1180:B=2:GOSUB 1190
1010 IF FILES=3 THEN B=-8:GOSUB 1180:B=-2:GOSUB 1190:B=4:GOSUB 1230
1020 NEXT A:RETURN
1030 REM POINT AND LINE GRAPH
1040 FOR A=0 TO FILES-1:FOR B=1 TO PTS
1050 X=A(B):Y=B(B,A):F=A+1:GOSUB 1110
1060 NEXT B:NEXT A
1070 IF GH=3 THEN RETURN
1080 FOR A=0 TO FILES-1:PLOT A(1),B(1,A):FOR B=2 TO PTS:DRAWTO A(B),B(B,A)
1090 NEXT B:NEXT A:RETURN
1100 REM DRAW POINTS
1110 COLOR 0:PLOT X,Y-2:DRAWTO X,Y+2:COLOR 1
1120 IF F=1 THEN PLOT X,Y:PLOT X,Y-1:PLOT X+1,Y-1:DRAWTO X+1,Y+1:DRAWTO X-1,Y+1:DRAWTO X-1,Y-1
1130 IF F=2 THEN PLOT X,Y:PLOT X-1,Y-2:DRAWTO X+1,Y-2:PLOT X+2,Y-1:DRAWTO X+2,Y+1
1140 IF F=2 THEN PLOT X+1,Y+2:DRAWTO X-1,Y+2:PLOT X-2,Y+1:DRAWTO X-2,Y-1
1150 IF F=3 THEN PLOT X-2,Y-2:DRAWTO X+2,Y+2:PLOT X+2,Y-2:DRAWTO X-2,Y+2
1160 RETURN
1170 REM DRAW BARS
1180 FOR C=B TO B+4:PLOT A(A)+C,B(A,0):DRAWTO A(A)+C,155:NEXT C:RETURN
1190 COLOR 0:FOR C=A(A)+B+1 TO A(A)+B+3:PLOT C,B(A,1):DRAWTO C,154:NEXT C:COLOR 1
1200 PLOT A(A)+B,155:DRAWTO A(A)+B,B(A,1):DRAWTO A(A)+B+4,B(A,1):DRAWTO A(A)+B+4,155
1210 IF B(A,1)<152 THEN FOR C=B(A,1) TO 153 STEP 3:PLOT A(A)+B,C:DRAWTO A(A)+B+4,C:NEXT C
1220 RETURN
1230 IF B(A,2)>153 THEN 1250
1240 COLOR 0:PLOT A(A)+B+1,B(A,2):DRAWTO A(A)+B+1,154:PLOT A(A)+B+3,B(A,2):DRAWTO A(A)+B+3,154:COLOR 1
1250 PLOT A(A)+B,155:DRAWTO A(A)+B,B(A,2):DRAWTO A(A)+B+4,B(A,2):DRAWTO A(A)+B+4,155
1260 PLOT A(A)+B+2,B(A,2):DRAWTO A(A)+B+2,155:RETURN
1270 REM GET YES OR NO
1280 ? "Y←";:POKE 702,64:GET #1,A:IF A<>78 AND A<>89 AND A<>155 THEN 1280
1285 IF A=155 THEN A=89
1290 ? CHR$(A):A=(A-78)/11:RETURN
1300 REM CUSTOM
1310 ? CL$:? "CUSTOM LABELS: (";PTS;" DATA POINTS)"
1320 ? :? "HOW MANY CHARACTERS LONG WILL EACH LABEL BE (1-3)?";
1330 TRAP 1330:GET #1,LL:LL=LL-48:IF LL<1 OR LL>3 THEN 1330
1340 ? LL:? :? "TYPE THE LABELS FOR EACH POINT. PRESS [RETURN] WHEN YOU ARE DONE AND"
1350 ? "YOU WANT THE LABELS TO REPEAT.":A=1
1360 ? :? "TYPE LABEL FOR POINT ";A;". >";:B=1
1370 GET #1,C:IF C=155 AND B=1 AND A>1 THEN ? "REPEAT":RETURN
1380 IF C<32 OR C>123 THEN 1370
1390 XL$(A*LL-LL+B)=CHR$(C):? CHR$(C);
1400 IF B<LL THEN B=B+1:GOTO 1370
1410 IF A<PTS THEN A=A+1:GOTO 1360
1420 ? :RETURN
1430 REM LETTERS
1440 FOR A=65 TO 90:XL$(A-64)=CHR$(A):NEXT A:LL=1:RETURN
1450 REM MONTHS
1460 TRAP 1460:? :? "STARTING MONTH # (1-12)";:INPUT A:A=INT(A):IF A<1 OR A>12 THEN 1460
1470 LL=3:B=A*3-2:XL$=M$(B,B+35):RETURN
1480 REM NUMBERS
1490 TRAP 1490:? :? "STARTING WITH # (0-900)";:INPUT A:A=INT(A):IF A<0 OR A>900 THEN 1490
1500 XL$=" ":XL$(300)=" ":XL$(2)=XL$
1510 LL=LEN(STR$(A+PTS)):FOR B=1 TO PTS:XL$(B*LL-LL+1)=STR$(A+B-1):NEXT B:RETURN
1520 REM SET Y-AXIS SCALE
1530 ? CL$:? "SET Y-AXIS SCALE:"
1540 ? :? "ENTER LOW VALUE FOR SCALE.":? "(0-";YMIN;") 0←←";
1550 ? "0←";:LOW=0:TRAP 1570:INPUT LOW:IF LOW<0 OR LOW>YMIN THEN 1540
1560 REM CALCULATE SCALE
1570 HI=YMAX-LOW
1580 POWER=0
1590 IF HI>=100 THEN HI=HI/10:POWER=POWER+1:GOTO 1590
1600 IF HI<10 THEN HI=HI*10:POWER=POWER-1:GOTO 1600
1610 HI=INT(HI+0.99)
1620 IF HI/12=INT(HI/12) THEN DIV=12:GOTO 1660
1630 IF HI/10=INT(HI/10) THEN DIV=10:GOTO 1660
1640 IF HI/8=INT(HI/8) THEN DIV=8:GOTO 1660
1650 HI=HI+1:GOTO 1620
1660 IF POWER>0 THEN FOR A=1 TO POWER:HI=HI*10:NEXT A
1670 IF POWER<0 THEN FOR A=POWER TO -1:HI=HI/10:NEXT A
1680 SCALE=144/HI
1690 HI=HI+LOW
1700 ? :? "TOP VALUE FOR SCALE = ";HI;".":? "IS THIS OK (Y/N)?";
1710 GOSUB 1280:IF A THEN 1760
1720 TRAP 1720:? :? "WHAT TOP VALUE DO YOU WANT (GREATER THAN ";YMAX;")";:INPUT HI
1730 IF HI<YMAX OR HI>900000 THEN 1720
1740 HI=HI-LOW:GOTO 1580
1750 REM CALCULATE POINTS ON SCREEN
1760 ? :? "CALCULATING POINTS...":PTS=PTS(1):FOR A=1 TO PTS:FOR B=1 TO FILES
1770 A(A)=INT(245/PTS*(A-0.5)+65):A(A)=INT(A(A)/2)*2:B(A,B-1)=INT(155.5-(Y(A,B-1)-LOW)*SCALE)
1780 NEXT B:NEXT A:RETURN
1790 REM SET LABELS
1800 ? CL$:? "SET LABELS: (";PTS;" DATA POINTS)"
1810 ? :? "ENTER A TITLE FOR THE GRAPH.":INPUT TL$
1820 ? :? "ENTER THE Y-AXIS LABEL.":INPUT YL$
1830 IF FILES=1 THEN 1890
1840 ? :? "ENTER THE LABELS FOR THE FILES.":? "(8 LETTERS MAX)"
1850 ? :K$=" ":K$(24)=" ":K$(2)=K$:G$(37)=" "
1860 FOR A=1 TO FILES:? "FILE ";A;" (";G$(A*12-11,A*12);") ";
1870 INPUT A$:IF A$<>"" THEN K$(A*8-7)=A$
1880 NEXT A:K$(25)=" "
1890 ? :? "LABEL X-AXIS WITH (K)-CUSTOM LABELS, (L)ETTERS, (M)ONTHS, (N)UMBERS, OR N(O) LABEL?";
1900 POKE 702,64:GET #1,XLABEL:XLABEL=XLABEL-74:IF XLABEL<1 OR XLABEL>5 THEN 1900
1910 ? CHR$(XLABEL+74):IF XLABEL<5 THEN ON XLABEL GOSUB 1310,1440,1460,1490
1920 RETURN
1930 POKE 710,12:POKE 712,12:POKE 709,2:POKE 77,0
1940 IF BRK THEN POKE 16,112:POKE 53774,112
1950 RETURN
1960 GRAPHICS 8+16+16:GOSUB 1930:POKE 712,64:POKE 752,1:? "↰↓↓ *** PRINTER OFFLINE ***↰↰"
1970 FOR X=1 TO 90:NEXT X:GRAPHICS 8+16+32:GOSUB 1930:GOTO 630
