New Owner's Column #2 (NEWOWN2.BAS)

New Owner's Column #2 by David Plotkin, 14

Description

New Owner's Column #2 by David Plotkin, 14

From the Antic disk of April 1986 (Vol. 4 No. 12).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 1.6 KB

Dialect
Atari BASIC
Lines
28
Variables
NAME$, W, WAIT, ANS$, DRAW$, PS, HOLD$, MSG$, CNT, HLD
BASIC listing (28 lines)
10 REM THE NEW OWNERS COLUMN
20 REM DEMO PROGRAM NUMBER TWO
30 REM BY DAVID PLOTKIN
40 REM (c) 1985, ANTIC PUBLISHING
60 REM SET UP THE VARIABLES
70 DIM NAME$(20),ANS$(2),DRAW$(4),HOLD$(100),MSG$(20)
80 REM SET UP THE SCREEN
90 GRAPHICS 0:POKE 752,1:PRINT :REM TURN OFF THE CURSOR
100 REM CYCLE THE SCREEN COLORS AND           MAKE SOME NOISE
110 FOR W=10 TO 250 STEP 10:POKE 710,W:SOUND 0,W,12,4
120 FOR WAIT=0 TO 20:NEXT WAIT:NEXT W:POKE 710,148:SOUND 0,0,0,0:POKE 752,0
130 REM GET THE NAME OF THE READER
140 POSITION 2,5:? "PLEASE TYPE IN YOUR NAME":INPUT NAME$
150 IF LEN(NAME$)>18 THEN POSITION 2,8:PRINT "OOPS...YOU HAVE A LONG NAME!"
160 POSITION 2,10:? "YOUR NAME IS ";NAME$:POSITION 2,11:? "IS THIS CORRECT (Y OR N)";:INPUT ANS$
170 IF ANS$<>"Y" AND ANS$<>"y" THEN GRAPHICS 0:GOTO 140
180 DRAW$="*◣◣*":REM ASTERISK,CONTROL-J,INVERSE CONTROL-J,INVERSE ASTERISK
185 REM DRAW THE MARQUIS
190 GRAPHICS 2+16:FOR PS=0 TO 17 STEP 4:POSITION PS,3:PRINT #6;DRAW$:POSITION PS,8:PRINT #6;DRAW$:NEXT PS
200 HOLD$="                    AT LEAST I HAVE ONE READER NAMED ":HOLD$(54)=NAME$:CNT=1
205 HOLD$(LEN(HOLD$)+1)="                    "
210 MSG$=HOLD$(CNT,CNT+20):CNT=CNT+1:IF CNT>LEN(HOLD$)-20 THEN CNT=1
215 REM PRINT THE SCROLLING MESSAGE
220 POSITION 0,5:PRINT #6;MSG$;
225 REM ROTATE THE COLORS!
230 HLD=PEEK(708):POKE 708,PEEK(709):POKE 709,PEEK(710):POKE 710,PEEK(711):POKE 711,HLD
235 REM SOME SOUND FOR EFFECT
240 SOUND 0,HLD,10,2:SOUND 1,HLD+5,10,2:SOUND 2,HLD+10,10,2:GOTO 210