Diskette Insert Maker (DSKINSRT.BAS)
Diskette Insert Maker by Robert A. Blaney, 30
Description
Diskette Insert Maker by Robert A. Blaney, 30
From the Antic disk of August 1986 (Vol. 5 No. 4).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.6 KB
- Dialect
- Atari BASIC
- Lines
- 75
- Variables
L$,U$,RET$,A$,B$,C$,TEMP$,LABEL$,DATE$,SEC$,LN,X1,X2,DLAY,I,START,J,K,PND,L,XX
BASIC listing (75 lines)
10 REM DISKETTE INSERT MAKER
20 REM BY ROBERT A. BLANEY
30 REM (c) 1986, ANTIC PUBLISHING
100 DIM L$(960),U$(17),RET$(1),A$(17),B$(17),C$(15),TEMP$(17),LABEL$(38),DATE$(8),SEC$(3)
110 LABEL$(1)=" ":LABEL$(38)=LABEL$:LABEL$(2)=LABEL$
120 GRAPHICS 7:SETCOLOR 4,12,4:COLOR 1:SETCOLOR 0,0,4:SETCOLOR 2,12,4
130 REM DRAW DISKETTE
140 PLOT 116,72:DRAWTO 116,24:DRAWTO 44,24:POSITION 44,72:POKE 765,1
180 XIO 18,#6,0,0,"S:"
200 COLOR 2:SETCOLOR 1,0,0
210 FOR LN=40 TO 51:READ X1,X2
220 PLOT X1,LN:DRAWTO X2,LN:NEXT LN
250 FOR LN=59 TO 70:READ X1,X2
260 PLOT X1,LN:DRAWTO X2,LN:NEXT LN
290 COLOR 3:SETCOLOR 2,12,4
300 PLOT 116,35:DRAWTO 116,33:DRAWTO 114,33:DRAWTO 114,35:DRAWTO 116,35:PLOT 115,34
350 COLOR 2
360 FOR LN=1 TO 13:READ X1,X2:PLOT X2,X1:NEXT LN
370 FOR LN=9 TO 13:PLOT 80,LN:NEXT LN
380 PLOT 80,17
390 POKE 752,1:? " DISKETTE LABEL INSERT"
400 ? " by":? " Robert A. Blaney"
410 FOR DLAY=1 TO 1000:NEXT DLAY
420 ? :? :? :?
430 ? "INSERT Diskette for Directory":? " Press RETURN when Ready";:INPUT #16;RET$
440 CLOSE #3:OPEN #3,6,0,"D:*.*"
450 TRAP 480:FOR I=1 TO 64
460 INPUT #3,U$
470 START=(I-1)*15+1:L$(START)=U$(3,17):NEXT I
480 ? "Ready Printer and Press RETURN";:INPUT #16;RET$:LPRINT "␛0":REM 8 LPI
500 GOSUB 790:REM LABEL/DATE ROUTINE
510 GOSUB 700:LPRINT "| ";LABEL$(1,38);DATE$;" |":J=I-1:SEC$=U$(1,3):GOSUB 740
520 GOSUB 770:GOSUB 780
530 K=1:FOR J=1 TO I-1
540 ON K GOTO 550,560
550 C$=L$(((J-1)*15)+1,J*15):GOSUB 610:A$=TEMP$:K=K+1:PND=1:GOTO 570
560 C$=L$(((J-1)*15)+1,J*15):GOSUB 610:B$=TEMP$:K=K-1:PND=0:GOSUB 720
570 NEXT J
580 IF PND=1 THEN GOSUB 720
590 FOR LN=1 TO (32-(INT(J/2))):GOSUB 710:NEXT LN:GOSUB 700
600 LPRINT "␛2":GOTO 920:REM 6 LPI
610 REM ROUTINE TO COMPRESS TO FN.FT
620 TEMP$(1)=" ":TEMP$(16)=TEMP$:TEMP$(2)=TEMP$
630 FOR L=1 TO 8:TEMP$(L,L)=C$(L,L)
640 IF TEMP$(L,L)=" " THEN 660
650 NEXT L
660 REM BLANK FOUND; SET "."
670 IF C$(9,9)=" " THEN 690
680 TEMP$(L,L)=".":TEMP$(L+1,L+3)=C$(9,11)
690 TEMP$(14,16)=C$(13,15):RETURN
700 LPRINT "+------------------------------------------------+":RETURN
710 LPRINT "| |":RETURN
720 LPRINT "| ";A$;" ";B$;" |"
730 B$(1)=" ":B$(16)=B$:B$(2)=B$:RETURN
740 IF J<10 THEN 760
750 LPRINT "| # FILES = ";J;" AVAIL. SECTS = ";SEC$;" |":RETURN
760 LPRINT "| # FILES = ";J;" AVAIL. SECTS = ";SEC$;" |":RETURN
770 LPRINT "| FILENAME SECS FILENAME SECS |":RETURN
780 LPRINT "| -------- ---- -------- ---- |":RETURN
790 REM LABEL/DATE ROUTINE
800 ? "TITLE OF DIRECTORY(MAX.38 CHARS)":INPUT LABEL$
810 IF LEN(LABEL$)>38 THEN ? "TOO MANY CHARACTERS. ENTER AGAIN.":GOTO 800
820 ? "ENTER THE DATE(MAX. 8 CHARS.)";:INPUT DATE$
840 IF LEN(DATE$)<8 THEN DATE$(LEN(DATE$)+1,8)=" "
850 FOR XX=LEN(LABEL$)+1 TO 38:LABEL$(XX,XX)=" ":NEXT XX
860 RETURN
870 DATA 79,81,77,83,75,85,74,86,73,87,72,88
880 DATA 72,88,73,87,74,86,75,85,77,83,79,81
890 DATA 79,81,78,82,77,83,77,83,77,83,77,83,77,83
900 DATA 77,83,77,83,77,83,78,82,79,81
910 DATA 5,75,4,76,3,77,2,79,2,80,2,81,3,83,4,84,5,85,6,85,7,84,8,83,9,81
920 ? " DIRECTORY COMPLETED"
930 ? "CUT DIRECTORY (on dotted lines) & PUT IT IN DISK JACKET."
940 ? "Do another one? (Y/N) ";:INPUT RET$:IF RET$="Y" THEN 430
950 GRAPHICS 0:END
