RLE to MicroPainter Converter (BUILD.BAS)
RLE to MicroPainter Converter by Charles Jackson 17
Description
RLE to MicroPainter Converter by Charles Jackson 17
From the Antic disk of July 1986 (Vol. 5 No. 3).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.0 KB
- Dialect
- Atari BASIC
- Lines
- 46
- Variables
BRK,IN$,OUT$,IO$,A,X,Y,BLACK,WHITE,IO,JNK
BASIC listing (46 lines)
10 REM CONVERT RLE TO MICROPAINTER
20 REM BY CHARLES JACKSON
30 REM (c) 1986, ANTIC PUBLISHING
40 BRK=1:IF PEEK(53279)=5 THEN BRK=0
50 GOTO 80
60 IF BRK THEN POKE 16,112:POKE 53774,112
70 POKE 710,0:POKE 77,0:POKE 752,1:RETURN
80 DIM IN$(18),OUT$(18),IO$(21)
90 GRAPHICS 0:GOSUB 60
100 ? :? " ◢ CHANGE R.L.E. TO MICROPAINTER ◢"
110 POSITION 2,7:? "RLE file to plot";:INPUT IO$:GOSUB 410:IN$=IO$
120 ? :? "SAVE as ";:INPUT IO$:GOSUB 410:OUT$=IO$
130 TRAP 90:GRAPHICS 8:GOSUB 60:? "Insert SOURCE disk, press [RETURN]":INPUT #16,IO$
140 CLOSE #1:OPEN #1,4,0,IN$:TRAP 40000
150 GET #1,A:IF A<>27 THEN 150
160 FOR X=1 TO 2:GET #1,A:NEXT X
170 X=32:Y=0:GRAPHICS 8+16:GOSUB 60:COLOR 1
180 TRAP 310
190 GET #1,BLACK:GET #1,WHITE:POKE 77,0
200 IF (BLACK=27) OR (WHITE=27) THEN 310
210 BLACK=BLACK-32:WHITE=WHITE-32
220 IF BLACK=0 THEN 260
230 FOR A=1 TO BLACK
240 COLOR 0:PLOT X,Y:X=X+1:IF X>287 THEN Y=Y+1:X=32
250 NEXT A
260 IF WHITE=0 THEN 180
270 FOR A=1 TO WHITE
280 COLOR 1:PLOT X,Y:X=X+1:IF X>287 THEN Y=Y+1:X=32
290 NEXT A
300 GOTO 180
310 CLOSE #1:GRAPHICS 8+32:GOSUB 60
320 ? "Insert DESTINATION disk, press [RETURN]":INPUT #16,IO$
330 TRAP 400:GRAPHICS 8+48:GOSUB 60
340 CLOSE #1:OPEN #1,8,0,OUT$
350 IO=848:POKE IO+2,11:POKE IO+4,PEEK(88):POKE IO+5,PEEK(89):POKE IO+8,0:POKE IO+9,30
360 JNK=USR(ADR("hhh*LVd"),16)
370 PUT #1,0:PUT #1,2:PUT #1,7:PUT #1,12:CLOSE #1
380 GRAPHICS 0:GOSUB 60
390 POSITION 14,10:? "↰* DONE *↰":GOTO 90
400 ? "ERROR-";PEEK(186)+PEEK(187)*256:END
410 IO$(LEN(IO$)+1)=" "
420 IF IO$(1,2)="D:" OR (IO$(1,1)="D" AND IO$(3,3)=":") THEN RETURN
430 FOR X=LEN(IO$) TO 3 STEP -1
440 IO$(X,X)=IO$(X-2,X-2):NEXT X
450 IO$(1,2)="D:"
460 RETURN
