Budget-DB (BUDGETDB.BAS)
Budget-DB by J. Roger Kearney, 90
Description
Budget-DB by J. Roger Kearney, 90
From the Antic disk of November 1986 (Vol. 5 No. 7).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 10.6 KB
- Dialect
- Atari BASIC
- Lines
- 214
- Variables
N82,N6,N0,R,N,YI$,PCNT,NCNT,L,N9,N1,STA$,Y$,N8,C$,SM$,SMO,EMO,N12,PR$,N4,PW$,TCNT,DSIZE,N21,TR,CT$,N15,N14,N5,N3,N2,N18,N19,N20,PL$,BL$,J,N11,N13,N10,S$,N7,X,S5,T56,P$,NC$,CN$,N16,N17,M,N64,STM$,BRK,TOT,CT,C,B$,CHKBAL,A,MO,STM,STA,N65,AL,N25,N752,Z$,L1,MCNT,AO,MM$,NXTCHK,N90,B,NXTC,DA,YR,NA,TX,TAX,A1,A2,NEG,ND,NXTRC,IO,JNK,PA,ERR,N33,N78,T53,Y
BASIC listing (214 lines)
2 REM BUDGET-DB
4 REM BY J. ROGER KEARNEY
6 REM (c) 1986, ANTIC PUBLISHING
10 GOTO 5000
20 TRAP 20:POKE N82,N6:? "↰↓↓↓1 Enter trans":? "↓2 List trans":? "↓3 List budget/actual"
30 ? "↓4 List misc info":? "↓5 Reconcile chkbk":? "↓6 Reconcile charge acct":? "↓7 Set up data"
40 ? "↓8 Save on DISK":? "↓9 Quit↓":POKE N82,N0:? :GOSUB 500
50 R=N0:INPUT N:ON N GOTO 1100,150,1000,1500,730,700,2000,1900,5300
150 YI$="":PCNT=N0:NCNT=N0:? "↰↓LIST":? "↓ 1 Cleared checks":? "↓ 2 Uncleared checks"
160 ? "↓ 3 All checks":? "↓↓ 4 Cleared charges":? "↓ 5 Uncleared charges":? "↓ 6 All charges"
165 ? "↓↓ 7 Cash purchases"
170 ? "↓↓ 8 Selected from all":? "↓ 9 All",,:INPUT L:? "↰":IF L>N9 OR L<N1 THEN 20
180 IF L=N9 THEN STA$="N":Y$="":L=N8:GOTO 230
190 ? "Payee(or 'RETURN')";:INPUT Y$:? "Taxed items only('Y')";:INPUT STA$:IF STA$="" THEN STA$="N"
200 ? C$;:INPUT YI$
210 ? SM$;:TRAP 230:INPUT SMO:? "End=";:INPUT EMO:IF EMO<SMO OR EMO>N12 OR SMO>N12 THEN 210
220 GOTO 235
230 SMO=N1:EMO=N12
235 ? "Printer('Y')";:INPUT PR$:IF PR$="" THEN PR$="N"
237 IF PR$="Y" THEN TRAP 4000:OPEN #N4,N8,N0,"P:"
240 ? "↰";PW$:POSITION N0,N1:IF TCNT=N0 THEN 455
250 FOR N=2049 TO DSIZE STEP N21:TR=ASC(CT$(N+N15)):IF ASC(CT$(N,N))<SMO OR ASC(CT$(N,N))>EMO THEN 450
260 IF LEN(YI$)=N1 THEN IF YI$<>CT$(N+N14,N+N14) THEN 450
270 IF NCNT>=TCNT THEN 450
280 IF L=N6 AND (TR=N4 OR TR=N5) THEN 320
290 IF L=N3 AND (TR<N4 OR TR=N6) THEN 320
293 IF L=N2 AND TR=N3 THEN 320
295 IF L=N1 AND (TR=N0 OR TR=N6) THEN 320
300 IF L<>N6 AND L<>N3 AND (L=TR OR L=N8) THEN 320
310 GOTO 450
320 IF STA$="Y" AND ASC(CT$(N+N18))=N0 AND ASC(CT$(N+N19))=N0 AND ASC(CT$(N+N20))=N0 THEN 450
325 PL$(N1)=BL$:FOR J=N1 TO N4:PL$(LEN(PL$)+N1)=PL$:NEXT J
330 PL$(N11,N18)=CT$(N+N6,N+N13)
340 IF LEN(Y$)>N0 THEN IF Y$<>PL$(N11,N10+LEN(Y$)) THEN 450
350 PL$(N2,N3)=STR$(ASC(CT$(N,N))):PL$(N5,N6)=STR$(ASC(CT$(N+N1,N+N1))):PL$(N8,N9)=STR$(ASC(CT$(N+N2,N+N2)))
355 PL$(N4,N4)=S$:PL$(N7,N7)=S$:X=ASC(CT$(N+N3))*S5+ASC(CT$(N+N4))*T56+ASC(CT$(N+N5))
360 GOSUB 1600:PL$(N21)=P$:IF TR=N0 THEN PL$(30)="Sv chg"
370 IF TR=N3 OR TR=N6 THEN PL$(30)="Deposit":PL$(66)=NC$:GOTO 430
380 IF TR=N7 THEN PL$(30)="Cash"
390 IF TR=N1 OR TR=N2 THEN PL$(30)=CN$:PL$(36)=STR$(ASC(CT$(N+N16))*T56+ASC(CT$(N+N17)))
400 M=ASC(CT$(N+N14)):IF TR=N4 OR TR=N5 THEN PL$(30)="Chg ":PL$(34,34)=CT$(N+N17)
410 PL$(44)=CHR$(M):IF M<>N64 THEN PL$(45)="-":PL$(46,51)=CT$(N6*(M-N64)+N1,N6*(M-N64)+N6):IF TR=0 THEN 430
420 PL$(53)=" TAX=$":X=(ASC(CT$(N+N18))*S5+ASC(CT$(N+N19))*T56+ASC(CT$(N+N20))):GOSUB 1600:PL$(58)=P$
425 IF TR=N2 OR TR=N5 THEN PL$(66)=NC$
430 ? PL$:IF PR$="Y" THEN ? #N4;PL$
440 PCNT=PCNT+N1
445 IF PCNT/N10-INT(PCNT/N10)=N0 THEN ? "↓'C' to cont";:INPUT STM$:POSITION N0,22:IF STM$<>"C" THEN 460
450 IF NCNT<TCNT-N1 THEN NCNT=NCNT+N1:NEXT N
455 ? "↓Found ";PCNT:GOSUB 1650
460 CLOSE #N4:GOTO 20
500 POKE 77,0:IF BRK THEN POKE N16,112:POKE 53774,112
510 RETURN
700 R=N:GOSUB 1800:? C$;:INPUT YI$:IF LEN(YI$)=N1 THEN M=ASC(YI$):IF M<91 AND M>64 THEN 730
710 GOTO 700
730 ? "↰":TOT=N0
740 ? PW$:FOR J=2049 TO 2049+TCNT*N21 STEP N21:TR=ASC(CT$(J+N15)):IF N=5 THEN IF TR=N2 OR TR=N3 THEN 770
750 IF R=N6 AND TR=N5 AND M=ASC(CT$(J+N17)) THEN 770
760 GOTO 910
770 ? "↰";STR$(ASC(CT$(J,J)));S$;STR$(ASC(CT$(J+N1,J+N1)));S$;STR$(ASC(CT$(J+N2,J+N2)));BL$(N1,N2);
775 ? CT$(J+N6,J+N13);BL$(N1,N2);
780 X=(ASC(CT$(J+N3))*S5+ASC(CT$(J+N4))*T56+ASC(CT$(J+N5))):GOSUB 1600:? P$;BL$(N1,N2);
790 IF TR=N3 THEN X=-X:? "Deposit"
800 IF TR=N2 THEN ? CN$;ASC(CT$(J+N16))*T56+ASC(CT$(J+N17))
810 IF TR=N5 THEN ? "Chg ";CT$(J+N17,J+N17)
820 IF TR=N3 THEN ? :GOTO 850
825 CT=ASC(CT$(J+N14))
830 ? BL$(N1,N3);CHR$(CT);:IF CT<>N64 THEN ? "-";CT$(N6*(CT-N64)+N1,N6*(CT-N64)+N6);BL$(N1,N2);
840 ? " TAX=$";(ASC(CT$(J+N18))*S5+ASC(CT$(J+N19))*T56+ASC(CT$(J+N20)))/C
850 TRAP 900:? "↓Enter 'Y' if cleared('M'=MENU)";:INPUT YI$:IF YI$="M" THEN 20
860 IF YI$<>"Y" THEN 900
870 IF TR=N3 THEN TR=N6
880 IF TR=N2 OR TR=N5 THEN TR=TR-N1
890 CT$(J+N15,J+N15)=CHR$(TR):GOTO 910
900 TOT=TOT+X/C
910 IF J<LEN(CT$)-N21 THEN NEXT J
920 X=TOT*C:GOSUB 1600:? "Outstanding=$";P$
930 IF N=N5 THEN ? :? B$;CHKBAL:? "↓Statement ";B$;CHKBAL+TOT
940 GOSUB 1650:GOTO 20
1000 TRAP 1000:A=177:? "↰";SM$;:INPUT STM$
1005 IF STM$="" THEN STM$=STR$(MO):IF MO>N1 THEN STM$=STR$(MO-N1)
1010 STM=VAL(STM$)-N1:IF STM<N0 OR STM>N11 THEN 1000
1020 IF STM=N11 THEN STM=N10
1030 ? C$;:INPUT STA$:IF STA$="" THEN STA$="A"
1035 IF STA$<"A" OR STA$>"Z" THEN 1030
1038 STA=ASC(STA$)-N65:AL=N20:IF STA+AL>N25 THEN AL=N25-STA
1040 POKE N752,N1:? "↰":POSITION N10,N0:FOR N=N0 TO N1
1045 ? " BDGT_";Z$((STM+N)*N3+N1,(STM+N)*N3+N3);"_ACTL";:NEXT N
1050 FOR N=STA TO STA+AL:? CHR$(N+N65);"-";CT$(N*N6+N7,N*N6+N12);
1060 FOR L1=N0 TO N11 STEP N3:R=A+L1+STM*N6+N*72:X=(ASC(CT$(R)))*S5+(ASC(CT$(R+N1)))*T56+ASC(CT$(R+N2))
1070 GOSUB 1600:? BL$(N1,N8-LEN(P$));:? P$;:NEXT L1:NEXT N
1080 IF STA<N5 THEN ? "'C' to cont";:INPUT STA$:IF STA$="C" THEN STA=STA+N21:AL=N25-STA:GOTO 1040
1090 GOSUB 1650
1095 GOTO 20
1100 IF TCNT=MCNT THEN ? "↰NO MORE SPACE↰":GOSUB 1650
1105 TRAP 20:GOSUB 1800:AO=TCNT*N21+2049
1110 CT$(AO,AO)=CHR$(N0):CT$(AO+N20,AO+N20)=CHR$(N0):CT$(AO+N1)=CT$(AO)
1120 ? :POKE N82,N7:X=CHKBAL*C:GOSUB 1600:? B$;P$,MM$:? "1 ";CN$;NXTCHK,"4 Cash"
1130 ? "2 ";CN$,,"5 Deposit":? "3 Charge",,"6 Sv chg":POKE 82,N0
1140 INPUT N:ON N GOTO 1200,1200,1150,1170,1180,1190
1150 TR=N5:? "Chg account ";C$;:INPUT Y$:IF ASC(Y$)<N65 OR ASC(Y$)>N90 THEN ? "INVALID":GOTO 1150
1160 B=AO+N17:CT$(B,B)=Y$:GOTO 1220
1170 TR=N7:GOTO 1220
1180 TR=N3:GOTO 1230
1190 TR=N0:GOTO 1220
1200 B=AO+N16:TR=N2:Y$=STR$(NXTCHK):NXTC=N1:IF N=N2 THEN NXTC=N0:? CN$;:INPUT Y$
1210 CT$(B,B)=CHR$(INT((VAL(Y$))/T56)):B=AO+N17:CT$(B,B)=CHR$(((VAL(Y$))/T56-INT((VAL(Y$))/T56))*T56)
1220 ? C$;:INPUT Y$:IF ASC(Y$(N1,N1))<N64 OR ASC(Y$(N1,N1))>N90 THEN 1220
1230 B=AO+N15:CT$(B,B)=CHR$(TR)
1240 IF TR<>N3 THEN CT$(AO+N14,AO+N14)=Y$(N1,N1)
1250 ? "Date";:INPUT YI$:IF YI$="" THEN CT$(AO,AO)=CHR$(MO):CT$(AO+N1,AO+N1)=CHR$(DA)
1255 IF YI$="" THEN CT$(AO,AO)=CHR$(MO):CT$(AO+N1,AO+N1)=CHR$(DA):CT$(AO+N2,AO+N2)=CHR$(YR):GOTO 1270
1260 GOSUB 1700:CT$(AO,AO)=CHR$(VAL(Y$(N1,N2))):CT$(AO+N1,AO+N1)=CHR$(VAL(Y$(N4,N5)))
1265 CT$(AO+N2,AO+N2)=CHR$(VAL(Y$(N7,N8)))
1270 TRAP 1270:? "Amount";:INPUT N:NA=N*C/S5:B=AO+N3:CT$(B,B)=CHR$(INT(NA)):NA=(NA-INT(NA))*T56
1275 IF TR=N3 THEN N=-N
1280 CT$(AO+N4,AO+N4)=CHR$(INT(NA)):CT$(AO+N5,AO+N5)=CHR$((NA-INT(NA))*T56)
1285 IF TR=N0 OR TR=N3 THEN Y$="CHKACCNT":GOTO 1320
1290 TRAP 1290:? "Tax";:INPUT TX:M=TX*C/S5:CT$(AO+N18,AO+N18)=CHR$(INT(M))
1295 M=(M-INT(M))*T56:CT$(AO+N19,AO+N19)=CHR$(INT(M))
1300 CT$(AO+N20,AO+N20)=CHR$((M-INT(M))*T56)
1310 TRAP 1310:? "Payee";:INPUT Y$:IF LEN(Y$)<N8 THEN Y$(LEN(Y$)+N1)=BL$
1320 CT$(AO+N6,AO+N13)=Y$
1330 ? "OK";:INPUT Y$:IF Y$(N1,N1)<>"Y" THEN 1100
1340 IF TR=N3 THEN 1380
1350 M=ASC(CT$(AO+N14))-N65:TAX=TAX+TX:NXTCHK=NXTCHK+NXTC:NXTC=N0:IF M=-N1 THEN 1380
1360 A1=180+72*M+(ASC(CT$(AO))-N1)*N6:A2=(ASC(CT$(A1))*S5+(ASC(CT$(A1+N1)))*T56+ASC(CT$(A1+N2))+N*C)/S5
1370 CT$(A1,A1)=CHR$(INT(A2)):A2=(A2-INT(A2))*T56:CT$(A1+N1,A1+N1)=CHR$(INT(A2))
1375 CT$(A1+N2,A1+N2)=CHR$((A2-INT(A2))*T56)
1380 IF TR<N4 THEN CHKBAL=CHKBAL-N
1410 TCNT=TCNT+N1:GOTO 1100
1500 ? "↰":X=TAX*C:GOSUB 1600:? "Sales tax=$";P$:? "Next ";CN$;NXTCHK,B$;:X=CHKBAL*C:GOSUB 1600:? P$
1510 ? "#trans=";TCNT,"Room for ";MCNT-TCNT;" more":? :GOSUB 1650
1520 GOTO 20
1600 IF X<N0 THEN NEG=N1:X=X*-N1
1610 P$=STR$((X+0.1)/C):P$=P$(N1,LEN(P$)-N1):IF X=N0 THEN P$="0.00"
1620 IF NEG THEN P$="-":P$(N2)=STR$((X+0.1)/C):P$=P$(N1,LEN(P$)-N1)
1630 NEG=N0:RETURN
1650 POKE N752,N0:? :? MM$;:INPUT YI$
1660 RETURN
1700 Y$=YI$:IF LEN(YI$)=N6 AND YI$(N4,N4)=S$ THEN Y$(N1,N1)="0":Y$(N2,N3)=YI$(N1,N2):Y$(N4,N4)="0"
1710 IF LEN(YI$)=N6 AND YI$(N4,N4)=S$ THEN Y$(N5,N5)=YI$(N3,N3):Y$(N6,N8)=YI$(N4,N6)
1720 IF LEN(YI$)=N7 AND YI$(N3,N3)=S$ THEN Y$(N1,N3)=YI$(N1,N3):Y$(N4,N4)="0":Y$(N5,N8)=YI$(N4,N7)
1730 IF LEN(YI$)=N7 AND YI$(N2,N2)=S$ THEN Y$(N1,N1)="0":Y$(N2,N8)=YI$(N1,N7)
1740 RETURN
1800 POKE N752,N1:? "↰":FOR N=N0 TO N8:ND=N*N6:POSITION N0,N:? CHR$(N+N64);"-";CT$(ND+N1,ND+N6)
1810 POSITION N16,N:? CHR$(N+73);"-";CT$(ND+55,ND+60):POSITION 30,N:? CHR$(N+82);"-";CT$(ND+109,ND+114)
1820 NEXT N:? :POKE N752,N0:RETURN
1900 B=TAX*C/S5:CT$(171,171)=CHR$(INT(B)):B=(B-INT(B))*T56:CT$(172,172)=CHR$(INT(B))
1905 CT$(173,173)=CHR$((B-INT(B))*T56)
1910 CT$(169,169)=CHR$(INT(NXTCHK/T56)):CT$(170,170)=CHR$((NXTCHK/T56-INT(NXTCHK/T56))*T56)
1920 CT$(166,166)=CHR$(MO):CT$(167,167)=CHR$(DA):CT$(168,168)=CHR$(YR):CT$(163,163)=CHR$(INT(TCNT/T56))
1930 CT$(164,164)=CHR$((TCNT/T56-INT(TCNT/T56))*T56):CT$(165,165)=CHR$(NXTRC):B=CHKBAL*C/S5:R=174
1940 CT$(R,R)=CHR$(INT(B)):B=(B-INT(B))*T56:CT$(175,175)=CHR$(INT(B)):CT$(176,176)=CHR$((B-INT(B))*T56)
1950 ? "Sure('Y')";:INPUT Y$:IF Y$="" THEN 20
1960 IF Y$<>"Y" THEN 20
1970 TRAP 4000:CLOSE #N1:OPEN #N1,N8,N0,"D:BDGTDISK.DAT"
1980 IO=848:POKE IO+N2,N11:N=ADR(CT$)/T56:POKE IO+N4,(N-INT(N))*T56:POKE IO+N5,INT(N):N=LEN(CT$)/T56
1990 POKE IO+N8,(N-INT(N))*T56:POKE IO+N9,INT(N):JNK=USR(ADR("hhh*LVd"),16):CLOSE #1:GOTO 20
2000 ? "↰":? MM$:POKE N82,N6:? :? "1 Set budget"
2010 ? "↓2 Set ";CN$:? "↓3 Name ";C$:? "↓4 Set ";B$:? "↓5 Clear all data.↓"
2020 INPUT N:POKE N82,N0:ON N GOTO 2080,2170,2180,2240,2260
2080 TRAP 2080:? "↰":? C$:INPUT YI$:IF YI$="" THEN 2250
2090 IF ASC(YI$(N1,N1))<N64 OR ASC(YI$(N1,N1))>N90 THEN 2080
2100 ? "MONTH(A=ALL)":INPUT STM$:IF STM$="A" THEN 2120
2110 STM=VAL(STM$)-N1:IF STM<N0 OR STM>N11 THEN 2100
2120 ? "AMOUNT":INPUT N:N=N*C/S5:A1=177+72*(ASC(YI$(N1,N1))-N65)
2130 IF STM$="A" THEN FOR STM=N0 TO N11
2140 R=A1+STM*N6:CT$(R,R)=CHR$(INT(N)):M=(N-INT(N))*T56:CT$(R+N1,R+N1)=CHR$(INT(M))
2150 CT$(R+N2,R+N2)=CHR$((M-INT(M))*T56):IF STM$="A" THEN NEXT STM
2160 GOTO 2080
2170 TRAP 2170:? "Enter next ";CN$:INPUT NXTCHK:GOTO 2250
2180 GOSUB 1800:? C$;",e.g.'A-AUTOMO'":INPUT YI$:IF YI$="" THEN 2250
2190 IF YI$(N2,N2)<>"-" OR YI$(N1,N1)<"@" OR YI$(N1,N1)>"Z" THEN 2180
2200 IF LEN(YI$)<N8 THEN YI$(LEN(YI$)+N1,N8)=BL$
2210 PA=N1+(ASC(YI$)-N64)*N6:CT$(PA,PA+N5)=YI$(N3)
2230 GOTO 2180
2240 TRAP 2240:? "Bal=";:INPUT CHKBAL
2250 GOTO 20
2260 CT$(163)=CHR$(N0):CT$(2048)=CHR$(N0):CT$(164)=CT$(163):TCNT=N0:GOTO 20
4000 TRAP 4000:ERR=PEEK(195):IF ERR<>170 THEN 4050
4010 ? "↰↓Input file D:BDGTDATA.DAT":? "is not on this disk.↰↓":? "Shall I create an empty one Y←←";
4020 INPUT STA$:IF STA$<>"Y" THEN GRAPHICS N0:END
4030 CT$(N1)=" ":CT$(162)=" ":CT$(N2)=CT$:CT$(163)=CHR$(N0):CT$(2048)=CHR$(N0):CT$(164)=CT$(163)
4040 GOTO 5170
4050 ? "Error # ";ERR:IF LEN(CT$)<2048 THEN GRAPHICS N0:END
4060 GOSUB 1650:GOTO 20
5000 CLR :N1=1:N0=0:N2=N1+N1:N3=N1+N2:N4=N2+N2:N5=N4+N1:N6=N3+N3:N7=N4+N3:N8=N4+N4:N9=N4+N5:N10=N5+N5
5005 BRK=N1:IF PEEK(53279)=N5 THEN BRK=N0
5010 N11=N5+N6:N12=N7+N5:N13=N9+N4:N14=N9+N5:N15=N7+N8:N16=N8+N8:N17=N9+N8:N18=N9+N9:N19=N9+10:N20=N4*N5
5020 N21=N7*N3:N25=N5*N5:N33=N11*N3:N64=N8*N8:N65=N64+N1:N78=N65+N13:N82=N78+N4:N90=N10*N9:C=N10*N10
5030 T56=N64*N4:N752=752:T53=53279:S5=T56*T56:GRAPHICS N18
5040 POSITION N5,N3:? #N6;"BUDGET-DB":POSITION N8,N5:? #N6;"BY":POSITION N4,N7:? #N6;"J.R.KEARNEY"
5050 DIM Y$(N8),Z$(36),P$(N9),STA$(N1),STM$(N2),BL$(N7),YI$(N8),S$(N1),NC$(N12),PW$(N11),PL$(77)
5060 DIM B$(N9),C$(N8),CN$(N6),MM$(N16),SM$(N12),PR$(N1):S$="/":BL$=" "
5070 Z$="JANFEBMARAPRMAYJUNJULAUGSEPOCTNOVDEC":PW$="PLEASE WAIT":NC$=" NOT CLEARED":C$="Category"
5080 B$="Balance=$":CN$="check#":MM$="RETURN=main menu":SM$="Start month=":Y=N0
5100 DSIZE=FRE(N0)-1096:IF DSIZE>32766 THEN DSIZE=32767
5120 MCNT=INT((DSIZE-2048)/N21):DIM CT$(DSIZE):CT$(DSIZE)="0":TRAP 4000
5130 OPEN #N1,N4,N0,"D:BDGTDISK.DAT":IO=848:POKE IO+N2,N7:N=ADR(CT$)/T56:POKE IO+4,(N-INT(N))*T56
5135 POKE IO+N5,INT(N)
5140 POKE IO+N8,N0:POKE IO+N9,255:JNK=USR(ADR("hhh*LVd"),16):CLOSE #1
5150 CT$=CT$(N1,PEEK(IO+N8)+PEEK(IO+N9)*T56)
5170 CHKBAL=(ASC(CT$(174))*S5+ASC(CT$(175))*T56+ASC(CT$(176)))/C
5180 TCNT=ASC(CT$(163))*T56+ASC(CT$(164)):NXTRC=ASC(CT$(165)):NXTCHK=ASC(CT$(169))*T56+ASC(CT$(170))
5190 TAX=(ASC(CT$(171))*S5+ASC(CT$(172))*T56+ASC(CT$(173)))/C
5200 MO=ASC(CT$(166)):DA=ASC(CT$(167)):YR=ASC(CT$(168))
5220 GRAPHICS N0:GOSUB 500:POKE 710,51:POKE 712,51:? "LAST DATE RUN=";MO;S$;DA;S$;YR:? "TODAY'S DATE";
5230 TRAP 5220:INPUT YI$:IF LEN(YI$)<N6 OR LEN(YI$)>N8 THEN ? "↓FORMAT='MO/DA/YR'↰↰":GOTO 5220
5240 GOSUB 1700:YI$(N1,N1)=CHR$(VAL(Y$(N1,N2))):MO=VAL(Y$(N1,N2)):DA=VAL(Y$(N4,N5)):YR=VAL(Y$(N7,N8))
5250 CT$(166,166)=CHR$(MO):CT$(167,167)=CHR$(DA):CT$(168,168)=CHR$(YR)
5260 GOTO 20
5300 ? "Sure";:INPUT Y$:IF Y$="" THEN 20
5310 IF Y$="Y" THEN POKE 82,2:GRAPHICS N0:END
5320 GOTO 20
