Weather Calc (WX.BAS)

Weather Calc by Jan Null

Description

Weather Calc by Jan Null

From the Antic disk of September 1986 (Vol. 5 No. 5).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 7.3 KB

Dialect
Atari BASIC
Lines
173
Variables
SS$, SR$, B, A, F, C, K, R, DRY, WET, PRES, DRY1, WET1, PRES1, VP1, TEMP, VP, VP2, RH, X, DP, DPF, CLDS, WIND, CHILL, D1, M1, D2, M2, M, D, Y, LAT, LON, YR, LEAP, DAY, T1, T2, MM1, MM2, L1, L2, TAN1, TAN2, A1, A2, L11, L22, SN1, SN2, CS1, CS2, X1, H1, X2, H2, RISE, SET, MIN1, MIN2
BASIC listing (173 lines)
10 REM WEATHER CALC
20 REM BY JAN NULL,
30 REM NATIONAL WEATHER SERVICE
40 REM (c) 1986, ANTIC PUBLISHING
50 CLOSE #4:OPEN #4,4,0,"K:"
60 DIM SS$(5),SR$(5)
400 REM MAIN MENU
405 GRAPHICS 0
410 ? "         WEATHER MENU":? :?
420 ? "1. TEMPERATURE":? "2. DEW POINT/RELATIVE HUMIDITY"
430 ? "3. WIND CHILL":? "4. SUNRISE/SUNSET":? "5. END"
440 GOSUB 500:GRAPHICS 0:ON B GOTO 1000,2000,5000,6000,550
500 REM OPTION SELECT SUBROUTINE
510 ? :? "SELECT OPTION:";:GET #4,A:? CHR$(A):TRAP 500:B=VAL(CHR$(A)):TRAP 20000:RETURN
550 GRAPHICS 0:END
1000 REM TEMPERATURE
1010 GRAPHICS 0:? "              TEMPERATURE MENU"
1020 ? :? :? "1. CONVERSION FROM FAHRENHEIT":? "2. CONVERSION FROM CELSIUS":? "3. RETURN TO MAIN MENU"
1030 GOSUB 500:ON B GOTO 1100,1300,405
1100 GRAPHICS 0:? "         FAHRENHEIT CONVERSIONS"
1110 ? :? :? "ENTER FAHRENHEIT TEMPERATURE ";:TRAP 1110:INPUT F
1120 C=(F-32)*(5/9)
1130 K=INT((C+273.16)*100+0.5)/100
1140 R=INT((F+459.69)*100+0.5)/100
1145 C=INT(C*100+0.5)/100
1150 ? :? "CELSIUS TEMPERATURE= ";C
1160 ? :? "KELVIN TEMPERATURE= ";K
1170 ? :? "RANKIN TEMPERATURE= ";R
1180 ? :? :? :? "RETURN FOR MAIN MENU":?
1190 ? "ANY OTHER KEY TO CONTINUE"
1200 GET #4,A:IF A=155 THEN 400
1210 ? "WOULD YOU LIKE ANOTHER FAHRENHEIT CONVERSION? (Y/N)"
1220 GET #4,A:IF A=89 THEN 1100
1230 GOTO 1010
1300 GRAPHICS 0:? "         CELSIUS CONVERSIONS"
1310 ? :? :? "ENTER CELSIUS TEMPERATURE ";:TRAP 1310:INPUT C
1320 F=C*9/5+32
1330 K=INT((C+273.16)*100+0.5)/100
1340 R=INT((F+459.69)*100+0.5)/100
1345 F=INT(F*100+0.5)/100
1350 ? :? "FAHRENHEIT TEMPERATURE= ";F
1360 ? :? "KELVIN TEMPERATURE= ";K
1370 ? :? "RANKIN TEMPERATURE= ";R
1380 ? :? :? :? "RETURN FOR MAIN MENU":?
1390 ? "ANY OTHER KEY TO CONTINUE"
1400 GET #4,A:IF A=155 THEN 400
1410 ? "WOULD YOU LIKE ANOTHER CELSIUS CONVERSION? (Y/N)"
1420 GET #4,A:IF A=89 THEN 1300
1430 GOTO 1010
2000 REM DEW POINT/RH
2010 GRAPHICS 0:? "    DEW POINT/RELATIVE HUMIDITY"
2020 ? :? "ENTER DRY BULB TEMPERATURE (DEGREES F)":INPUT DRY
2030 ? :? "ENTER WET BULB TEMPERATURE (DEGREES F)":INPUT WET
2040 PRES=30
2050 DRY1=((5/9)*(DRY-32))+273.16
2060 WET1=((5/9)*(WET-32))+273.16
2070 PRES1=PRES/0.02953
2080 VP1=6.108*EXP((17.27*(WET1-273.16))/(WET1-35.86))
2090 TEMP=3.67E-04*PRES1*(DRY-WET)*(1+((WET-32)/1571))
2100 VP=VP1-TEMP
2110 VP2=6.108*EXP((17.27*(DRY1-273.16))/(DRY1-35.86))
2120 RH=(100*VP)/VP2:IF RH<0 OR RH>100 THEN ? "RH OUT OF RANGE";:GOTO 2020
2130 X=LOG((RH*VP2)/610.8)/17.27
2140 DP=(273.16-(35.86*X))/(1-X)
2150 DPF=(DP-273.16)*9/5+32:DPF=INT(DPF+0.5)
2160 CLDS=INT(0.5+(225*(DRY-DPF)))
2170 ? :? "DEW POINT= ";DPF
2180 ? "RELATIVE HUMIDITY= ";:RH=INT(RH+0.5):? RH;" %"
2190 ? "ESTIMATED CLOUD BASES= ";CLDS;" FT"
2200 ? :? :? :? :? :? :? "RETURN FOR MAIN MENU"
2210 ? "ANY OTHER KEY FOR ANOTHER DEW POINT/RH CALCULATION"
2220 GET #4,A:IF A=155 THEN 400
2230 GOTO 2010
5000 REM WIND CHILL
5010 GRAPHICS 0:? "        WIND CHILL FACTOR"
5020 ? :? :? "ENTER AIR TEMPERATURE (DEGREES F)":TRAP 5020:INPUT TEMP:IF TEMP>100 OR TEMP<-80 THEN 5020
5030 ? :? "ENTER WIND SPEED (MPH)           ":TRAP 5030:INPUT WIND:IF WIND>150 OR WIND<0 THEN 5030
5035 IF WIND<4 THEN WIND=4
5036 IF WIND>50 THEN WIND=50
5040 CHILL=0.0817*(3.71*SQR(WIND)+5.81-0.25*WIND)*(TEMP-91.4)+91.4
5050 CHILL=INT((CHILL*100+0.5)/100)
5052 GRAPHICS 0:? "       WIND CHILL FACTOR":? :?
5055 ? "TEMPERATURE: ";TEMP
5056 ? "WIND SPEED : ";WIND:? :?
5060 ? :? "WIND CHILL FACTOR IS:  ";CHILL
5070 IF CHILL<31 AND CHILL>15 THEN ? :? "          COLD"
5080 IF CHILL<16 AND CHILL>0 THEN ? :? "          VERY COLD"
5090 IF CHILL<1 AND CHILL>-20 THEN ? :? "          BITTER COLD"
5100 IF CHILL<-19 THEN ? :? "          EXTREME COLD"
5110 ? :? :? :? :? :? :? :? :? "RETURN FOR MAIN MENU"
5120 ? :? "ANY OTHER KEY TO CONTINUE"
5130 GET #4,A:IF A=155 THEN 400
5140 GOTO 5010
6000 REM SUNRISE/SUNSET
6005 GRAPHICS 0:? "        SUNRISE/SUNSET":? :?
6010 ? "ENTER LATITUDE (DEGREES,MIN)":TRAP 6010:INPUT D1,M1:IF D1<0 OR D1>90 OR M1<0 OR M1>59.9 THEN 6010
6020 ? "ENTER LONGITUDE (DEGREES,MIN)":TRAP 6020:INPUT D2,M2:IF D2<0 OR D2>180 OR M2<0 OR M2>59.9 THEN 6020
6030 ? "ENTER DATE (Month, Day, Year)":TRAP 6030:INPUT M,D,Y
6032 IF M<1 OR M>12 OR D<1 OR D>31 OR Y<0 THEN 6030
6035 ? :? :? "CALCULATING"
6040 LAT=D1+M1/60
6050 LON=D2+M2/60
6060 YR=(Y/4)-INT(Y/4)
6070 IF YR<>0 THEN 6100
6080 IF ((Y/400)-INT(Y/400)=0) THEN 6100
6090 LEAP=1:GOTO 6120
6100 LEAP=2
6120 DAY=INT((275*M)/9)-LEAP*INT((M+9)/12)+D-30
6125 DEG
6130 T1=DAY+(6+LON/15)/24
6140 T2=DAY+(18+LON/15)/24
6145 MM1=M1:MM2=M2
6150 M1=0.9856*T1-3.251
6160 M2=0.9856*T2-3.251
6180 L1=M1+1.916*SIN(M1)+0.02*SIN(M1*2)+282.565
6190 L2=M2+1.916*SIN(M2)+0.02*SIN(M2*2)+282.565
6200 TAN1=0.91746*(SIN(L1)/COS(L1))
6210 TAN2=0.91746*(SIN(L2)/COS(L2))
6220 A1=(ATN(TAN1))
6230 A2=(ATN(TAN2))
6240 REM QUADRANT CONVERSIONS
6242 IF L1>360 THEN L1=L1-360
6243 IF L2>360 THEN L2=L2-360
6244 IF L1<0 THEN L1=L1+360
6245 IF L2<0 THEN L2=L2+360
6250 L11=INT(L1/90)+1
6260 L22=INT(L2/90)+1
6270 A2=ABS(A2):A1=ABS(A1)
6290 IF L11=2 THEN A1=A1+(2*(90-A1))
6300 IF L11=3 THEN A1=(3*A1)+(2*(90-A1))
6310 IF L11=4 THEN A1=(3*A1)+(4*(90-A1))
6320 IF L22=2 THEN A2=A2+(2*(90-A2))
6330 IF L22=3 THEN A2=(3*A2)+(2*(90-A2))
6340 IF L22=4 THEN A2=(3*A2)+(4*(90-A2))
6350 A1=A1/15
6360 A2=A2/15
6370 SN1=0.39782*SIN(L1)
6380 SN2=0.39782*SIN(L2)
6390 CS1=ABS(COS(ATN(SN1/SQR(-SN1*SN1+1))))
6400 CS2=ABS(COS(ATN(SN2/SQR(-SN2*SN2+1))))
6410 X1=(COS(90.8333)-SN1*SIN(LAT))/(CS1*COS(LAT)):H1=90-ATN(X1/SQR(-X1*X1+1))
6420 X2=(COS(90.8333)-SN2*SIN(LAT))/(CS2*COS(LAT)):H2=90-ATN(X2/SQR(-X2*X2+1))
6430 H1=360-H1:H1=H1/15
6440 H2=H2/15
6450 RISE=H1+A1-(0.0657*T1)-6.62:RISE=RISE+(LON/15)-INT(LON/15)
6460 SET=H2+A2-(0.06571*T2)-6.62:SET=SET+(LON/15)-INT(LON/15)
6470 IF RISE<0 THEN RISE=RISE+24
6480 IF SET<0 THEN SET=SET+24
6490 IF RISE>24 THEN RISE=RISE-24
6493 IF INT(RISE)<12 THEN 6498
6494 RISE=RISE-12:SR$="P.M.":GOTO 6500
6498 SR$="A.M."
6500 IF SET>24 THEN SET=SET-24
6503 IF INT(SET)<12 THEN 6508
6504 SET=SET-12:SS$="P.M.":GOTO 6510
6508 SS$="A.M."
6510 GRAPHICS 0:? "       SUNRISE/SUNSET":? :? :? :?
6512 ? "LAT :  ";D1;" DEG, ";MM1;" MIN"
6514 ? "LONG:  ";D2;" DEG, ";MM2;" MIN"
6516 ? "DATE:  ";M;"/";D;"/";Y:? :?
6520 MIN1=(RISE-INT(RISE))*60:IF INT(MIN1)<10 THEN GOTO 6560
6530 ? "SUNRISE: ";INT(RISE);":";INT(MIN1);" ";SR$;" LOCAL STANDARD TIME"
6540 MIN2=(SET-INT(SET))*60:IF INT(MIN2)<10 THEN 6570
6550 ? "SUNSET : ";INT(SET);":";INT(MIN2);" ";SS$;" LOCAL STANDARD TIME":GOTO 6590
6560 ? "SUNRISE: ";INT(RISE);":0";INT(MIN1);" ";SR$;" LOCAL STANDARD TIME":GOTO 6540
6570 ? "SUNSET : ";INT(SET);":0";INT(MIN2);" ";SS$;" LOCAL STANDARD TIME"
6590 ? :? "ADD ONE HOUR FOR DAYLIGHT SAVINGS TIME":?
6600 ? :? :? "RETURN FOR MAIN MENU":?
6610 ? "ANY OTHER KEY TO CONTINUE"
6620 GET #4,A:IF A=155 THEN 400
6630 ? "WOULD YOU LIKE TO USE THE SAME LATITUDE AND LONGITUDE (Y/N)"
6640 GET #4,A:IF A=89 THEN GRAPHICS 0:? "       SUNRISE/SUNSET":M1=MM1:M2=MM2:GOTO 6030
6650 GOTO 6010