Car Financer (CARFINAN.BAS)

Car Financer by Elaine A. Patterson, 41

Description

Car Financer by Elaine A. Patterson, 41

From the Antic disk of November 1986 (Vol. 5 No. 7).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 4.9 KB

Dialect
Atari BASIC
Lines
93
Variables
BRK, PRICE, AMOUNT, D, TRADE, TAX, DPAY, MISC, RATE, M, FINAN, REPAY, PAYMENT, EAP, TIME
BASIC listing (93 lines)
10 REM CAR FINANCER
12 REM BY ELAINE A. PATTERSON
14 REM (c) 1986, ANTIC PUBLISHING
15 BRK=1:IF PEEK(53279)=5 THEN BRK=0
20 GOSUB 3000:CLOSE #1:OPEN #1,4,0,"K:"
29 REM COST OF AUTO
30 GRAPHICS 1:POKE 712,146:POKE 710,PEEK(712):POKE 709,40:POKE 708,138:POKE 711,30:POKE 752,1
35 GOSUB 3000:POSITION 1,2:? #6;"THIS PROGRAM WILL":? #6;" TAKE INTO ACCOUNT"
40 ? #6;"   ALL VARIABLES":? #6;" WHEN BUYING A CAR":? #6;" TO DETERMINE YOUR"
45 ? #6;" monthly  payments":POSITION 4,11:? #6;"WHAT IS THE":? #6;"   asking price";CHR$(159)
50 TRAP 50:INPUT PRICE:AMOUNT=PRICE
60 POSITION 6,13:? #6;"$";PRICE:GOSUB 1000
70 IF D=78 THEN 30
79 REM TRADE
80 ? #6;CHR$(125):POSITION 1,2:? #6;"WILL YOU TRADE-IN?":POSITION 7,4:? #6;"(Y/N)":? "↰";:GOSUB 1010
90 IF D=78 THEN TRADE=0:GOTO 130
100 POSITION 0,6:? #6;"enter trade▔in value":TRAP 100:? "↰";:INPUT TRADE
110 POSITION 5,8:? #6;"$";TRADE:GOSUB 1000:IF D=78 THEN ? #6;CHR$(125):GOTO 100
120 AMOUNT=AMOUNT-TRADE
129 REM TAX
130 ? #6;CHR$(125):POSITION 4,3:? #6;"WHAT IS THE":? #6;"  sales tax rate";CHR$(159)
140 POSITION 2,6:? #6;"ENTER 4 FOR 4% or":POSITION 1,7:? #6;"6.75 FOR 6.75%"
150 TRAP 150:? "↰";:INPUT TAX:POSITION 7,9:? #6;TAX;"%":GOSUB 1000
160 IF D=78 THEN 130
170 TAX=TAX/100:AMOUNT=INT((AMOUNT+TAX*AMOUNT)*100)/100
179 REM DOWN PAYMENT
180 ? #6;CHR$(125):POSITION 4,3:? #6;"HOW MUCH":POSITION 2,4:? #6;"down payment";CHR$(159)
190 TRAP 190:? "↰";:INPUT DPAY:POSITION 7,9:? #6;"$";DPAY:GOSUB 1000:IF D=78 THEN 180
199 REM MISC. EXPENSES
200 ? #6;CHR$(125):POSITION 2,2:? #6;"TAG, TITLE, AND":POSITION 3,3:? #6;"MISCELLANEOUS"
205 POSITION 5,5:? #6;"expenses";CHR$(159)
210 TRAP 210:? "↰";:INPUT MISC:POSITION 7,10:? #6;"$";MISC:GOSUB 1000:IF D=78 THEN 200
220 AMOUNT=AMOUNT+MISC-DPAY
229 REM FINANCE RATE
230 ? #6;CHR$(125):POSITION 4,3:? #6;"WHAT IS THE":POSITION 3,4:? #6;"finance rate";CHR$(31)
240 POSITION 2,6:? #6;"ENTER 19 FOR 19%":POSITION 9,7:? #6;"OR":POSITION 4,8:? #6;"9.9 FOR 9.9%"
250 TRAP 250:? "↰";:INPUT RATE:POSITION 7,10:? #6;RATE;"%":GOSUB 1000
260 IF D=78 THEN 230
270 RATE=RATE/100
279 REM NUMBER OF MONTHS
280 ? #6;CHR$(125):POSITION 2,2:? #6;"HOW MANY months";CHR$(159)
290 TRAP 290:? "↰";:INPUT M:TRAP 40000
300 POSITION 4,8:? #6;M;" MONTHS":GOSUB 1000
310 IF D=78 THEN 280
319 REM SOURCE OF LOAN
320 ? #6;CHR$(125):POSITION 2,2:? #6;"WILL THIS LOAN BE  FROM A:":POSITION 2,7:? #6;"1 bank"
330 POSITION 2,9:? #6;"2 car finance co":POSITION 4,10:? #6;"(GMAC,FORD,ETC.)"
340 POSITION 0,15:? #6;"what is your choice";CHR$(159):GOSUB 2000
350 ON D GOTO 360,390
359 REM BANK METHOD
360 FINAN=RATE*AMOUNT*M/12:FINAN=INT(FINAN*100+0.5)/100
370 REPAY=AMOUNT+FINAN:PAYMENT=REPAY/M:PAYMENT=INT(PAYMENT*100+0.5)/100
380 GOTO 480
389 REM CAR FINANCE CO. METHOD
390 PAYMENT=(AMOUNT+(AMOUNT*RATE*M/12))/M:PAYMENT=PAYMENT-30:EAP=AMOUNT:PAYMENT=INT(PAYMENT*100+0.5)/100
400 FOR TIME=1 TO M:POKE 77,0
410 FINAN=AMOUNT*RATE*(1/12):FINAN=INT(FINAN*100+0.5)/100
420 AMOUNT=AMOUNT+FINAN-PAYMENT
430 NEXT TIME:? " WORKING "
440 IF AMOUNT<40 AND AMOUNT>-40 THEN AMOUNT=EAP:FINAN=PAYMENT*M-AMOUNT:GOTO 480
450 IF AMOUNT<-40 THEN PAYMENT=PAYMENT-0.5
451 REM .5'S CAN BE CHANGED TO .75 IF THAT WOULD SPEED IT UP
460 IF AMOUNT>40 THEN PAYMENT=PAYMENT+0.5
470 AMOUNT=EAP:GOTO 400
479 REM OUTPUT CHOICE
480 ? #6;CHR$(125):POSITION 3,4:? #6;"DO YOU WANT THE":? #6;"  RESULTS ON:"
490 POSITION 3,8:? #6;"1 screen or":POSITION 3,10:? #6;"2 printer"
500 POSITION 0,14:? #6;"WHAT IS YOUR CHOICE?":GOSUB 2000
790 ON D GOTO 800,900
799 REM DISPLAY RESULTS
800 GRAPHICS 0:GOSUB 3000:? "PRICE: $";PRICE:? "TRADE-IN VALUE: $";TRADE
810 ? "TAX RATE: ";TAX*100;"%":? "DOWN PAYMENT: $";DPAY
820 ? "FINANCE RATE: ";RATE*100;"%":? "AMOUNT FINANCED: $";AMOUNT:? "MONTHS: ";M:? "INTEREST: $";FINAN
830 ? "TOTAL TO REPAY: $";AMOUNT+FINAN:? "MONTHLY PAYMENT: $";PAYMENT:GOTO 1030
899 REM PRINT RESULTS
900 GRAPHICS 0:GOSUB 3000:? "PRINTING":LPRINT "PRICE: $";PRICE:LPRINT "TRADE-IN VALUE: $";TRADE
910 LPRINT "TAX RATE: ";TAX*100;"%":LPRINT "DOWN PAYMENT: $";DPAY
920 LPRINT "FINANCE RATE: ";RATE*100;"%":LPRINT "AMOUNT FINANCED: $";AMOUNT:LPRINT "MONTHS: ";M
930 LPRINT "INTEREST: $";FINAN:LPRINT "TOTAL TO REPAY: $";AMOUNT+FINAN:LPRINT "MONTHLY PAYMENT: $";PAYMENT
940 GOTO 1030
1000 POSITION 1,15:? #6;"IS THIS CORRECT?":POSITION 6,16:? #6;"(Y/N)"
1010 GET #1,D:IF D=89 OR D=78 THEN RETURN
1020 GOTO 1010
1030 POSITION 2,15:? "1 ONE MORE TIME":POSITION 2,17:? "2 QUIT"
1040 POSITION 2,20:? "What is your choice?";
1050 GOSUB 2000
1060 IF D=1 THEN 30
1070 GRAPHICS 0:END
2000 GET #1,D:D=D-48:IF D<1 OR D>2 THEN 2000
2010 RETURN
2999 REM DISABLE BREAK
3000 POKE 77,0:IF BRK THEN POKE 16,112:POKE 53774,112
3010 RETURN