Artistic Mathematics (MATHART1.BAS)

Artistic Mathematics by Marian Lorenz and ALLAN MOOSE, 81

Description

Artistic Mathematics by Marian Lorenz and ALLAN MOOSE, 81

From the Antic disk of June 1986 (Vol. 5 No. 2).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 4.8 KB

Dialect
Atari BASIC
Lines
108
Variables
PR1$, PR2$, HD$, A$, DRAW, MODE, LINE, X, AXIS, TEMP1, TEMP2, AMP, PER, PHI, HUE, FDGFACTR, Y, JNK, ME, IT, PR1, PR2, DL, SCR, PICT, STR, ML, G15, DS, IO, GM
BASIC listing (108 lines)
10 REM ARTISTIC MATHEMATICS, LISTING ONE
20 REM BY MARIAN LORENZ/ALLAN MOOSE
30 REM (c) 1986, ANTIC PUBLISHING
40 GRAPHICS 2:POKE 712,148:? #6:? #6:? #6:? #6;"    ARTISTIC":? #6;"    MATHEMATICS"
41 ? #6:? #6;"    part i"
42 ? ,"BY LORENZ/MOOSE":POKE 752,1
43 ? :? "    (c) 1986, ANTIC PUBLISHING"
44 GOSUB 540
45 DIM PR1$(964),PR2$(964),HD$(4),A$(42)
46 A$="hI┘p▖I┐p├◆h┐\h┐[hh┐Zh┐Vh┐Uhh┐Thh▔♠▕)┌┐!L||":A$(39,39)=CHR$(34)
47 DRAW=ADR(A$):GRAPHICS 0
50 POKE 752,1:? "↰PRINTER:":? :? "Epson":? "Star/Gemini":? "None":? :? "Choose One"
52 POKE 764,255
53 IF PEEK(764)=42 THEN MODE=24:GOTO 58
54 IF PEEK(764)=62 THEN MODE=16:GOTO 58
55 IF PEEK(764)=35 THEN MODE=0:GOTO 58
56 GOTO 53
58 POKE 764,255:GM=8:TRAP 60:GRAPHICS 15
59 GM=15
60 TRAP 40000:GRAPHICS GM+16:GOSUB 750
70 COLOR 1
80 FOR LINE=0 TO 191 STEP 2
90 IF GM=8 THEN X=USR(DRAW,0,LINE,159,LINE,1):GOTO 100
95 PLOT 0,LINE:DRAWTO 159,LINE
100 NEXT LINE
110 REM DETERMINE AN AXIS FOR SINE CURVE
120 GRAPHICS GM+48:GOSUB 750
125 AXIS=INT(192*RND(1))
130 REM DETERMINE AN AMPLITUDE FOR SINE WAVE
140 REM KEEP IT WITHIN SCREEN BOUNDARIES
150 TEMP1=192-AXIS
160 IF AXIS<TEMP1 THEN TEMP2=AXIS
170 IF TEMP1<AXIS THEN TEMP2=TEMP1
180 AMP=INT(TEMP2*RND(1)):IF AMP<3 THEN 125
190 REM DETERMINE PERIOD FOR SINE CURVE
200 PER=INT(100*RND(1)+1)
210 REM DETERMINE A PHASE SHIFT
220 PHI=6.28*RND(1)
230 REM DETERMINE COLOR
240 HUE=INT(RND(0)*4)
260 REM DETERMINE A SPACING FACTOR
270 FDGFACTR=INT(3*RND(1))+1
280 REM PLOT PICTURE
290 COLOR HUE
300 FOR X=0 TO 159 STEP FDGFACTR
310 Y=AMP*(SIN(X/PER-PHI))+AXIS
320 IF GM=8 THEN JNK=USR(DRAW,X,AXIS,X,Y,HUE):GOTO 340
330 COLOR HUE:PLOT X,AXIS:DRAWTO X,Y
340 NEXT X
350 REM WAIT FOR USER'S CHOICE OF OPTIONS
355 GRAPHICS GM+32:GOSUB 750:? "↰Continue":? "Print":? "Save":? "Quit";
360 POKE 764,255
370 IF PEEK(764)=18 THEN POKE 764,255:GOTO 120:REM CONTINUE
380 IF PEEK(764)=47 THEN POKE 764,255:GRAPHICS 0:END :REM QUIT
385 IF PEEK(764)=62 THEN POKE 764,255:GOTO 900:REM SAVE AS MICROPAINTER
390 IF PEEK(764)=10 THEN POKE 764,255:GOTO 410:REM PRINT
395 GOTO 370
400 REM SCREEN DUMP FROM ANTIC, JAN 1984
410 IF MODE=0 THEN ? "↰NO PRINTER SELECTED!↰↰↰↰":GOTO 355
415 CLOSE #1:OPEN #1,8,0,"P:":? #1;CHR$(27);CHR$(64);CHR$(27);CHR$(51);CHR$(MODE)
420 GRAPHICS GM+48:GOSUB 750
430 REM SET LINE SPACING AND MAKE LOOP
440 RESTORE 460
450 FOR ME=1 TO 4:READ IT:HD$(ME,ME)=CHR$(IT):NEXT ME
460 DATA 27,76,192,3
470 PR1$=CHR$(0):PR1$(964)=CHR$(0):PR1$(2)=PR1$:PR2$=PR1$
480 PR1$(1,4)=HD$:PR2$(1,4)=HD$
490 PR1=ADR(PR1$):PR2=ADR(PR2$)
500 DL=PEEK(560)+PEEK(561)*256:SCR=PEEK(DL+4)+(PEEK(DL+5))*256
510 FOR X=0 TO 39:PICT=191*40+SCR+X
520 STR=USR(1536,PICT,PR1,PR2):PRINT #1;PR1$:PRINT #1;PR2$
530 NEXT X:CLOSE #1:GOTO 355
540 RESTORE 570
550 FOR ME=1536 TO 1746:READ ML:POKE ME,ML:NEXT ME
560 RETURN
570 DATA 104,104,133,204,104,133,203,104,141,192,6,104
580 DATA 141,191,6,104,141,194,6,104,141,193,6,169
590 DATA 1,133,207,169,191,133,208,160,0,177,203,141
600 DATA 190,6,165,207,240,28,169,0,133,207,173,193
610 DATA 6,24,105,4,141,193,6,133,205,173,194,6
620 DATA 105,0,141,194,6,133,206,76,95,6,169,1
630 DATA 133,207,173,191,6,24,105,4,141,191,6,133
640 DATA 205,173,192,6,105,0,141,192,6,133,206,32
650 DATA 137,6,32,146,6,32,160,6,32,137,6,32
660 DATA 169,6,32,160,6,165,207,240,177,56,165,203
670 DATA 233,40,176,2,198,204,133,203,198,208,165,208
680 DATA 201,255,208,151,96,173,190,6,41,3,10,10
690 DATA 170,96,160,0,189,195,6,145,205,232,200,192
700 DATA 4,208,245,96,173,190,6,74,74,141,190,6
710 DATA 96,160,0,189,195,6,10,10,10,10,24,113
720 DATA 205,145,205,232,200,192,4,208,238,96,0,0,0,0,0
730 DATA 0,0,0,0,10,5,10,5,10,0,5,0,15,15,15,15
750 IF GM=8 THEN G15=USR(ADR("h-0▕┐P-1▕┐Q ┘)N┌P ╱1PI▖P┤)▂┌PIOP┤)N┌PH@M♣i)╲┐W◆"))
755 POKE 708,86:POKE 709,196:POKE 710,236:POKE 712,56:POKE 752,1
820 REM MOVE PLOT & DRAWTO ROUTINES INTO RAM, DELETE BOUNDS CHECKING (COURTESY DAVID SMALL)
830 DS=USR(ADR("h"♥=||↓||h◆♥Pu"♥=|↰↓|↰h◆KPu"◀▂┴↰▂&◀J▂A◀)j▔v↰▔w↰▔x↰◆"))
840 RETURN
900 POKE 752,0:? "↰SAVE FILENAME";:INPUT PR1$
910 IF LEN(PR1$)<3 THEN 930
920 IF (PR1$(1,1)="D" AND (PR1$(2,2)=":" OR PR1$(3,3)=":")) OR PR1$="C:" THEN 940
930 PR2$="D:":PR2$(3)=PR1$:PR1$=PR2$
940 GRAPHICS GM+48:GOSUB 750:DL=PEEK(560)+PEEK(561)*256
950 TRAP 900:CLOSE #1:OPEN #1,8,0,PR1$
960 DL=PEEK(560)+PEEK(561)*256
970 IO=848:POKE IO+2,11:POKE IO+4,PEEK(DL+4):POKE IO+5,PEEK(DL+5):POKE IO+8,0:POKE IO+9,30
980 X=USR(ADR("hhh*LVd"),16)
990 PUT #1,PEEK(712):FOR X=708 TO 710:PUT #1,PEEK(X):NEXT X
1000 CLOSE #1:TRAP 40000:GOTO 355