New Owner's Column #6 (NEWOWN6.BAS)

New Owner's Column #6 by David Plotkin, 29

Description

New Owner's Column #6 by David Plotkin, 29

From the Antic disk of September 1986 (Vol. 5 No. 5).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.7 KB

Dialect
Atari BASIC
Lines
32
Variables
STX(, STY(, X, Y, KNTR, ST, Z, LP, DT, DRCTN
BASIC listing (32 lines)
1 REM THE NEW OWNERS COLUMN, PART 6
2 REM BY DAVID PLOTKIN
3 REM (c) 1986, ANTIC PUBLISHING
10 GRAPHICS 7:COLOR 1:DIM STX(15),STY(15):X=79:Y=39:POKE 752,1:PRINT "PRESS START TO FILL"
15 GOSUB 1200:COLOR 1:PLOT 0,0:DRAWTO 159,0:DRAWTO 159,79:DRAWTO 0,79:DRAWTO 0,0
17 PLOT 79,24:DRAWTO 59,54:DRAWTO 99,54
19 DRAWTO 92,44:DRAWTO 92,14:DRAWTO 90,14:DRAWTO 90,24:DRAWTO 86,24:DRAWTO 86,34:DRAWTO 79,24:KNTR=0
20 COLOR 1:PLOT X,Y:ST=PEEK(632)
30 IF STRIG(0)=1 AND PEEK(53279)<>6 THEN X=X+STX(ST):Y=Y+STY(ST):COLOR 0:PLOT X-STX(ST),Y-STY(ST):GOTO 20
40 X=X+STX(ST):Y=Y+STY(ST):PLOT X,Y:IF PEEK(53279)=6 THEN GOTO 200
50 GOTO 20
200 ? CHR$(125):POKE 657,3:POKE 656,1:? "WORKING ON RECURSION #"
205 COLOR 2:GOSUB 1000
210 POKE 656,0:POKE 657,0:PRINT "↰PRESS START TO RERUN THIS PROGRAM"
220 IF PEEK(53279)<>6 THEN 220
230 RUN
999 END
1000 KNTR=KNTR+1:DRCTN=1:GOSUB 2000:POKE 77,0:PLOT X,Y:X=X-1:LOCATE X,Y,Z:IF Z=0 THEN GOSUB 1000
1030 X=X+1:Y=Y-1:LOCATE X,Y,Z:IF Z=0 THEN GOSUB 1000
1060 Y=Y+1:X=X+1:LOCATE X,Y,Z:IF Z=0 THEN GOSUB 1000
1090 X=X-1:Y=Y+1:LOCATE X,Y,Z:IF Z=0 THEN GOSUB 1000
1120 Y=Y-1
1130 KNTR=KNTR-1:DRCTN=0:GOSUB 2000:RETURN
1200 FOR LP=5 TO 15:READ DT:STX(LP)=DT:NEXT LP
1210 DATA 1,1,1,0,-1,-1,-1,0,0,0,0
1220 FOR LP=5 TO 15:READ DT:STY(LP)=DT:NEXT LP
1230 DATA 1,-1,0,0,1,-1,0,0,1,-1,0
1240 RETURN
2000 POKE 656,1:POKE 657,25:? KNTR;"   ";:POKE 657,30
2010 IF DRCTN=1 THEN ? "(GOSUB) "
2020 IF DRCTN=0 THEN ? "(RETURN) "
2030 RETURN