File Master v5.0, disk utility (FILEMSTR.BAS)

File Master v5.0, disk utility by Jason Worley, 96

Description

File Master v5.0, disk utility by Jason Worley, 96

From the Antic disk of August 1986 (Vol. 5 No. 4).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 11.6 KB

Dialect
Atari BASIC
Lines
273
Variables
C, A, COUNT, LC, P, AREA$, L, SAV$, B, D1$, DN, X, TONE, Z, N, V, SR$, INSR$, CH, D$, FNC$, LABEL, PSW, DISKS, FILE$, D, LOC, LINES, INCH$, CH$, SOR$, MAXSIZE
BASIC listing (273 lines)
10 REM FILE MASTER - VERSION 5.0
20 REM BY JASON WORLEY
30 REM (c) 1986, ANTIC PUBLISHING
50 GOTO 2580
60 C=INT(C/3)+1:FOR A=1 TO COUNT-C:LC=A*20-20+P
70 IF AREA$(LC,LC+L-1)<=AREA$(LC+(20*C),LC+(20*C)+L-1) THEN 120
80 SAV$(1,20)=AREA$((A+C)*20-19):B=A
90 AREA$((B+C)*20-19,(B+C)*20)=AREA$(B*20-19):B=B-C
100 IF B>0 THEN IF SAV$(P,P+L-1)<AREA$(B*20-20+P) THEN 90
110 AREA$((B+C)*20-19,(B+C)*20)=SAV$(1,20)
120 NEXT A:IF C>1 THEN 60
130 RETURN
140 REM PRINT LABEL SUBROUTINE
150 TRAP 180:? "Disk Name";:INPUT D1$
160 LPRINT D1$:LPRINT "Disk #";DN
170 FOR X=1 TO 4:LPRINT :NEXT X:RETURN
180 ? :? "Make sure printer is on and connected":GOSUB 220:POP :GOTO 680
190 REM SUBROUTINE FOR SOUNDS
200 TONE=14:GOTO 230:REM PROMPT TONE
210 TONE=2:GOTO 230:REM ATTEN TONE
220 TONE=4:REM DANGER TONE
230 FOR Z=1 TO 15:SOUND 0,10,TONE,12:NEXT Z
240 FOR Z=39 TO 1 STEP -1:SOUND 0,10,TONE,Z/3:NEXT Z
250 SOUND 0,0,0,0:RETURN
260 REM
270 ? "↰   No records in memory!":GOSUB 220
280 FOR X=1 TO 200:NEXT X:GOTO 1950
290 REM SORT SUBROUTINE
300 IF COUNT=0 THEN GOTO 270
310 TRAP 40000:N=3:CLOSE #4:OPEN #4,4,0,"K:"
320 ? "↰Total number of records is ";COUNT
330 ? "Sort by:"
340 FOR V=0 TO 4
350 POSITION 12,V+3:? SR$(V*14+1,V*14+14):NEXT V
360 POSITION 12,N:? INSR$((N-3)*14+1,(N-3)*14+14)
370 POKE 764,255:GET #4,CH
380 IF CH=45 THEN IF N>3 THEN N=N-1:POSITION 12,N+1:? SR$((N-2)*14+1,(N-2)*14+14):GOTO 360
390 IF CH=45 THEN POSITION 12,3:? SR$(1,14):N=7:GOTO 360
400 IF CH=61 THEN IF N<7 THEN N=N+1:POSITION 12,N-1:? SR$((N-4)*14+1,(N-4)*14+14):GOTO 360
410 IF CH=61 THEN POSITION 12,7:? SR$(57,70):N=3:GOTO 360
420 IF CH<>155 THEN 360
430 IF N=3 THEN L=3:P=12
440 IF N=4 THEN L=1:P=20
450 IF N=5 THEN L=14:P=1
460 IF N=6 THEN L=12:P=4
470 IF N=7 THEN L=3:P=16
480 POSITION 2,10:? " Sort will take ";INT(COUNT*(COUNT/500)+6);" seconds "
490 FOR X=1 TO 200:NEXT X:POKE 559,0:REM TURN OFF SCREEN
500 TRAP 40000:C=COUNT
510 GOSUB 60
520 POKE 559,34:? " Sort completed "
530 GOSUB 210:REM ATTN SOUND
540 FOR Z=1 TO 200:NEXT Z:RETURN
550 REM
560 ? :? "Press [RETURN] to continue...";:INPUT #16,D$:RETURN
570 ? :? FNC$;" Aborted by request.":GOSUB 560:RETURN
580 REM ADD RECORDS SUBROUTINE
590 ? "↰Do you wish to print disk labels";:INPUT D$:IF D$="Y" THEN LABEL=1
600 IF LABEL THEN ? "Ready printer, press [RETURN].":INPUT #16,D$
610 ? "Do you want to enter the type"
620 ? "  of each file (Y or N)";
630 TRAP 610:INPUT D$
640 IF D$<>"Y" THEN 680
650 PSW=1:? :? "E - Educational      F - DataFile":? "U - Utility          B - Business"
660 ? "H - Household        G - Game":? "P - Practical        M - Music"
670 ? "V - VisiCalc         D - Demo":? "L - Language"
680 ? " Insert next disk and enter disk"
690 ? " number. Type 'END' to go to Menu"
700 TRAP 680
710 INPUT #16,D$:IF LEN(D$)=0 THEN 680
720 IF D$="END" THEN 990
730 DN=VAL(D$)
740 IF LEN(D$)<>1 THEN 760
750 D$(3,3)=D$(1,1):D$(1,2)="00"
760 IF LEN(D$)<>2 THEN 780
770 D$(3,3)=D$(2,2):D$(2,2)=D$(1,1):D$(1,1)="0"
780 DISKS=DISKS+1:TRAP 940
790 FILE$="D":FILE$(2)=STR$(D):FILE$(3)=":*.*":OPEN #1,6,0,FILE$
800 INPUT #1;FILE$:? FILE$,:IF PSW=0 THEN ?
810 IF FILE$(5,9)="FREE " THEN 940
820 IF FILE$(3,6)="DOS " OR FILE$(3,6)="DUP " THEN 920
830 IF FILE$(3,7)="MENU " THEN 920
840 SAV$=" ":IF PSW=0 THEN 870
850 TRAP 40000:POKE 764,255:? "Program Type";:INPUT SAV$
860 IF SAV$="*" THEN 930
870 FILE$(18,20)=", ":FILE$(19,19)=SAV$
880 COUNT=COUNT+1
890 LOC=COUNT*20-19:AREA$(LOC,LOC+2)=D$
900 AREA$(LOC+3,LOC+19)=FILE$(3,19)
910 AREA$(LOC+14,LOC+14)=",":GOTO 800
920 IF PSW=0 THEN 800
930 ? "**Bypassed**":GOTO 800
940 ? :? " End of directory, this disk "
950 ? COUNT;" Total records.":?
960 POKE 764,255:GOSUB 210
970 IF LABEL THEN GOSUB 150
980 CLOSE #1:GOTO 680
990 REM END OF FILE;
1000 ? :? "Records added: ";COUNT
1010 ? "Disks input:  ";DISKS
1020 GOSUB 210
1030 PSW=0:FOR X=1 TO 250:NEXT X:RETURN
1040 REM DISPLAY/PRINT RECORDS
1050 IF COUNT=0 THEN 270
1060 IF N=3 THEN TRAP 1440:OPEN #3,8,0,"P:":PSW=1:GOTO 1080
1070 OPEN #3,8,0,"S:":SETCOLOR 2,9,0
1080 LINES=0:POKE 752,1:GOSUB 1390
1090 FOR X=1 TO COUNT:FILE$(1,20)=AREA$(X*20-19,X*20)
1100 IF PSW=1 THEN ? #3;""
1110 ? #3;" ";FILE$(1,3);"  ";FILE$(4,11);"   ";FILE$(12,14);
1120 ? #3;"   ";FILE$(16,18);"  ";
1130 D$=FILE$(20,20):IF D$=" " THEN SAV$="        ":REM 8 SPACES
1140 SAV$=D$
1150 IF D$="E" THEN SAV$="Educational"
1160 IF D$="F" THEN SAV$="Datafile"
1170 IF D$="U" THEN SAV$="Utility"
1180 IF D$="B" THEN SAV$="Business"
1190 IF D$="S" THEN SAV$="System"
1200 IF D$="H" THEN SAV$="Household"
1210 IF D$="G" THEN SAV$="Game"
1220 IF D$="P" THEN SAV$="Practical"
1230 IF D$="M" THEN SAV$="Music"
1240 IF D$="V" THEN SAV$="VisiCalc"
1250 IF D$="D" THEN SAV$="Demo"
1260 IF D$="L" THEN SAV$="Language"
1270 ? #3;SAV$
1280 IF (PSW=0 AND LINES=16) THEN GOSUB 1330
1290 IF (PSW=1 AND LINES=52) THEN GOSUB 1350
1300 LINES=LINES+1:NEXT X
1310 IF PSW=1 THEN ? "↰"
1311 ? :? ,"End of file":GOSUB 560
1320 GOTO 1470
1330 IF PEEK(53279)=6 THEN 1480
1340 GOSUB 560
1350 IF PEEK(53279)=6 THEN 1480
1360 IF PEEK(53279)=6 THEN 1480
1370 IF PSW=1 THEN FOR Z=1 TO 8:? #3:NEXT Z:GOTO 1390
1380 ? #3;"↰"
1390 IF PSW=1 THEN ? #3;""
1400 ? #3;"      File Master Index":? #3:? #3
1410 LINES=0:IF PSW=1 THEN ? #3;""
1420 ? #3;"Disk# Prog.Name  XTen  Size Filetype"
1430 RETURN
1440 ? "↰":? ,"Turn The Printer On! "
1450 GOSUB 220
1460 FOR X=1 TO 100:NEXT X
1470 TRAP 40000:CLOSE #3:POKE 752,0:PSW=0:RETURN
1480 GOSUB 570:GOTO 1450
1490 REM SAVE SUBROUTINE
1500 IF COUNT=0 THEN GOTO 270
1510 GOSUB 2510
1520 TRAP 1570:OPEN #2,9,0,FILE$
1530 ? "↰";FILE$;" already exists, write over it";:INPUT D$
1540 GOSUB 220
1550 IF D$="Y" THEN CLOSE #2:OPEN #2,8,0,FILE$:GOTO 1580
1560 GOTO 1950
1570 CLOSE #2:OPEN #2,8,0,FILE$
1580 C=0:FOR X=1 TO COUNT
1590 IF PEEK(53279)=6 THEN FNC$="Save":GOSUB 570:GOTO 1630
1600 FILE$(1,20)=AREA$(X*20-19,X*20)
1610 IF FILE$(1,1)="*" THEN C=C+1:NEXT X:GOTO 1630
1620 PRINT #2;FILE$:NEXT X
1630 CLOSE #2:? X-C-1;" Records written":? C;" Records dropped":FOR X=1 TO 300:NEXT X:RETURN
1640 REM LOAD SUBROUTINE
1650 GOSUB 2510
1660 TRAP 1760:OPEN #2,4,0,FILE$
1670 TRAP 1790
1680 ? "↰       File Master Index"
1690 ? "DISK#  PROG.NAME  XTEN  SIZE"
1700 INPUT #2;FILE$:COUNT=COUNT+1
1710 ? "  ";FILE$(1,3);"  ";FILE$(4,11);"   ";FILE$(12,14);
1720 ? "   ";FILE$(16,18);"     ";FILE$(20,20)
1730 AREA$(COUNT*20-19,COUNT*20)=FILE$
1740 IF PEEK(53279)=6 THEN ? :? " Load aborted at your request.":GOTO 1770
1750 GOTO 1700
1760 TRAP 40000:CLOSE #2:? "↰ File Not Found "
1770 GOSUB 220
1780 FOR X=1 TO 200:NEXT X:RETURN
1790 IF PEEK(195)<>136 THEN ? "Error ";PEEK(195);" On Load.":FOR Z=1 TO 300:NEXT Z:GOTO 1950
1800 ? ,"   End of file reached."
1810 GOSUB 560:REM PRESS [RETURN]
1820 CLOSE #2:GOTO 1950
1830 REM DELETE FILE SUBROUTINE
1840 GOSUB 2510
1850 GOSUB 220:REM DANGER TONE
1860 ? "This will delete all contents of":? "file ";FILE$;", Press Y to":? "delete it, N t return to Menu"
1870 INPUT #16,D$
1880 IF D$<>"Y" THEN RETURN
1890 TRAP 1930:XIO 33,#3,0,0,FILE$
1900 ? :? "File:";FILE$;" Deleted."
1910 GOSUB 210:REM ATTEN TONE
1920 FOR X=1 TO 200:NEXT X:RETURN
1930 ? #6;"File doesn't exist.":GOSUB 220:RETURN
1940 REM MAIN MENU
1950 TRAP 1950:? "↰","   Jason Worley's"
1960 SETCOLOR 2,9,0:POKE 752,1
1970 N=3:CLOSE #4:OPEN #4,4,0,"K:"
1980 ? ," Program Indexing"
1990 ?
2000 ? ,"    Add Records"
2010 ? ,"Display Indexes On Screen"
2020 ? ,"  Print Indexes In Memory"
2030 ? ,"   Sort Indexes In Memory"
2040 ? ,"   Save Indexes To Disk"
2050 ? ,"   Load Indexes From Disk"
2060 ? ," Delete Index Disk File"
2070 ? ," Delete Index From Memory"
2080 ? ,"  Clear Memory"
2090 ? ,"   Exit Program"
2100 ? ,"Display Current Directory"
2110 ? ," Change Drive Number"
2120 POSITION 11,22:? " Records In Memory =  ";COUNT
2130 POSITION 12,N:? INCH$((N-3)*7+1,(N-3)*7+7)
2140 POKE 764,255:FOR X=1 TO 10:GET #4,CH
2142 IF CH=28 THEN CH=45
2144 IF CH=29 THEN CH=61
2145 IF  NOT (CH=45 OR CH=61 OR CH=155) THEN 2140
2150 IF CH=45 THEN IF N>3 THEN N=N-1:POSITION 12,N+1:? CH$((N-2)*7+1,(N-2)*7+7):GOTO 2130
2160 IF CH=45 THEN POSITION 12,3:? CH$(1,7):N=14:GOTO 2130
2170 IF CH=61 THEN IF N<14 THEN N=N+1:POSITION 12,N-1:? CH$((N-4)*7+1,(N-4)*7+7):GOTO 2130
2180 IF CH=61 THEN POSITION 12,14:? CH$(78,84):N=3:GOTO 2130
2190 IF CH=155 THEN N=N-2:ON N GOSUB 590,1050,1050,300,1500,1650,1840,2290,2210,2260,2460,2550
2200 GOTO 1950
2210 ? :? "↰Zeroing Memory Will Destroy All"
2220 ? "Entries That Are Not Saved On Disk."
2230 ? "(Y=Zero memory, N=Main menu)":? "Continue";:INPUT D$:IF D$="Y" THEN 2250
2240 RETURN
2250 CLR :GOTO 2620
2260 ? "↰End program";:INPUT D$:IF D$="Y" THEN GRAPHICS 0:END
2270 RETURN
2280 REM DELETE FROM MEMORY
2290 IF COUNT=0 THEN GOTO 270
2300 ? "↰        Deleting Records"
2310 ? "An Entire Disks Index May Be":? "Deleted By Entering That Number Now.":? "Press [RETURN] To Exit."
2320 TRAP 40000:INPUT #16,D$:IF LEN(D$)=0 THEN RETURN
2330 IF LEN(D$)<>1 THEN 2350
2340 D$(3,3)=D$(1,1):D$(1,2)="00"
2350 IF LEN(D$)<>2 THEN 2370
2360 D$(3,3)=D$(2,2):D$(2,2)=D$(1,1):D$(1,1)="0"
2370 C=0:FOR X=1 TO COUNT:Z=X*20
2380 IF AREA$(Z-19,Z-17)=D$(1,3) THEN AREA$(Z-19,Z-19)="*":C=C+1
2390 IF PEEK(53279)=6 THEN FNC$="Delete":GOSUB 570:POP :GOTO 2410
2400 NEXT X
2410 ? "";C;" Records were flagged."
2420 ? "Actual deletion will not occur until":? "file is written back to disk."
2430 GOSUB 210
2440 FOR Z=1 TO 100:NEXT Z:GOTO 1950
2450 REM DISPLAY DIRECTORY
2460 POKE 82,0:POKE 83,40:? "↰":? ,"Menu Of Disk In Drive ";D:? :TRAP 2490
2470 FILE$="D":FILE$(2)=STR$(D):FILE$(3)=":*.*":OPEN #1,6,0,FILE$
2480 INPUT #1;FILE$:? FILE$,:GOTO 2480
2490 CLOSE #1:POKE 82,2:POKE 83,38:? :GOSUB 210:GOSUB 560:GOTO 1950
2500 REM REQUEST FILENAME
2510 FILE$="D":FILE$(2)=STR$(D):FILE$(3)=":PROGINDX."
2520 TRAP 2520:? "↰":POSITION 2,4:? "Enter 3-Digit Extension For Filename>";:INPUT SOR$
2530 IF LEN(SOR$)<>0 THEN FILE$(13)=SOR$:RETURN
2540 GOTO 1940
2550 ? "↰":? :? "Current drive number is ";D;".":?
2555 ? "Enter new drive number or [RETURN] for":? "no change."
2560 INPUT #16,D$:IF LEN(D$)=0 THEN RETURN
2570 D=VAL(D$):RETURN
2580 GRAPHICS 2+16:POSITION 4,3:? #6;"file master":POSITION 4,5:? #6;"THE ULTIMATE":POSITION 4,6
2590 GRAPHICS 2+16:POSITION 4,3:? #6;"file master":POSITION 4,5:? #6;"THE ULTIMATE":POSITION 4,6
2600 ? #6;"DISK INDEXER":POSITION 2,10:? #6;"BY JASON WORLEY"
2610 FOR X=1 TO 150:NEXT X
2620 DIM FILE$(30),SOR$(3),D$(5),D1$(25):D$="     ":D=1
2625 MAXSIZE=INT(FRE(0)/2000)*100
2630 DIM AREA$(20*MAXSIZE),SAV$(20)
2640 DIM CH$(86):CH$="    AddDisplay  Print   Sort   Save   Load Delete Delete  Clear   ExitDisplay Change"
2650 DIM INCH$(86):INCH$="    AddDisplay  Print   Sort   Save   Load Delete Delete  Clear   ExitDisplay Change"
2660 DIM SR$(71):SR$="Extension     Program Type  Disk Number   AlphabeticallyFile Length   "
2670 DIM INSR$(71):INSR$="Extension     Program Type  Disk Number   AlphabeticallyFile Length   "
2680 GOTO 1950