Stick Writer, programming demo (STIKWRIT.BAS)
Stick Writer, programming demo by Bill Lukeroth, 40
Description
Stick Writer, programming demo by Bill Lukeroth, 40
From the Antic disk of March 1986 (Vol. 4 No. 11).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 4.8 KB
- Dialect
- Atari BASIC
- Lines
- 114
- Variables
BB,L,MAIN$,TEMP$,COL,ARY(,L2,WORD$,PUNC$,WORD,FLAG1,OLDWORD,PAUSE,MOVE,P,PIX$,SCRN$,XX,YY,ERR,ERRLN,TITLE,L0,S
BASIC listing (114 lines)
10 REM STICK WRITER
20 REM BY BILL LUKEROTH
30 REM (c) 1985, ANTIC PUBLISHING
40 GOSUB 1030:REM SET UP PROGRAM
50 GOTO 170
60 STOP
70 POKE 752,1:RETURN :REM CURSOR OFF
80 POKE 752,0:RETURN :REM CURSOR ON
90 POKE 16,112:POKE 53774,112:RETURN :REM DISABLE BREAK KEY
100 POSITION 2,19:FOR L=1 TO 189:? " ";:NEXT L:RETURN :REM CLEAR SCREEN
110 IF LEN(MAIN$)<=1 THEN 130
120 MAIN$=MAIN$(1,LEN(MAIN$)-1)
130 RETURN
140 IF LEN(TEMP$)<=1 THEN 160
150 TEMP$=TEMP$(1,LEN(TEMP$)-1)
160 RETURN
170 GRAPHICS 0:GOSUB 90:OPEN #1,4,0,"K:"
180 GOSUB 70:POKE 709,PEEK(710):REM TURN OFF CURSOR, SET CHARACTER COLOR TO BACKGROUND COLOR
190 FOR L=1 TO 6:READ COL:ARY(L)=COL:NEXT L:REM PRINT WORD SCREEN
200 FOR L=1 TO 6
210 FOR L2=0 TO 11:READ WORD$:POSITION ARY(L),L2:? WORD$:NEXT L2
220 NEXT L
230 FOR L=65 TO 82:? CHR$(L);" ";:NEXT L:?
240 FOR L=83 TO 90:? CHR$(L);" ";:NEXT L
250 FOR L=48 TO 57:? CHR$(L);" ";:NEXT L:?
260 FOR L=1 TO 18:? PUNC$(L,L);" ";:NEXT L:?
270 ? "CLEAR SCREEN BACKSPACE PRINT"
280 ? "ERASE MEMORY DELETE WORD RING BELL"
290 ? "VOICE QUIT"
300 FOR L=1 TO 38:? "─";:NEXT L
310 ? "DIRECTIONS:use the joystick to move the cursor to the desired word,then press the joystick button."
320 ? "TO START:press the joystick button."
330 POKE 709,154:REM MAKE CHARACTERS VISIBLE
340 IF STRIG(0)=1 THEN 340
350 WORD=0
360 CLOSE #2:GOSUB 100:TEMP$="":FLAG1=0
370 POSITION 19,5:GOSUB 80:? " ";:REM JOYSTICK ROUTINE
380 OLDWORD=WORD:WORD=0:PAUSE=0:IF FLAG1=1 THEN 410
390 IF LEN(MAIN$)<4000-200 THEN 410
400 POKE 710,48:POSITION 2,18:? "MEMORY CRITICAL.ERASE,PRINT OR QUIT. ":POSITION 19,5:? " ";:FLAG1=1
410 MOVE=STICK(0):POKE 77,0:REM DISABLE ATTRACT MODE
420 IF MOVE=15 THEN 540
430 IF INT(MOVE/2)<>MOVE/2 THEN 470
440 IF PEEK(84)=0 THEN POKE 84,18
450 ? "↑";
460 GOTO 500
470 IF MOVE=11 OR MOVE=7 THEN 500
480 IF PEEK(84)=17 THEN POKE 84,23
490 ? "↓";
500 IF MOVE>8 AND MOVE<12 THEN ? "←";
510 IF MOVE>4 AND MOVE<8 THEN ? "→";
520 PAUSE=PAUSE+1:IF PAUSE>16 THEN PAUSE=16
530 FOR L=0 TO PAUSE:NEXT L:REM SLOW DOWN CURSOR
540 IF STRIG(0)=0 THEN 560
550 GOTO 410
560 WORD=WORD+1:LOCATE PEEK(85),PEEK(84),P
570 PIX$=CHR$(P):IF P<123 THEN 680:REM CURSOR OVER INVERSE CHARACTER
580 SCRN$=CHR$(P-128)
590 IF LEN(MAIN$)=4000 THEN 410:REM MEMORY FULL, ACCEPT ERASE, PRINT OR QUIT
600 ? CHR$(126);:? SCRN$;:REM BACKSPACE, REPRINT LETTER
610 MAIN$(LEN(MAIN$)+1)=SCRN$
620 TEMP$(LEN(TEMP$)+1)=PIX$
630 IF SCRN$<>" " THEN 560
640 IF WORD=2 THEN GOSUB 110:GOSUB 140:GOTO 650:REM DELETE BLANK SPACE AFTER SINGLE LETTERS
650 IF LEN(TEMP$)>151 THEN TEMP$=TEMP$(LEN(TEMP$)-112,LEN(TEMP$)):GOSUB 100
660 POSITION 2,19:? TEMP$:REM PRINT WORD IN WINDOW
670 GOTO 370
680 IF PIX$="Q" THEN 860:REM COMMAND ROUTINE
690 IF PIX$="E" THEN MAIN$="":GOTO 360
700 IF PIX$<>"P" THEN 750
710 OPEN #2,8,0,"P:"
720 ? #2,MAIN$
730 CLOSE #2
740 GOTO 360
750 IF LEN(MAIN$)=4000 THEN 360
760 IF PIX$="C" THEN 360
770 IF PIX$<>"R" THEN 800
780 FOR XX=1 TO 8:SOUND 0,47,10,15:FOR YY=1 TO 75:NEXT YY:SOUND 0,64,10,15:FOR YY=1 TO 75:NEXT YY:NEXT XX
790 SOUND 0,0,0,0:GOTO 370
800 IF PIX$="B" THEN GOSUB 110:GOSUB 140:GOSUB 100:WORD=WORD-1:GOTO 660
810 IF PIX$<>"D" THEN 840
820 FOR L=1 TO OLDWORD:GOSUB 110:GOSUB 140:NEXT L
830 GOSUB 100:GOTO 660
840 REM POKE 8208,100:CLOSE#2:OPEN #2,8,0,"V:":?#2;MAIN$:CLOSE#2
850 GOTO 360
860 CLOSE #1:GRAPHICS 0:END
870 REM DATA FOR WORD SCREEN
880 DATA 2,8,13,19,23,30
890 DATA DID,HAVE,HOW,I'M,LET,THAT,WAS,WILL,WHO,WHAT,WHY,WHEN
900 DATA ALL,ARE,CAN,EAT,GET,HER,HIS,OUR,SEE,THE,YES,YOU
910 DATA COLD,FOOD,HOME,MUST,NEED,SEEN,SICK,PLAY,SOME,TOO,YOUR,WORK
920 DATA AM,AT,DO,HI,IS, ,IT,ME,MY,NO,TO,WE
930 DATA DRINK,HAPPY,LET'S,LOVE,ROOM,SLEEP,TELL,THERE,THEIR,THINK,TIME,WHERE
940 DATA BATHROOM,DOES,GO,GOING,GOOD,HOT,MEDICINE,NOT,NOW,PLEASE,THANKS,THIS
950 ? CHR$(253);:GOSUB 100:REM ERRORS
960 ERR=PEEK(195):ERRLN=PEEK(187)*256+PEEK(186)
970 IF ERR<>138 THEN 990
980 POSITION 2,19:? "PRINTER ERROR.CHECK PRINTER AND CABLE.":GOTO 1000
990 POSITION 2,19:? "ERROR ";ERR;" AT LINE ";ERRLN
1000 ? "PRESS JOYSTICK BUTTON TO CONTINUE."
1010 IF STRIG(0)=1 THEN 1010
1020 CLOSE #2:TRAP 950:GOSUB 100:GOTO 660
1030 TRAP 950
1040 DIM WORD$(8),MAIN$(4000),PUNC$(18),ARY(6),PIX$(1),SCRN$(1),TEMP$(175)
1050 PUNC$=",;:.!?'#()&$%*+-/="
1060 GRAPHICS 2+16:POKE 708,0:POKE 710,132:POKE 712,30:POKE 65,0:POKE 731,1
1070 ? #6:? #6;" STICK WRITER":? #6:? #6:? #6
1080 ? #6;" BY":? #6:? #6:? #6;" BILL LUKEROTH"
1090 FOR TITLE=1 TO 30:IF STRIG(0)=0 THEN POP :GOTO 1140
1100 FOR L0=1 TO 50:NEXT L0:IF S=0 THEN S=10:GOTO 1120
1110 S=0
1120 SETCOLOR 2,8,S
1130 NEXT TITLE
1140 RETURN
