make your own DCK files (COMPDECK.BAS)
make your own DCK files, 58
Description
make your own DCK files, 58
From the Antic disk of July 1986 (Vol. 5 No. 3).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 6.0 KB
- Dialect
- Atari BASIC
- Lines
- 103
- Variables
CRD$,SHOW$,A$,B$,FO$,C1(,DNUM,K$,CARD,FI$,LN,I,C(,ADDR,SCR,MV,K,CIO$,A,TIM,MV$,BF$,BYTES,TYPE,H
BASIC listing (103 lines)
1 REM COMPDECK.BAS
2 REM BY CHET WALTERS
3 REM (c) 1986, ANTIC PUBLISHING
10 GOSUB 20000:DIM CRD$(1921),SHOW$(40),A$(20),B$(20),FO$(20),C1(5):FO$=" DECK FILE":GOSUB 500:GOSUB 510
20 SHOW$="hh┐Mh┐L"_ ┼1LI▶┌L◢♣w%L┴i(┐L%Mi♥┐MJ♣e◆":B$=FO$(3):DNUM=1:? :GOSUB 520:FO$="D:":FO$(3)=A$
30 FO$(LEN(FO$)+1)=".DCK":B$="INPUT PIC":GOSUB 580:? :? "DECK FILE IS->";FO$;" ";:GOSUB 800
35 IF K$="N" THEN RUN
40 GOSUB 500:GOSUB 510:? :? "ENTER DRIVE #(1 OR 2) FOR PICDISK->";:INPUT DNUM
45 IF DNUM<1 OR DNUM>2 THEN 40
50 GOSUB 500:CARD=1:? "COLORS LOADED WITH THIS FILE WILL":? "BE USED THROUGHOUT COMPILATION":GOTO 70
60 ? "SAVE COMPLETE":? "USE ";FI$(4,LEN(FI$)-2);" AGAIN FOR CARD #";CARD;
65 GOSUB 800:IF K$<>"N" THEN 90
70 ? :? "INSERT PICDISK INTO DRIVE # ";DNUM:? :GOSUB 520
72 IF A$="/EXIT" THEN CLOSE #1:CLOSE #2:GRAPHICS 0:? "↰ABORTED AT YOUR REQUEST!":END
75 FI$="D1:":FI$(2,2)=STR$(DNUM):FI$(4)=A$:GOSUB 580
80 FI$(LEN(FI$)+1)=".*":? :? "LOADING-> ";FI$;:LN=70:GOSUB 21000
85 IF CARD=1 THEN FOR I=0 TO 4:C1(I)=C(I):NEXT I
90 FOR I=0 TO 4:C(I)=C1(I):NEXT I:GOSUB 22000:GOSUB 501:POKE 559,0:GOSUB 23000:POKE 195,0
100 I=USR(ADR("h(%X┐L%Y┐M"←1LI▶┌L◢PwfMJPr◆")):POKE 559,34:ADDR=SCR:MV=0:I=USR(ADR(SHOW$),ADDR)
110 MV=0:GOSUB 620:IF K=15 OR K=143 THEN MV=40+280*(K=143):GOTO 180
120 IF K=14 OR K=142 THEN MV=-40-280*(K=142):GOTO 180
130 IF K=7 OR K=135 THEN MV=1+(K=135):GOTO 180
140 IF K=6 OR K=134 THEN MV=-1-(K=134):GOTO 180
150 IF K=12 THEN 200
160 IF K=28 THEN GOSUB 500:GOTO 70
170 GOTO 110
180 IF NOT (ADDR+MV>SCR+3860 OR ADDR+MV<SCR) THEN 190
185 POKE 18,0:POKE 19,0:POKE 20,0:POKE 712,12:POKE 712,C1(4):GOTO 110
190 I=USR(ADR(SHOW$),ADDR):ADDR=ADDR+MV:I=USR(ADR(SHOW$),ADDR):GOTO 110
200 I=USR(ADR("hh┐Nh┐Mh┐Lh┐K"◆ ┼1M┌K◢♣y%M┴i(┐M%Ni♥┐N%K┴i●┐K%Li♥┐LJPZ◆"),ADDR,ADR(CRD$))
210 GOSUB 500:LN=220:GOSUB 590:?
220 IF DNUM=1 OR PEEK(195)<>0 THEN ? :? "INSERT DISK FOR ";FO$(3):? "INTO DRIVE # 1":GOSUB 600:?
230 ? "SAVING CARD #";CARD;" IN ";FO$(3);
240 POKE 195,0:IF CARD=1 THEN CLOSE #2:OPEN #2,8,0,FO$:FOR I=0 TO 4:PUT #2,C1(I):NEXT I
250 I=USR(ADR(CIO$),32,11,ADR(CRD$),1920):CARD=CARD+1:IF CARD<>13 THEN ? "↑";:GOTO 60
260 CLOSE #2:GOSUB 500
270 LN=270:? :? FO$(3,LEN(FO$)-4);" DECK COMPLETED!":? :? "DO YOU WANT TO:"
280 ? "1-> COMPILE ANOTHER DECK":? "2-> SHUFFLE ";FO$(3):? "3-> QUIT TO BASIC":? "4-> GO TO DOS"
290 TRAP 270:INPUT A:GRAPHICS 0:ON A GOTO 310,320,330,340
300 GOSUB 500:GOTO LN
310 RUN
320 ? :? "INSERT DISK WITH DECKLOAD.BAS ":GOSUB 600:? :? "LOADING":RUN "D:DECKLOAD.BAS"
330 GRAPHICS 0:END
340 DOS
500 GRAPHICS 0:? "▶ ANTIC'S DECK COMPILER ":? :TRAP 630
501 POKE 16,64:POKE 53774,64:RETURN
510 ? FO$(3);" REQUIRES 185 FREE SECT.":? "AND IS WRITTEN TO DRIVE#1":GOTO 590
520 ? "ENTER NAMES WITH NO PREFIX OR EXT.":? "PRESS RETURN FOR DIRECTORY":LN=520
525 IF CARD>0 THEN ? "TYPE: /EXIT TO ABORT"
530 IF CARD THEN ? :? "WORKING ON CARD # ";CARD;" FOR ";FO$(3):?
540 ? B$;" FILENAME->";:INPUT A$:IF A$<>"" THEN RETURN
550 GOSUB 500:CLOSE #1:A$="D1:*.*":A$(2,2)=STR$(DNUM):OPEN #1,6,0,A$
560 INPUT #1,A$:IF A$(2,2)<>" " THEN ? :? ,A$:? :CLOSE #1:GOTO 520
570 POKE 83,37:? A$(2,10);:POKE 83,39:GOTO 560
580 ? :? "DURING EDIT USE:":? "ARROW KEYS OR JOYSTICK TO MOVE WINDOW"
581 ? "CTRL/ARROWS OR JOYSTICK TO MOVE FAST"
582 ? "RETURN OR TRIGGER TO SAVE WINDOW":? "ESC TO LOAD NEW PIC":RETURN
590 ? "OUTPUT FILE REMAINS OPEN!":? " DON'T CONFUSE DISKS! ":RETURN
600 ? " PRESS ANY KEY";:GOTO 700
610 ? "(Y/N)Y←";
620 POKE 764,255
621 IF (PEEK(764)=255 AND PEEK(632)=15 AND PEEK(644)=1) THEN POKE 19,0:POKE 18,0:POKE 20,128:K=0:GOTO 621
622 TIM=PEEK(19)+PEEK(18)*256:IF PEEK(644)=0 THEN K=12:GOTO 629
623 K=(15*(PEEK(632)=13)):IF K<>0 THEN 628:REM DOWN
624 K=(14*(PEEK(632)=14)):IF K<>0 THEN 628:REM UP
625 K=(7*(PEEK(632)=7)):IF K<>0 THEN 628:REM RIGHT
626 K=(6*(PEEK(632)=11)):IF K<>0 THEN 628:REM LEFT
627 IF K=0 THEN K=PEEK(764):GOTO 629
628 K=K+(K<>0)*(128*(TIM>0))
629 POKE 764,255:RETURN
630 GOSUB 500:? "**ERROR->";PEEK(195):GOTO LN
700 POKE 764,255
710 IF PEEK(764)=255 THEN 710
720 POKE 764,255:RETURN
800 ? "(Y/N) Y←←";:INPUT K$:RETURN
19999 REM MICROSCREEN LOADER
20000 DIM C(5),FI$(20),CIO$(30),MV$(64),BF$(7680),K$(1)
20009 REM INITIALIZE VARIABLES
20010 RESTORE 20030:FOR I=1 TO 3:READ MV$:BF$(LEN(BF$)+1)=MV$:NEXT I:CIO$="hhh*hh↓B┘h↓E┘h↓D┘h↓I┘h↓H┘LVd"
20020 MV$="hh┐Lh┐Kh┐Nh┐Mh┐Ph┐O ♥&Pp▂1K┌M◢PyfLfNJPr$Op▘◢1K┌M◢Py1K┌M◆":I=USR(ADR(MV$),ADR(BF$),1536,250):RETURN
20030 DATA Xhh┐Nh┐Mh┐W┐U┐Oh┐VP▕)P┐Th┐Zh┐Y)←┐P 2╱)├┐S %╱I♥0┤"♥╱S)▶p◢┐Q)♥┐R
20040 DATA p┌ %╱┐R %╱┐QLQ╱%Sp┘ %╱$U%X┌KFOP┐FPP├◆%VP&fW&W◆◆P▗ 2╱ (┤UP"◆@P┌
20050 DATA fMP▕fN 2╱"♥╱W╱Up▔┴%KeT┐K%Li♥┐LFQP/FR♣+L%╱ ♥1Y┐XfYP▕fZ◆%M┐K%N┐L◆
20998 REM
20999 REM LOAD PIC INTO BUFFER STRING
21000 CLOSE #1:BYTES=7680:TYPE=0:RESTORE 21000:OPEN #1,4,0,FI$:DATA 255,128,201,199,26,0,1,14
21010 FOR I=1 TO 7:GET #1,A:POKE ADR(BF$)+I-1,A:READ H:IF A<>H THEN POP :GOTO 21040
21020 NEXT I:GET #1,TYPE:FOR I=1 TO 5:GET #1,A:NEXT I:FOR I=0 TO 5:GET #1,A:C(I)=A:NEXT I:GET #1,H
21030 FOR I=1 TO 7:GET #1,A:NEXT I:I=0:IF TYPE THEN BYTES=H*256+255
21040 A=USR(ADR(CIO$),16,7,ADR(BF$)+I,BYTES-I):IF I=0 THEN 21060
21050 C(3)=0:C(4)=0:C(0)=135:C(1)=53:C(2)=15:TRAP 21060
21055 GET #1,A:C(4)=A:FOR I=0 TO 2:GET #1,A:C(I)=A:NEXT I
21060 TRAP 630:CLOSE #1:RETURN
21998 REM
21999 REM SET UP DISPLAY LIST
22000 IF PEEK(87)=8 THEN 22020
22010 GRAPHICS 24:I=USR(ADR("h(-0▕┐K-1▕┐LH1KIAP├◆8i├INP╱┌KHHPkI▂Pg┌Kpc"))
22020 SCR=PEEK(88)+256*PEEK(89):RETURN
22998 REM
22999 REM DUMP PICTURE TO SCREEN
23000 FOR I=0 TO 4:POKE 708+I,C(I):NEXT I
23010 IF TYPE THEN I=USR(1536,SCR,TYPE-1,ADR(BF$)):RETURN
23020 I=USR(ADR(MV$),ADR(BF$),SCR,7680):RETURN
