New Owner's Column #4 (NEWOWN4.BAS)
New Owner's Column #4 by David Plotkin, 14
Description
New Owner's Column #4 by David Plotkin, 14
From the Antic disk of June 1986 (Vol. 5 No. 2).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.9 KB
- Dialect
- Atari BASIC
- Lines
- 56
- Variables
QUESTION$,ANSWER$,YOURANSWER$,XXX,YYY,ZZZ,RT,WG,X,WAIT,PERC,Y
BASIC listing (56 lines)
10 REM NEW OWNER'S COLUMN, PART 4
20 REM BY DAVID PLOTKIN
30 REM (c) 1986, ANTIC PUBLISHING
40 DIM QUESTION$(50),ANSWER$(1),YOURANSWER$(1)
50 XXX=1:YYY=2:ZZZ=3:RT=0:WG=0:REM SET UP THE VARIABLES
60 GRAPHICS 0:POKE 752,1
70 POSITION 4,0:PRINT "NEW OWNER'S COLUMN LOGIC TEST"
80 POSITION 3,3:PRINT "ASSUMPTIONS: XXX=1 YYY=2 ZZZ=3"
90 POSITION 3,4:PRINT "PRESS T FOR TRUE, F FOR FALSE":POSITION 11,5:PRINT "AND Q TO QUIT"
100 FOR X=0 TO 39:POSITION X,6:PRINT "*";:SOUND 0,X*3+20,10,6:NEXT X:SOUND 0,0,0,0
110 RESTORE 1000:TRAP 300:REM FALLS THROUGH WHEN OUT OF DATA
120 READ QUESTION$,ANSWER$
130 FOR X=0 TO 38:POSITION X,9:PRINT " ";:SOUND 0,200-X*4,10,6:NEXT X:SOUND 0,0,0,0
140 FOR X=3 TO 30:POSITION X,11:PRINT " ";:SOUND 0,200-X*4,10,6:NEXT X:SOUND 0,0,0,0
150 X=(39-LEN(QUESTION$))/2:POSITION X,9:PRINT QUESTION$
160 POSITION 3,11:PRINT "TRUE OR FALSE";:INPUT YOURANSWER$
170 IF ANSWER$=YOURANSWER$ THEN GOSUB 500:RT=RT+1:GOTO 120:REM RIGHT ANSWER
180 IF YOURANSWER$="Q" THEN GRAPHICS 0:GOTO 400:REM READY TO QUIT
185 IF YOURANSWER$<>"T" AND YOURANSWER$<>"F" AND YOURANSWER$<>"Q" THEN GOTO 130
190 WG=WG+1:REM ANSWER IS WRONG
200 FOR X=1 TO 5:POSITION 3,14:PRINT "SORRY! ANSWER IS WRONG";:SOUND 0,X*100/2,10,4
210 FOR WAIT=1 TO 30:NEXT WAIT:POSITION 3,14:PRINT "SORRY! ANSWER IS WRONG";:SOUND 0,0,0,0
220 FOR WAIT=1 TO 30:NEXT WAIT
230 NEXT X:POSITION 3,14:PRINT " ";
240 GOTO 120
300 GRAPHICS 0:POSITION 3,5:PRINT "THANK YOU FOR TRYING OUT THIS"
310 POSITION 1,6:PRINT "LOGIC TEST IN THE NEW OWNER'S COLUMN"
320 POSITION 7,7:PRINT "SEE YOU NEXT MONTH!"
400 POSITION 1,9
410 IF WG=0 THEN PRINT "CONGRATULATIONS!!! YOU GOT THEM ALL":END
420 PERC=RT/(RT+WG)*100:PRINT "YOU GOT ";PERC;"% RIGHT"
430 POSITION 2,12:PRINT "WANT TO TRY AGAIN (Y/N)";:INPUT YOURANSWER$
440 IF YOURANSWER$="Y" THEN GOTO 50
450 POSITION 2,14:PRINT "GOODBYE!!";:END
500 FOR X=1 TO 5:POSITION 3,14:PRINT "HURRAY! ANSWER IS RIGHT";:FOR Y=10 TO 30:SOUND 0,X*100/2+Y,10,4:NEXT Y
510 FOR WAIT=1 TO 30:NEXT WAIT:POSITION 3,14:PRINT "HURRAY! ANSWER IS RIGHT";:SOUND 0,0,0,0
520 FOR WAIT=1 TO 30:NEXT WAIT
530 NEXT X:POSITION 3,14:PRINT " ";
540 RETURN
999 END
1000 REM DATA FOR QUESTIONS
1010 DATA (XXX=1 AND YYY=2 AND ZZZ=3),T
1020 DATA (XXX>1 OR YYY>2 OR ZZZ=3),T
1030 DATA (XXX=5 AND YYY=2) OR ZZZ>2,T
1040 DATA (XXX+YYY)>0 AND ZZZ=3,T
1050 DATA (XXX=2 OR YYY=2) AND ZZZ=2,F
1060 DATA (XXX=1 AND YYY=3)AND(XXX=3 AND ZZZ=3),F
1070 DATA (XXX=1 OR YYY=3)AND(XXX=3 OR ZZZ=3),T
1080 DATA (XXX=3 AND YYY=2)OR(YYY=4 AND ZZZ=3),F
1090 DATA (XXX<YYY) AND (YYY>ZZZ),F
1100 DATA (XXX<YYY) OR (YYY>ZZZ),T
1110 DATA (XXX=YYY) OR (YYY=ZZZ) OR (ZZZ=3),T
1120 DATA (XXX=YYY AND YYY=2)OR(ZZZ>YYY),T
1130 DATA (XXX+YYY>YYY+XXX) OR (ZZZ>YYY),T
1140 DATA (XXX+YYY>YYY+XXX) AND (ZZZ>YYY),F
1150 DATA (XXX=5 AND YYY=10)OR(YYY=7 OR ZZZ=3),T
