New Owner's Column #7 (NEWOWN7.BAS)

New Owner's Column #7 by David Plotkin, 29

Description

New Owner's Column #7 by David Plotkin, 29

From the Antic disk of November 1986 (Vol. 5 No. 7).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.8 KB

Dialect
Atari BASIC
Lines
36
Variables
A, NAME$, TXT$, DUM$, LN, LQ, LOOP, WAIT, Y
BASIC listing (36 lines)
10 REM THE NEW OWNER'S COLUMN, PART 7
20 REM BY DAVID PLOTKIN
30 REM (c) 1986, ANTIC PUBLISHING
50 GRAPHICS 0:DIM NAME$(20),TXT$(15),DUM$(30)
60 POSITION 4,9:PRINT "WHAT IS YOUR NAME";:INPUT NAME$:REM THE INPUT STATEMENT
70 POKE 752,1:POSITION 0,10:PRINT " ";
80 COLOR 42:PLOT 4,14:DRAWTO 36,14:DRAWTO 36,18:DRAWTO 4,18:DRAWTO 4,14:DRAWTO 4,16:DRAWTO 5,16
90 LN=6+LEN(NAME$):LQ=20-LN/2:DUM$="HELLO ":DUM$(LEN(DUM$)+1)=NAME$
100 FOR LOOP=1 TO LN:POSITION LQ+LOOP-1,16:PRINT DUM$(LOOP,LOOP);
110 FOR WAIT=10 TO 20:SOUND 0,WAIT*5,10,4:NEXT WAIT:NEXT LOOP:SOUND 0,0,0,0
120 POSITION 4,20:PRINT "PRESS RETURN TO CONTINUE"
130 OPEN #1,4,0,"K:"
140 GET #1,A:IF A<>155 THEN 140
150 PRINT CHR$(125):POSITION 3,2
160 PRINT "PRESS ANY KEY AND I WILL TELL YOU     WHICH KEY YOU PRESSED"
170 REM TEST FOR KEYS WHICH ARE CURSOR CONTROLS
180 GET #1,A:TXT$=""
190 IF A=27 THEN TXT$="ESC":GOTO 350
200 IF A=127 THEN TXT$="TAB":GOTO 350
210 IF A=159 THEN TXT$="SET":GOTO 350
220 IF A=158 THEN TXT$="CLR":GOTO 350
230 IF A=126 THEN TXT$="BACKSPACE":GOTO 350
240 IF A=156 THEN TXT$="DELETE":GOTO 350
250 IF A=254 THEN TXT$="CTRL-DELETE":GOTO 350
260 IF A=157 THEN TXT$="INSERT":GOTO 350
270 IF A=255 THEN TXT$="CNTRL-INSERT":GOTO 350
280 IF A=125 THEN TXT$="CLEAR":GOTO 350
290 IF A=155 THEN TXT$="RETURN":GOTO 350
300 IF A=31 THEN TXT$(1,1)=CHR$(27):TXT$(2,2)=CHR$(31):GOTO 350
310 IF A=30 THEN TXT$(1,1)=CHR$(27):TXT$(2,2)=CHR$(30):GOTO 350
320 IF A=28 THEN TXT$(1,1)=CHR$(27):TXT$(2,2)=CHR$(28):GOTO 350
330 IF A=29 THEN TXT$(1,1)=CHR$(27):TXT$(2,2)=CHR$(29):GOTO 350
340 TXT$=CHR$(A)
350 PRINT "YOU PRESSED ";TXT$;" : CODE ";A
360 GOTO 180
370 END