Decision Analysis Program (DECIDE.BAS)
Decision Analysis Program by Jeffrey A. Summers, 79
Description
Decision Analysis Program by Jeffrey A. Summers, 79
From the Antic disk of June 1986 (Vol. 5 No. 2).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 9.5 KB
- Dialect
- Atari BASIC
- Lines
- 250
- Variables
BRK,I,BPTR(,VALUE(,NTYPE(,J,FPTR(,LABEL$,NODE,TOP,TYPE,NBRANCH,RESPONSE$,SPACE$,PROBAB,PROB(,V,ND,N1,A,ENODE,EX,OPT,BRANCH,EDFLG,MM,CNODE,TEMP$
BASIC listing (250 lines)
10 REM DECISION ANALYSIS PROGRAM
20 REM BY JEFFREY A. SUMMERS
30 REM (c) 1986, ANTIC PUBLISHING
40 GRAPHICS 0:BRK=1:IF PEEK(53279)=5 THEN BRK=0
50 GOTO 70
60 IF BRK THEN POKE 16,112:POKE 53774,112:POKE 77,0
65 RETURN
70 GRAPHICS 1:POSITION 6,7:? #6;"DECISION":POKE 752,1:POKE 710,0
75 ? #6;" TREE":? #6;" ANALYSIS":? :? " By Jeffrey A. Summers"
77 ? :? " (c) 1986 Antic Publishing"
80 GOSUB 60:GOTO 10000:REM INITIALIZE
500 REM INPUT ERROR TRAP ROUTINE
505 PRINT #1;CHR$(253);
510 PRINT #1;"Input error - please re-try"
515 TRAP 500
520 GOTO PEEK(186)+256*PEEK(187)
600 REM FILE ERROR TRAP ROUTINE
605 PRINT #1;CHR$(253);
606 CLOSE #2
610 PRINT #1;"Error in file handling. Please Retry":GOSUB 20040
615 TRAP 600
620 GOTO 10040
1000 REM NEW TREE SELECTION
1004 REM CLEAR TREE
1009 CLOSE #1:OPEN #1,4,0,"E:":GOSUB 60:PRINT #1;"Clearing tree for entry..."
1010 FOR I=1 TO 200:BPTR(I)=0:VALUE(I)=-1:NTYPE(I)=0:FOR J=1 TO 5
1015 FPTR(I,J)=0:NEXT J:NEXT I:LABEL$="":NODE=1:TOP=2
1017 TRAP 500
1020 PRINT #1;"Node Types:":PRINT #1;"1 - Decision":PRINT #1;"2 - Chance"
1025 PRINT #1;"3 - Terminal"
1026 PRINT #1;"Type: ";:INPUT #1,TYPE
1030 IF TYPE<1 OR TYPE>3 THEN 1020
1035 NTYPE(NODE)=TYPE:? #1
1040 ON TYPE GOTO 1050,1100,1150
1050 REM DECISION NODE
1051 PRINT #1;"How many branches? ";:INPUT #1,NBRANCH
1055 IF NBRANCH>5 THEN PRINT #1;"Too many. Regroup.":GOTO 1050
1060 FOR I=1 TO NBRANCH:FPTR(NODE,I)=TOP:BPTR(TOP)=NODE:TOP=TOP+1:NEXT I
1065 PRINT #1;"Label: ";:INPUT #1,RESPONSE$
1070 IF LEN(RESPONSE$)<20 THEN RESPONSE$(LEN(RESPONSE$)+1)=SPACE$
1075 LABEL$(20*(NODE-1)+1,20*NODE)=RESPONSE$
1080 GOTO 1200
1100 REM CHANCE NODE
1101 PRINT #1;"How many branches? ";:INPUT #1,NBRANCH
1105 IF NBRANCH>5 THEN PRINT #1;"Too many. Break it up.":GOTO 1100
1110 FOR I=1 TO NBRANCH:PRINT #1;"Prob of branch ";I;" ":INPUT #1,PROBAB
1115 FPTR(NODE,I)=TOP:BPTR(TOP)=NODE:PROB(TOP)=PROBAB:TOP=TOP+1:NEXT I
1120 GOTO 1065
1150 REM TERMINAL NODE
1151 PRINT #1;"Value: ";:INPUT #1,V:VALUE(NODE)=V:GOTO 1065
1200 REM SELECT NEXT NODE
1201 I=1
1210 IF NTYPE(I)=0 THEN NODE=I:GOTO 1240
1220 I=I+1:IF I=TOP THEN 10040
1230 GOTO 1210
1240 REM WIND BACK TO ORIGIN
1241 PRINT #1;"Node # ";I;" from:":ND=I
1250 N1=BPTR(ND)
1260 IF NTYPE(N1)=2 THEN PRINT #1;"Prob ";PROB(ND);" ";
1270 PRINT #1;N1;" ";LABEL$(20*(N1-1)+1,20*N1)
1280 IF N1=1 THEN GOSUB 20040:GOTO 1020
1290 ND=N1:GOTO 1250
2000 REM RETRIEVE TREE SECTION
2004 TRAP 600
2005 PRINT #1;"File to recover: ";:INPUT #1,RESPONSE$:GOSUB 20050
2010 CLOSE #2:OPEN #2,4,0,RESPONSE$:GOSUB 60
2020 INPUT #2,TOP
2030 FOR I=1 TO TOP-1
2040 INPUT #2,A:BPTR(I)=A
2050 INPUT #2,A:VALUE(I)=A
2060 INPUT #2,A:PROB(I)=A
2070 INPUT #2,A:NTYPE(I)=A
2080 FOR J=1 TO 5:INPUT #2,A:FPTR(I,J)=A:NEXT J
2090 INPUT #2,RESPONSE$
2100 IF LEN(RESPONSE$)<20 THEN RESPONSE$(LEN(RESPONSE$)+1)=SPACE$
2110 LABEL$(20*(I-1)+1,(20*I))=RESPONSE$
2120 NEXT I:? #1;"File has been read.":GOSUB 20040
2130 CLOSE #2:GOTO 10040
3000 REM SAVE TREE SECTION
3004 TRAP 600
3005 PRINT #1;"File to save to: ";:INPUT #1,RESPONSE$:GOSUB 20050
3010 CLOSE #2:OPEN #2,8,0,RESPONSE$:GOSUB 60
3020 PRINT #2;TOP
3030 FOR I=1 TO TOP-1
3040 PRINT #2;BPTR(I)
3050 PRINT #2;VALUE(I)
3060 PRINT #2;PROB(I)
3070 PRINT #2;NTYPE(I)
3080 FOR J=1 TO 5:PRINT #2;FPTR(I,J):NEXT J
3090 PRINT #2;LABEL$(20*(I-1)+1,20*I)
3100 NEXT I:? #1;"File has been saved.":GOSUB 20040
3110 CLOSE #2:GOTO 10040
4000 REM EDIT TREE SECTION
4004 CLOSE #1:OPEN #1,4,0,"E:":GOSUB 60:TRAP 500
4010 PRINT #1;"Node (0 to quit): ";:INPUT #1,ENODE:IF ENODE=0 THEN 10040
4015 EX=NTYPE(ENODE)
4020 ON EX GOTO 4030,4200,4400
4030 PRINT #1;"Options-":? #1:? #1;"0 - Exit":? #1;"1 - Change label"
4035 ? #1;"2 - Add Branch":? #1;"3 - Delete Branch"
4040 ? #1:? #1;"Option: ";:INPUT #1,OPT
4045 IF OPT>3 OR OPT<0 THEN 4030
4050 IF OPT=0 THEN 4190
4055 ON OPT GOTO 4060,4080,4105
4060 PRINT #1;"Label: ";:INPUT #1,RESPONSE$
4065 IF LEN(RESPONSE$)<20 THEN RESPONSE$(LEN(RESPONSE$)+1)=SPACE$
4070 LABEL$(20*(ENODE-1)+1,20*ENODE)=RESPONSE$
4075 GOTO 4030
4080 FOR I=1 TO 5:IF FPTR(ENODE,I)=0 THEN POP :GOTO 4088
4085 NEXT I:PRINT #1;"Too many banches.":GOTO 4030
4088 I=1
4090 IF FPTR(ENODE,I)<>0 THEN I=I+1:GOTO 4090
4095 FPTR(ENODE,I)=TOP:BPTR(TOP)=ENODE:TOP=TOP+1
4100 PRINT #1;"Done.":GOTO 1200
4105 PRINT #1;"Branches to nodes numbered:"
4110 FOR I=1 TO 5
4112 IF FPTR(ENODE,I)<>0 THEN PRINT #1;FPTR(ENODE,I);" ";LABEL$(20*(FPTR(ENODE,I)-1)+1,20*FPTR(ENODE,I))
4115 NEXT I
4120 PRINT #1;"Cut branch to which node #? ";:INPUT #1,BRANCH
4125 I=1
4130 IF FPTR(ENODE,I)<>BRANCH THEN I=I+1:GOTO 4130
4135 FPTR(ENODE,I)=0:PRINT #1;"Done.":GOTO 4030
4190 IF EDFLG=0 THEN 4000
4195 GOTO 1200
4200 ? #1;"Options-":? #1:? #1;"0 - Exit":? #1;"1 - Change label"
4205 PRINT #1;"2 - Add Branch":PRINT #1;"3 - Delete Branch"
4210 PRINT #1;"4 - Change Probabilities":PRINT #1
4215 PRINT #1;"Option: ";:INPUT #1,OPT:IF OPT<0 OR OPT>4 THEN 4200
4220 IF OPT=0 THEN 4190
4225 ON OPT GOTO 4230,4250,4290,4320
4230 PRINT #1;"Label: ";:INPUT #1,RESPONSE$
4235 IF LEN(RESPONSE$)<20 THEN RESPONSE$(LEN(RESPONSE$)+1)=SPACE$
4240 LABEL$(20*(ENODE-1)+1,20*ENODE)=RESPONSE$
4245 GOTO 4200
4250 I=1
4255 IF FPTR(ENODE,I)=0 THEN 4270
4260 I=I+1:IF I<5 THEN 4255
4265 PRINT #1;"Too many branches.":GOTO 4200
4270 REM
4275 FPTR(ENODE,I)=TOP:BPTR(TOP)=ENODE:REM FPTR
4280 PRINT #1;"Probability: ";:INPUT #1,PROBAB
4285 PROB(TOP)=PROBAB:TOP=TOP+1:GOTO 1200
4290 PRINT #1;"Branches to nodes numbered:":FOR I=1 TO 5
4295 IF FPTR(ENODE,I)<>0 THEN PRINT #1;FPTR(ENODE,I);" ";LABEL$(20*(FPTR(ENODE,I)-1)+1,20*FPTR(ENODE,I))
4300 NEXT I
4302 PRINT #1;"Cut branch to which node # ";:INPUT #1,BRANCH
4305 I=1
4310 IF FPTR(ENODE,I)<>BRANCH THEN I=I+1:GOTO 4310
4315 FPTR(ENODE,I)=0:PRINT #1;"Done.":GOTO 4200
4320 PRINT #1;"NODE PROB":FOR I=1 TO 5:IF FPTR(ENODE,I)=0 THEN 4325
4321 PRINT #1;FPTR(ENODE,I);" ";PROB(FPTR(ENODE,I));" ";
4322 PRINT #1;LABEL$(20*(FPTR(ENODE,I)-1)+1,20*FPTR(ENODE,I))
4325 NEXT I:PRINT #1;"New probabilities to node #":FOR I=1 TO 5
4330 IF FPTR(ENODE,I)=0 THEN 4340
4335 ? #1;FPTR(ENODE,I);" ";:INPUT #1,PROBAB:PROB(FPTR(ENODE,I))=PROBAB
4340 NEXT I
4345 GOTO 4200
4400 ? #1;"Options-":? #1:? #1;"0 - Exit":? #1;"1 - Change label"
4405 ? #1;"2 - Change value":? #1
4407 ? #1;"Option: ";:INPUT #1,OPT
4410 IF OPT<0 OR OPT>2 THEN 4400
4415 IF OPT=0 THEN 4000
4420 IF OPT=2 THEN 4450
4425 PRINT #1;"Label: ";:INPUT #1,RESPONSE$
4430 IF LEN(RESPONSE$)<20 THEN RESPONSE$(LEN(RESPONSE$)+1)=SPACE$
4435 LABEL$(20*(ENODE-1)+1,20*ENODE)=RESPONSE$
4440 GOTO 4400
4450 ? #1;"New Value: ";:INPUT #1,V
4455 VALUE(ENODE)=V:GOTO 4400
5000 REM SOLVE TREE SECTION
5004 TRAP 500
5010 PRINT #1;"Minimize (0) or Maximize(1): ";:INPUT #1,MM
5020 FOR I=1 TO TOP-1
5030 IF NTYPE(I)<>3 THEN VALUE(I)=-1
5035 NEXT I
5040 FOR I=1 TO TOP-1
5050 CNODE=I:REM CURRENT NODE
5060 IF NTYPE(CNODE)<>3 THEN 5230
5070 CNODE=BPTR(CNODE):IF CNODE=0 THEN POP :GOTO 5240
5080 IF NTYPE(CNODE)=2 THEN 5180
5090 V=-1:IF MM=0 THEN V=10^90
5100 FOR J=1 TO 5
5110 IF FPTR(CNODE,J)=0 THEN 5150
5120 IF VALUE(FPTR(CNODE,J))=-1 THEN POP :GOTO 5230
5130 IF MM=1 AND V<VALUE(FPTR(CNODE,J)) THEN V=VALUE(FPTR(CNODE,J))
5140 IF MM=0 AND V>VALUE(FPTR(CNODE,J)) THEN V=VALUE(FPTR(CNODE,J))
5150 NEXT J
5160 VALUE(CNODE)=V:GOTO 5070
5180 V=0
5185 FOR J=1 TO 5
5190 IF VALUE(FPTR(CNODE,J))=-1 THEN POP :GOTO 5230
5200 V=V+PROB(FPTR(CNODE,J))*VALUE(FPTR(CNODE,J))
5210 NEXT J
5220 VALUE(CNODE)=V:GOTO 5070
5230 NEXT I
5240 PRINT #1;"Solved.":GOSUB 20040
5250 GOTO 10040
6000 REM PRINT THE TREE SECTION
6004 TRAP 600
6010 PRINT #1;"Output to: ";:INPUT #1,RESPONSE$:GOSUB 20050
6020 CLOSE #2:OPEN #2,8,0,RESPONSE$:GOSUB 60
6030 FOR I=1 TO TOP-1
6040 PRINT #2;"Node # ";I;" ";LABEL$(20*(I-1)+1,20*I)
6050 EX=NTYPE(I):ON EX GOTO 6060,6130,6200
6060 ? #2;" Decision Value= ";VALUE(I)
6070 ? #2;" From node # ";BPTR(I);
6075 IF BPTR(I)<>0 THEN PRINT #2;" ";LABEL$(20*(BPTR(I)-1)+1,20*BPTR(I));
6077 ? #2
6080 FOR J=1 TO 5
6090 IF FPTR(I,J)=0 THEN 6110
6100 PRINT #2;" To node # ";FPTR(I,J);" ";LABEL$(20*(FPTR(I,J)-1)+1,20*FPTR(I,J))
6110 NEXT J
6120 PRINT #2:GOTO 6220
6130 PRINT #2;" Chance Value= ";VALUE(I)
6140 PRINT #2;" From node # ";BPTR(I);" ";LABEL$(20*(BPTR(I)-1)+1,20*BPTR(I))
6150 FOR J=1 TO 5
6160 IF FPTR(I,J)=0 THEN 6180
6170 PRINT #2;" To node # ";FPTR(I,J);" Prob: ";PROB(FPTR(I,J));" ";LABEL$(20*(FPTR(I,J)-1)+1,20*FPTR(I,J))
6180 NEXT J
6190 PRINT #2:GOTO 6220
6200 ? #2;" Terminal Value= ";VALUE(I)
6210 ? #2;" From node # ";BPTR(I);" ";LABEL$(20*(BPTR(I)-1)+1,20*BPTR(I))
6220 NEXT I
6230 CLOSE #2:GOSUB 20040
6240 GOTO 10040
10000 REM INITIALIZE SECTION
10010 DIM FPTR(200,5),BPTR(200),VALUE(200),NTYPE(200),PROB(200)
10020 DIM LABEL$(4000),RESPONSE$(20),SPACE$(20),TEMP$(22)
10025 VALUE(0)=0:PROB(0)=0
10030 SPACE$=" ":REM 20 SPACES
10035 FOR I=1 TO 200:NTYPE(I)=0:NEXT I:REM INIT NTYPE
10040 GRAPHICS 0:CLOSE #1:OPEN #1,4,0,"E:":GOSUB 60
10041 REM OPEN SCREEN FOR I/O
10050 PRINT #1;"Decision Analysis Program":PRINT #1:PRINT #1;"Options:"
10055 TRAP 500
10060 PRINT #1;"0 - Exit":PRINT #1;"1 - New Tree":PRINT #1;"2 - Recover Tree"
10070 PRINT #1;"3 - Save Tree":PRINT #1;"4 - Edit Tree":PRINT #1;"5 - Solve Tree"
10080 PRINT #1;"6 - Print Tree":PRINT #1
10085 POSITION 2,11:PRINT #1;"Option: ";:INPUT #1,OPT
10090 IF OPT<0 OR OPT>6 THEN 10040
10100 IF OPT=0 THEN 20000
10110 ? #1:ON OPT GOTO 1000,2000,3000,4000,5000,6000
20000 POSITION 2,13:? #1:? #1;"Are you sure you want to exit? (Y/N)";:INPUT #1,RESPONSE$
20010 IF RESPONSE$="Y" THEN GRAPHICS 0:END
20020 IF RESPONSE$="N" THEN 10040
20030 GOTO 20000
20040 FOR I=1 TO 150:NEXT I:RETURN
20050 IF LEN(RESPONSE$)>1 THEN IF RESPONSE$(2,2)=":" THEN 20080
20060 IF LEN(RESPONSE$)>2 THEN IF RESPONSE$(3,3)=":" THEN 20080
20070 TEMP$="D:":TEMP$(3)=RESPONSE$:RESPONSE$=TEMP$
20080 RETURN
