Garden Layout Program (MYGARDEN.BAS)

Garden Layout Program by Charles Bartish, 115 (BASIC, Garden data)

Description

Garden Layout Program by Charles Bartish, 115 (BASIC, Garden data)

From the Antic disk of May 1986 (Vol. 5 No. 1).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 12.5 KB

Dialect
Atari BASIC
Lines
364
Variables
R$, VEG$, TEMP$, DISROW(, DISPLT(, PLTF4(, HTSEQ(, ROWS(, ROWZ(, ROWGAR(, BL$, GARDEN$, J$, N, LONG, WIDE, I, FACT, M, D, J, II, LGARD, RM, HTSEQ, K, LTOT, KOLOR, TMP, L, P, TL, JJ, KK, JJJ, LGA
BASIC listing (364 lines)
1000 REM GARDEN LAYOUT PROGRAM
1010 REM BY CHARLES BARTISH
1015 REM (c) 1985, ANTIC PUBLISHING
1020 DIM R$(20),VEG$(600),TEMP$(600),DISROW(30),DISPLT(30),PLTF4(30),HTSEQ(30),ROWS(15),ROWZ(15),ROWGAR(70)
1030 DIM BL$(20),GARDEN$(14),J$(21):J$="HIT START TO CONTINUE":POKE 82,2
1040 GRAPHICS 18:SETCOLOR 3,4,8
1050 POSITION 8,4:PRINT #6;"my"
1060 POSITION 6,6:PRINT #6;"garden"
1070 FOR N=1 TO 2000:NEXT N:PRINT #6;CHR$(125):PRINT #6
1080 PRINT #6;" THIS PROGRAM WILL"
1090 PRINT #6;"   ASSIST YOU IN"
1100 PRINT #6;"PLANNING YOUR SPRING"
1110 PRINT #6;" GARDEN, BUT YOU'LL"
1120 PRINT #6;"  HAVE TO PLANT IT"
1130 PRINT #6;"     YOURSELF!"
1140 GOSUB 3380:REM INITIALIZE VEGETABLE CHOICES AND USE DELAY AS DISPLAY TIMER
1150 LONG=30:WIDE=15:I=1:REM DEFAULT DIMENSIONS IN FEET
1160 GOTO 2380:REM MENU
1170 GOSUB 3200:REM DRAW PLOT
1180 I=2
1190 GRAPHICS 0:POKE 82,1
1200 PRINT "   SELECT THE SIZE OF YOUR GARDEN":? :?
1210 PRINT "IF YOU'RE NOT SURE OF THE PROPER SIZE,"
1220 PRINT "ENTER 30 FOR LENGTH AND 15 FOR WIDTH."
1230 PRINT "WE'LL TELL YOU HOW MUCH ROOM YOU NEED.":PRINT :PRINT :PRINT
1240 TRAP 1240:PRINT "THE LENGTH IN FEET IS?":INPUT R$
1250 LONG=VAL(R$)
1260 TRAP 1260:PRINT "THE WIDTH IN FEET IS?":INPUT R$
1270 WIDE=VAL(R$):IF WIDE>LONG THEN N=LONG:LONG=WIDE:WIDE=N
1280 FACT=LONG*WIDE/450
1290 TRAP 40000
1300 GOSUB 3200
1310 REM PRINT VEGETABLE CHOICES
1320 GRAPHICS 0:POKE 752,1:POKE 82,2
1330 PRINT "     CHOOSE FROM THESE VEGETABLES.":PRINT
1340 M=0:FOR N=1 TO 15:M=N+15
1350 PRINT VEG$(N*20-19,N*20-2);VEG$(M*20-19,M*20-5)
1360 NEXT N
1370 PRINT :PRINT :PRINT "LET'S PICK THE VEGETABLES WE WANT.":PRINT J$
1380 IF PEEK(53279)<>6 THEN 1380
1390 GRAPHICS 0:PRINT :PRINT
1400 PRINT "EACH VEGETABLE WILL FLASH ONTO THE":PRINT "SCREEN.  IF YOU WANT TO PLANT THAT"
1410 PRINT "VEGETABLE, RESPOND WITH Y FOR YES.":PRINT "IF AN ITEM IS NOT WANTED, JUST HIT"
1420 PRINT "RETURN.":PRINT :PRINT
1430 PRINT J$
1440 IF PEEK(53279)<>6 THEN 1440
1450 GRAPHICS 0:PRINT "           DO YOU WANT...?"
1460 I=1
1470 FOR N=1 TO 30
1480 POSITION 2,3:PRINT VEG$(N*20-19,N*20):INPUT R$
1490 IF R$<>"Y" THEN 1530
1500 VEG$(I*20-19,I*20)=VEG$(N*20-19,N*20)
1510 DISROW(I)=DISROW(N):DISPLT(I)=DISPLT(N):PLTF4(I)=INT(PLTF4(N)*FACT):HTSEQ(I)=HTSEQ(N)
1520 I=I+1
1530 PRINT "↑↑↑↑":NEXT N
1540 M=I-1
1550 GRAPHICS 0
1560 PRINT "        YOU HAVE SELECTED......":PRINT :PRINT :FOR D=1 TO 200:NEXT D
1570 FOR N=1 TO M
1580 PRINT VEG$(N*20-19,N*20)
1590 NEXT N
1600 PRINT :PRINT :PRINT "IF THE SELECTION IS CORRECT,":PRINT "HIT RETURN. OTHERWISE, TYPE 1"
1610 POKE 764,255:INPUT R$
1620 IF R$="1" THEN PRINT :PRINT "WAIT...":RESTORE 4000:GOSUB 3380:GOTO 1320
1630 GOSUB 3080:REM DISK STORAGE
1640 GRAPHICS 0:POKE 201,7
1650 PRINT "        VEGETABLE PRODUCTION":PRINT
1660 PRINT "VEGETABLE";"           ";"ROWS","PLANTS"
1670 PRINT "▔▔▔▔▔▔▔▔▔";"           ";"▔▔▔▔","▔▔▔▔▔▔"
1680 J=0
1690 FOR N=1 TO M
1700 ROWS(N)=(PLTF4(N)*DISPLT(N))/(12*(WIDE-1))
1710 ROWS(N)=INT(ROWS(N)+0.5):IF ROWS(N)<1 THEN ROWS(N)=1
1720 PRINT VEG$(N*20-19,N*20);ROWS(N),INT(PLTF4(N))
1730 J=J+ROWS(N)
1740 NEXT N
1750 PRINT "  Total Rows       ";J
1760 PRINT :PRINT :PRINT J$
1770 IF PEEK(53279)<>6 THEN 1770
1780 PRINT "↑↑":PRINT " ●CHANGE ROWS/PLANT NUMBERS: 1 RETURN":I=1
1790 PRINT " ●LOOK AT PLANT LIST AGAIN:  2 RETURN"
1800 PRINT " ●CONTINUE -- JUST PRESS:     RETURN "
1810 INPUT R$:IF R$="1" THEN GOSUB 3470:GOSUB 3080
1820 IF R$="2" THEN 1640
1830 IF I>1 THEN 1640
1840 REM PLANT THE GARDEN.  SEARCH FOR TALLEST PLANT
1850 POKE 82,0:I=0:II=0:LGARD=0:GRAPHICS 0:POKE 752,1:PRINT "             GARDEN SUMMARY"
1860 POSITION (40-LEN(GARDEN$)+6)/2,1:PRINT GARDEN$(3,LEN(GARDEN$)-4):PRINT
1870 PRINT "VEGETABLE         DISP   ROWS DISR SUM"
1880 PRINT "▔▔▔▔▔▔▔▔▔         ▔▔▔▔   ▔▔▔▔ ▔▔▔▔ ▔▔▔"
1890 PRINT "                inches   #  inches feet":PRINT
1900 POKE 201,5:RM=0
1910 FOR J=1 TO M
1920 HTSEQ=30:GOSUB 3700:HTSEQ(I)=HTSEQ(I)+30
1930 FOR K=1 TO ROWS(I)
1940 II=II+1
1950 IF II>70 THEN GOSUB 3950:END
1960 IF K=1 AND RM>DISROW(I) THEN ROWGAR(II)=LGARD+RM:GOTO 1980
1970 ROWGAR(II)=LGARD+DISROW(I)
1980 ROWGAR(1)=6
1990 LGARD=ROWGAR(II)
2000 NEXT K
2010 RM=DISROW(I)
2020 TEMP$(3*J-2,3*J)=VEG$(I*20-19,I*20-17):ROWZ(J)=ROWS(I):REM STORE DATA FOR PLOTTING
2025 LTOT=INT(10*LGARD/12)/10:IF LTOT>99.9 THEN LTOT=INT(LTOT)
2030 PRINT VEG$(I*20-19,I*20-2);DISPLT(I),ROWS(I),DISROW(I),LTOT
2040 NEXT J
2050 FOR J=1 TO M:HTSEQ(J)=HTSEQ(J)-30:NEXT J
2060 LGARD=LGARD/12+0.5:LGARD=INT(LGARD+0.5)
2070 PRINT :PRINT "***THE GARDEN LENGTH IS ";LGARD;" feet";"***"
2080 PRINT "***THE GARDEN WIDTH  IS ";WIDE;" feet";"***"
2090 IF LGARD>1.15*LONG THEN 3820
2100 PRINT :PRINT " START TO PLOT THE GARDEN."
2110 PRINT " START AFTER PLOT TO GET THIS PAGE."
2111 PRINT " SELECT FOR PRINTOUT."
2115 PRINT " OPTION TO RERUN PROGRAM.";
2120 IF PEEK(53279)=3 THEN ? :? "PLEASE WAIT...":RESTORE 4000:GOSUB 3380:GOTO 1150
2125 IF PEEK(53279)=6 THEN 2130
2126 IF PEEK(53279)=5 THEN 5000
2127 GOTO 2120
2130 GRAPHICS 7:POKE 709,198:COLOR 2:REM COLOR 2 GREEN
2140 J=142
2150 K=J*WIDE/LGARD
2160 IF K>80 THEN J=0.95*J:GOTO 2150
2170 POKE 710,0:REM COLOR 3 BLACK
2180 PLOT 150,79
2190 DRAWTO 150,79-K:DRAWTO 150-J,79-K:POSITION 150-J,79
2200 POKE 765,2
2210 XIO 18,#6,0,0,"S:"
2220 II=0:KOLOR=1
2230 POKE 708,14:REM COLOR 1 WHITE
2240 FOR N=1 TO M
2250 IF KOLOR>3 THEN KOLOR=1
2260 COLOR KOLOR
2270 FOR I=1 TO ROWZ(N)
2280 II=II+1
2290 IF I=1 THEN GOSUB 3740
2300 PLOT 150-J+(ROWGAR(II)/12)*J/LGARD,76
2310 DRAWTO 150-J+(ROWGAR(II)/12)*J/LGARD,80-K+2
2320 NEXT I
2330 KOLOR=KOLOR+2
2340 NEXT N
2350 POKE 77,0:IF PEEK(53279)<>6 THEN 2350
2360 POKE 82,2:GOTO 1850
2370 REM END OF MAIN PROGRAM. SUBROUTINES FOLLOW
2380 REM MENU
2390 GRAPHICS 0:SETCOLOR 2,9,2
2400 TRAP 2390
2410 PRINT "                CHOICES":PRINT :PRINT
2420 PRINT "    MAKE NEW GARDEN         1"
2430 PRINT "    RECALL PREVIOUS GARDEN  2"
2440 PRINT :PRINT :PRINT "  TYPE NUMBER OF CHOICE, RETURN";
2450 INPUT R$:I=VAL(R$)
2460 IF I>2 THEN 2390
2470 TRAP 40000
2480 ON I GOTO 2490,2570
2490 GOSUB 2810
2500 PRINT :PRINT "GIVE THE GARDEN A NAME, e.g., CMB1985."
2510 PRINT "I'LL ADD THE SUFFIX .GAR TO THE NAME."
2520 INPUT R$
2530 GARDEN$="D:"
2540 GARDEN$(3)=R$
2550 GARDEN$(LEN(GARDEN$)+1)=".GAR"
2560 GOTO 1170
2570 GOSUB 2810
2580 PRINT :PRINT "WHICH GARDEN DO YOU WANT TO RECALL"
2590 INPUT R$:IF R$(LEN(R$)-3)=".GAR" THEN R$=R$(1,LEN(R$)-4)
2600 GARDEN$="D:"
2610 GARDEN$(3)=R$
2620 GARDEN$(LEN(GARDEN$)+1)=".GAR"
2630 REM OPEN DISK FILE TO INPUT STORED DATA
2640 OPEN #1,4,0,GARDEN$
2650 INPUT #1;WIDE
2660 INPUT #1;FACT
2670 INPUT #1;M
2680 INPUT #1;TEMP$:VEG$(1,200)=TEMP$
2690 INPUT #1;TEMP$:VEG$(201,400)=TEMP$
2700 INPUT #1;TEMP$:VEG$(401,600)=TEMP$
2710 FOR I=1 TO M
2720 INPUT #1;TMP:ROWS(I)=TMP
2730 INPUT #1;TMP:HTSEQ(I)=TMP
2740 INPUT #1;TMP:DISROW(I)=TMP
2750 INPUT #1;TMP:DISPLT(I)=TMP
2760 INPUT #1;TMP:PLTF4(I)=TMP
2770 NEXT I
2780 CLOSE #1
2790 GOTO 1640:REM RETURN TO MAIN PROGRAM TO PLOT RECALLED DATA
2800 REM SUBROUTINE TO PRINT DISK DIRECTORY
2810 SETCOLOR 2,12,2:PRINT "↰               DIRECTORY":PRINT
2820 R$="D:*.GAR"
2830 OPEN #1,6,0,R$
2840 TRAP 2880
2850 INPUT #1,R$
2860 PRINT R$
2870 GOTO 2850
2880 CLOSE #1:TRAP 40000:PRINT
2890 RETURN
2900 REM OPEN DISK FILE TO PRINT STORED DATA
2910 OPEN #1,8,0,GARDEN$
2920 PRINT #1;WIDE
2930 PRINT #1;FACT
2940 PRINT #1;M
2950 TEMP$=VEG$(1,200):PRINT #1;TEMP$
2960 TEMP$=VEG$(201,400):PRINT #1;TEMP$
2970 TEMP$=VEG$(401,600):PRINT #1;TEMP$
2980 FOR I=1 TO M
2990 TMP=ROWS(I):PRINT #1;TMP
3000 TMP=HTSEQ(I):PRINT #1;TMP
3010 TMP=DISROW(I):PRINT #1;TMP
3020 TMP=DISPLT(I):PRINT #1;TMP
3030 TMP=PLTF4(I):PRINT #1;TMP
3040 NEXT I
3050 CLOSE #1
3060 PRINT "DISK SAVE COMPLETE":FOR I=1 TO 200:NEXT I
3070 RETURN
3080 REM DISK STORAGE SUBROUTINE
3090 GRAPHICS 0:SETCOLOR 2,9,2
3100 PRINT "              DISK STORAGE":PRINT
3110 PRINT "DO YOU WISH TO STORE THIS GARDEN?":PRINT "IF YOU DO, HIT Y AND RETURN."
3120 PRINT :PRINT "CURRENT GARDEN NAME IS ";GARDEN$(3)
3130 INPUT R$:IF R$<>"Y" THEN 3180
3140 PRINT :PRINT "DO YOU WANT A DIFFERENT NAME?":PRINT "IF YOU DO, HIT Y AND RETURN."
3150 INPUT R$:IF R$<>"Y" THEN GOSUB 2910:GOTO 3180
3160 PRINT "TYPE IN NEW NAME. I'LL ADD THE .GAR"
3170 INPUT R$:GARDEN$(3)=R$:GARDEN$(LEN(GARDEN$)+1)=".GAR":PRINT GARDEN$:GOSUB 2910
3180 RETURN
3190 REM LENGTH AND WIDTH PLOT
3200 GRAPHICS 0:POKE 752,1
3210 IF I=1 THEN POKE 710,0
3220 IF I=2 THEN POKE 710,196:POKE 709,204
3230 POSITION 19,3:PRINT LONG:POSITION 36,12:PRINT WIDE:POSITION 5,4
3240 FOR N=1 TO 15:PRINT CHR$(124):POSITION 5,4+N:NEXT N:PRINT CHR$(26)
3250 FOR N=1 TO 30:POSITION 5+N,19:PRINT CHR$(18):NEXT N:POSITION 35,19:PRINT CHR$(3)
3260 FOR N=1 TO 15:POSITION 35,19-N:PRINT CHR$(124):NEXT N:POSITION 35,4:PRINT CHR$(5)
3270 FOR N=1 TO 30:POSITION 35-N,4:PRINT CHR$(18):POSITION 35-N,4:NEXT N:PRINT CHR$(17)
3280 IF I=1 THEN POSITION 6,7:PRINT "WHAT SIZE GARDEN DO YOU WANT?"
3290 IF I=1 THEN BL$="   MY ":TEMP$=" US"
3300 IF I=2 THEN BL$=" YOUR ":TEMP$=" YOU"
3310 POSITION 6,9:PRINT BL$;WIDE;"x";LONG;" PLOT GIVES";TEMP$
3320 POSITION 6,10:PRINT " PLENTY OF FRESH VEGETABLES,"
3330 POSITION 6,11:PRINT " AND IS NOT A FULLTIME CHORE"
3340 POSITION 6,12:PRINT " TO MAINTAIN."
3350 POSITION 6,18:PRINT J$
3360 IF PEEK(53279)<>6 THEN 3360
3370 RETURN
3380 BL$=" ":BL$(20)=BL$:BL$(2)=BL$
3390 FOR N=1 TO 30
3400 READ TEMP$,I,J,K,L:DISROW(N)=I:DISPLT(N)=J:PLTF4(N)=K:HTSEQ(N)=L
3410 FOR P=1 TO 20
3420 TL=LEN(TEMP$):IF TL<20 THEN TEMP$(TL+1)=BL$
3430 NEXT P
3440 VEG$(N*20-19,N*20)=TEMP$
3450 NEXT N
3460 RETURN
3470 I=I+1:FOR N=1 TO M:GRAPHICS 0
3480 PRINT "               CHANGES"
3490 PRINT :PRINT :PRINT "TO CHANGE NUMBER OF ROWS,   TYPE R.":PRINT "TO CHANGE NUMBER OF PLANTS, TYPE P."
3500 PRINT "OTHERWISE, HIT RETURN.":PRINT
3510 PRINT "************************************"
3520 PRINT :PRINT :PRINT :PRINT "VEGETABLE           ";"ROWS","PLANTS"
3530 PRINT "▔▔▔▔▔▔▔▔▔           ";"▔▔▔▔","▔▔▔▔▔▔"
3540 PRINT VEG$(N*20-19,N*20);ROWS(N),PLTF4(N)
3550 INPUT R$
3560 IF R$="R" THEN GOSUB 3600
3570 IF R$="P" THEN GOSUB 3650
3580 NEXT N
3590 RETURN
3600 PRINT :PRINT "ENTER THE NEW NUMBER OF ROWS"
3610 INPUT R$
3620 ROWS(N)=VAL(R$)
3630 PLTF4(N)=(ROWS(N)*12*(WIDE-1))/DISPLT(N)
3640 RETURN
3650 PRINT :PRINT "ENTER THE NEW NUMBER OF PLANTS"
3660 INPUT R$
3670 PLTF4(N)=VAL(R$)
3680 ROWS(N)=(PLTF4(N)*DISPLT(N))/(12*(WIDE-1))
3690 RETURN
3700 FOR N=1 TO M
3710 IF HTSEQ(N)<HTSEQ THEN HTSEQ=HTSEQ(N):I=N
3720 NEXT N
3730 RETURN
3740 JJ=(J/142)*38:KK=INT((ROWGAR(II)/12)*(JJ-2)/LGARD)
3750 FOR JJJ=0 TO 3
3760 POKE 752,1:POKE 656,JJJ:POKE 657,40-JJ+KK
3770 IF JJJ=3 THEN PRINT ROWZ(N);"↑":GOTO 3790
3780 PRINT TEMP$(3*N-2+JJJ,3*N-2+JJJ)
3790 NEXT JJJ
3800 RETURN
3810 REM ERROR SUBROUTINES
3820 GRAPHICS 0:? :? "THE LENGTH IS GREATER THAN YOUR LIMIT.":? "   PICKED",LONG:? "   ACTUAL",LGARD
3830 PRINT :PRINT :PRINT "         HERE ARE YOUR OPTIONS"
3840 PRINT :PRINT "OPTION                         KEY"
3850 PRINT "▔▔▔▔▔▔                         ▔▔▔":PRINT
3860 PRINT "ACCEPT NEW LENGTH--CONTINUE     1"
3870 PRINT "REDUCE SPACING OF ALL BY 10%    2"
3880 PRINT "CHANGE NUMBER OF ROWS/PLANTS    3"
3890 PRINT "CHANGE DATA OF CERTAIN VEG      4"
3900 TRAP 3820:PRINT :INPUT R$
3910 ON VAL(R$) GOTO 3920,3930,1640,3940
3920 TRAP 40000:LONG=LGARD:GOTO 1850
3930 TRAP 40000:FOR J=1 TO M:DISROW(J)=INT(0.9*DISROW(J)):NEXT J:GOTO 1850
3940 TRAP 40000:GRAPHICS 0:LIST 4000,4290:END
3950 PRINT :PRINT "YOU HAVE EXCEEDED 70 ROWS.":PRINT "EITHER REDIMENSION 'ROWGAR' IN"
3960 PRINT "LINE 1020, OR REDUCE THE SIZE OF YOUR":PRINT "GARDEN!"
3970 PRINT "THE GRAPHIC RESOLUTION WILL BE POOR!"
3980 RETURN
3990 REM DATA VEGETABLE, ROW DISTANCE,PLANT DISTANCE, STANDARD NUMBER OF PLANTS, HEIGHT SEQUENCE
4000 DATA ASPARAGUS,42,18,10,3
4010 DATA BEANS--SNAP BUSH,18,4,172,18
4020 DATA BEANS--SNAP POLE,36,6,58,1
4030 DATA BEANS--LIMA,24,3,228,8
4040 DATA BEETS,20,2,85,12
4050 DATA BROCCOLI,24,18,6,9
4060 DATA BRUSSELS SPROUTS,24,18,6,10
4070 DATA CABBAGE,24,18,10,19
4080 DATA CANTELOUPE,60,24,8,20
4090 DATA CARROTS,12,2,85,26
4100 DATA CAULIFLOWER,24,18,6,11
4110 DATA CELERY,24,6,29,13
4120 DATA CB1-BRUS/BRO/CAU,24,18,6,9
4130 DATA CB2-CARRT/RADSH,12,2,85,26
4140 DATA CORN,12,12,45,2
4150 DATA CUCUMBERS,36,18,10,5
4160 DATA EGGPLANT,24,18,10,6
4170 DATA LETTUCE--HEAD,18,12,15,16
4180 DATA LETTUCE--LEAF,18,3,57,25
4190 DATA ONIONS,12,4,129,24
4200 DATA PEAS,24,3,228,7
4210 DATA PEPPERS,24,18,10,17
4220 DATA POTATOES,30,12,45,14
4230 DATA PUMPKINS,60,24,8,22
4240 DATA RADISHES,12,1,85,28
4250 DATA SPINACH,18,3,57,27
4260 DATA SQUASH,48,18,10,21
4270 DATA TOMATOES,36,36,15,4
4280 DATA TURNIPS,18,2,85,15
4290 DATA WATERMELON,72,36,5,23
5000 I=0:II=0:LGARD=0:LPRINT ,"GARDEN SUMMARY"
5010 LPRINT ,GARDEN$(3,LEN(GARDEN$)-4):PRINT
5020 LPRINT "VEGETABLE         DISP   ROWS DISR SUM"
5030 LPRINT "---------         ----   ---- ---- ---"
5040 LPRINT "                inches   #  inches feet":LPRINT
5050 POKE 201,5:RM=0
5060 FOR J=1 TO M
5070 HTSEQ=30:GOSUB 3700:HTSEQ(I)=HTSEQ(I)+30
5080 FOR K=1 TO ROWS(I)
5090 II=II+1
5100 IF II>70 THEN GOSUB 3950:END
5110 IF K=1 AND RM>DISROW(I) THEN ROWGAR(II)=LGARD+RM:GOTO 5130
5120 ROWGAR(II)=LGARD+DISROW(I)
5130 ROWGAR(1)=6
5140 LGARD=ROWGAR(II)
5150 NEXT K
5160 RM=DISROW(I)
5170 TEMP$(3*J-2,3*J)=VEG$(I*20-19,I*20-17):ROWZ(J)=ROWS(I):REM STORE DATA FOR PLOTTING
5180 LTOT=INT(10*LGARD/12)/10:IF LTOT>99.9 THEN LTOT=INT(LTOT)
5190 LPRINT VEG$(I*20-19,I*20-2);DISPLT(I),ROWS(I),DISROW(I),LTOT
5200 NEXT J
5210 FOR J=1 TO M:HTSEQ(J)=HTSEQ(J)-30:NEXT J
5220 LGARD=LGARD/12+0.5:LGARD=INT(LGARD+0.5)
5230 LPRINT :LPRINT "***THE GARDEN LENGTH IS ";LGARD;" feet";"***"
5240 LPRINT "***THE GARDEN WIDTH  IS ";WIDE;" feet";"***"
5250 IF LGARD>1.15*LONG THEN 3820
5260 GOTO 1850