RLE Maker (RLEMAKE.BAS)
RLE Maker by Charles Jackson, 32
Description
RLE Maker by Charles Jackson, 32
From the Antic disk of July 1986 (Vol. 5 No. 3).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 3.8 KB
- Dialect
- Atari BASIC
- Lines
- 89
- Variables
DEBUG,BUFSIZE,FN$,OUT$,IO$,OLD$,CUR$,MP$,BUFR$,AD,ADHI,ADLO,INV,WHITE,BLACK,CHG,KNT,COL,BUFCNT,FLUSH,SCR,A,MEM,INVCOL,X,IO,J
BASIC listing (89 lines)
10 REM CONVERT MICROPAINTER TO RLE
20 REM BY CHARLES JACKSON
30 REM (c) 1986, ANTIC PUBLISHING
40 DEBUG=0:IF PEEK(53279)=5 THEN DEBUG=1
50 GOTO 80
60 IF NOT DEBUG THEN POKE 16,112:POKE 53774,112
70 POKE 77,0:RETURN
80 BUFSIZE=500
90 DIM FN$(18),OUT$(18),IO$(20),OLD$(1),CUR$(1),MP$(7680),BUFR$(BUFSIZE)
100 GRAPHICS 0:POKE 710,12:POKE 709,0:POKE 712,142:GOSUB 60
110 ? " MICROPAINTER TO RLE ":? " ▌FILE CONVERTER▌"
120 ? :? " By Charles Jackson":? :? ," (v. 1.2)":? :?
130 MP$(1)="♥":MP$(7680)=MP$:MP$(2)=MP$
140 AD=ADR(MP$):ADHI=INT(AD/256):ADLO=AD-ADHI*256
150 ? "File to convert";:INPUT IO$:GOSUB 830:FN$=IO$
160 ? :? "Output file";:INPUT IO$:GOSUB 830:OUT$=IO$
170 ? :? :? "↰Insert SOURCE disk, ";:GOSUB 800
180 TRAP 100:CLOSE #1:OPEN #1,4,0,FN$:CLOSE #1
190 GRAPHICS 8:POKE 710,0:POKE 752,1:GOSUB 60:GOSUB 680
200 ? :? "Invert it (Y/N)?";:GOSUB 750
210 ? "↰":? "Are you sure (Y/N)?";
220 POKE 764,255
230 IF PEEK(764)=43 THEN POKE 764,255:INV=1:GOTO 260
240 IF PEEK(764)=35 THEN POKE 764,255:POKE 710,0:POKE 709,202:INV=0:? "↰":GOTO 200
250 GOTO 230
260 ? "↰":? "Insert DESTINATION disk, ";:GOSUB 800
270 IF NOT DEBUG THEN GRAPHICS 8+48:POKE 710, NOT (INV)*202:POKE 709,INV*202:GOSUB 60
280 TRAP 40000:CLOSE #2:OPEN #2,8,0,OUT$:IF DEBUG THEN ? "↰"
290 ? #2;"␛GH";
300 WHITE=0:BLACK=0:OLD$="*":CUR$="*":CHG=0:KNT=0:COL=0:BUFCNT=1:FLUSH=0:SCR=PEEK(88)+PEEK(89)*256
310 TRAP 460:POKE 77,0
320 KNT=KNT+1:A=ASC(MP$(KNT,KNT)):COL=COL+1
330 IF COL=41 THEN COL=1
340 IF COL<5 THEN 320
350 IF COL>36 THEN 320
360 IF INV=1 THEN A=255-A
370 IF KNT>7680 THEN 460
380 MEM=PEEK(KNT+SCR-1)
390 INVCOL=USR(ADR("hh┐UhI▶┐T◆"),MEM):POKE KNT+SCR-1,INVCOL
400 FOR X=1 TO 8:IF PEEK(53279)=6 THEN 455
410 IF A>127 THEN CHG=1:GOSUB 500:GOTO 430
420 CHG=0:GOSUB 560
430 A=USR(ADR("hh┐Uh◣┐T◆"),A):REM SHIFT BITS LEFT ONE PLACE
440 NEXT X:POKE KNT+SCR-1,MEM
450 GOTO 310
455 GRAPHICS 0:? "↰ABORTED AT YOUR REQUEST!"
460 FLUSH=1:GOSUB 620:? #2;"␛GN";:CLOSE #1:CLOSE #2:GRAPHICS 0:? OUT$;" IS DONE!"
470 ? :? "Press START to re-run"
480 IF PEEK(53279)=6 THEN 100
490 GOTO 480
500 CUR$="B"
510 IF (CUR$<>OLD$) AND (OLD$<>"*") THEN CHG=CHG+1:IF CHG>1 THEN GOSUB 620
520 BLACK=BLACK+1
530 IF BLACK>94 THEN GOSUB 620
540 OLD$="B"
550 RETURN
560 CUR$="W"
570 IF (CUR$<>OLD$) AND (OLD$<>"*") THEN CHG=CHG+1:IF CHG>1 THEN GOSUB 620
580 WHITE=WHITE+1
590 IF WHITE>94 THEN GOSUB 620
600 OLD$="W"
610 RETURN
620 BUFR$(BUFCNT,BUFCNT)=CHR$(BLACK+32)
630 BUFR$(BUFCNT+1,BUFCNT+1)=CHR$(WHITE+32)
640 BUFCNT=BUFCNT+2
650 IF (BUFCNT>=BUFSIZE) OR (FLUSH=1) THEN ? #2;BUFR$(1,BUFCNT-1);:BUFCNT=1
660 IF DEBUG THEN ? BLACK,WHITE,"(";KNT;")"
670 BLACK=0:WHITE=0:RETURN
680 CLOSE #1:OPEN #1,4,0,FN$
690 IO=848:POKE IO+2,7:POKE IO+4,ADLO:POKE IO+5,ADHI:POKE IO+8,0:POKE IO+9,30
700 J=USR(ADR("hhh*LVd"),16):CLOSE #1
710 OPEN #1,4,0,FN$
720 POKE IO+2,7:POKE IO+4,PEEK(88):POKE IO+5,PEEK(89):POKE IO+8,0:POKE IO+9,30
730 J=USR(ADR("hhh*LVd"),16):CLOSE #1
740 RETURN
750 POKE 764,255
760 IF PEEK(764)=43 THEN INV=0:POKE 710,202:POKE 709,0:GOTO 790:REM YES
770 IF PEEK(764)=35 THEN INV=1:POKE 710,0:POKE 709,202:GOTO 790:REM NO
780 GOTO 760
790 POKE 764,255:RETURN
800 POKE 752,1:? "press ▌START▌";
810 IF PEEK(53279)<>6 THEN 810
820 RETURN
830 IO$(LEN(IO$)+1)=" "
840 IF IO$(1,2)="D:" OR (IO$(1,1)="D" AND IO$(3,3)=":") THEN RETURN
850 FOR X=LEN(IO$) TO 3 STEP -1
860 IO$(X,X)=IO$(X-2,X-2):NEXT X
870 IO$(1,2)="D:"
880 RETURN
