game (HEXCON.BAS)

game by Bruce Brigden, 23

Description

game by Bruce Brigden, 23

From the Antic disk of May 1986 (Vol. 5 No. 1).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 2.8 KB

Dialect
Atari BASIC
Lines
60
Variables
I, HEX$, H$, B$, N$, K, X, N, DEC, R, F, MM, HH, AN$, DC, HX, F$, TEST
BASIC listing (60 lines)
5 REM HEXCON
6 REM BY BRUCE BRIGDEN
7 REM (c) 1986, ANTIC PUBLISHING
10 GOTO 30
20 GRAPHICS 18:POKE 712,10:POKE 711,196:POKE 710,22:POKE 709,68:POKE 708,132:RETURN
30 CLOSE #1:OPEN #1,4,0,"K":DIM H$(16),N$(10),HEX$(20),AN$(20)
40 GOSUB 20:POSITION 4,1:? #6;"hex/decimal"
50 POSITION 0,3:? #6;"CONVERSION PROGRAMS"
60 POSITION 2,5:? #6;"hex TO decimal?                         decimal TO hex?"
70 POSITION 2,9:? #6;"(CHOOSE h OR d)"
80 GET #1,K:IF K<68 OR K>72 THEN 70
90 IF K=72 THEN 410
100 GOSUB 20:H$="0123456789ABCDEF"
110 POSITION 0,1:? #6;"  CONVERTS decIMAL     NUMBERS TO hex"
130 POSITION 4,5:? #6;"YOUR NUMBER?":N$="":HEX$="":AN$="":TEST=0:POSITION 4,7:? #6;"dec:";
140 GET #1,X:TRAP 610:IF X=155 THEN GOTO 200
150 IF X=126 THEN N$="":POSITION 10,7:? #6;"         ":GOTO 130
160 IF X=27 THEN GOTO 410
170 IF X<48 OR X>57 THEN 140
180 N$(LEN(N$)+1)=CHR$(X)
190 POSITION 10,7:? #6;N$
195 GOTO 140
200 N=4294967290:DEC=VAL(N$):POSITION 4,9:? #6;"hex:":POSITION 10,9
210 FOR X=8 TO 1 STEP -1
220 N=N/16
230 R=INT(DEC/N)
240 IF R>=1 THEN DEC=DEC-(R*N)
250 HEX$=H$(R+1,R+1):AN$(LEN(AN$)+1)=HEX$:NEXT X
260 FOR I=1 TO LEN(AN$):TEST=TEST+ASC(AN$(I,I)):IF TEST>I*48 THEN GOTO 265
264 GOTO 270
265 ? #6;AN$(I,I);
270 NEXT I
280 GET #1,F:POSITION 10,7:? #6;"                      ":POSITION 10,9:? #6;"                   "
290 GOTO 130
400 REM HEX TO DECIMAL CONVERSION
410 GOSUB 20
420 POSITION 2,1:? #6;"  CONVERTS hex       NUMBERS TO dec"
425 POSITION 4,7:? #6;"hex:"
430 POSITION 4,5:? #6;"YOUR NUMBER?":HEX$=""
440 GET #1,X:TRAP 610:IF X=155 THEN 530
450 IF X=126 THEN POSITION 10,7:? #6;"        ":HEX$="":GOTO 430
460 IF X=27 THEN HEX$="":GOTO 100
470 IF X<48 OR X>70 THEN GOTO 440
500 HEX$(LEN(HEX$)+1)=CHR$(X)
510 POSITION 10,7:PRINT #6;HEX$
520 GOTO 440
530 POSITION 4,9:? #6;"dec:"
540 DC=0:HX=0
550 FOR X=1 TO LEN(HEX$)
560 HX=ASC(HEX$(X,X))-48
570 DC=16*DC+HX-7*(HX>9)
580 NEXT X
590 POSITION 10,9:? #6;DC
600 GET #1,F:POSITION 10,7:? #6;"                    ":POSITION 10,9:? #6;"                     "
605 GOTO 430
610 REM ERROR TRAP ROUTINE
620 GRAPHICS 0:? CHR$(125):POSITION 2,10
630 ? "SORRY! THIS PROGRAM LIMITS YOU TO A"
640 ? "DECIMAL INPUT OF 4.2 BILLION OR A HEX INPUT OF 20 CHARACTERS!"
650 ? "      (HIT ANY KEY TO RESTART!)":GET #1,R:RUN