programming demo (BITZ.BAS)
programming demo by Don Lebow, 55 (BASIC, MAC/65 source)
Description
programming demo by Don Lebow, 55 (BASIC, MAC/65 source)
From the Antic disk of March 1986 (Vol. 4 No. 11).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 4.0 KB
- Dialect
- Atari BASIC
- Lines
- 71
- Variables
C$,X,NUM,J,I,A,HEX$,CV$,B$,HP,M$,CHOICE,DLIST,OP1$,OP2$,OP1(,OP2(,B,RESULT,FLAGS,FLAGOPT,OPCODE1,OPCODE2,BYTES,O,WHICHTYPE,NUM1,NUM2
BASIC listing (71 lines)
10 REM BITZ
20 REM BY DON LEBOW
30 REM (c) 1985, ANTIC PUBLISHING
100 GOTO 1400:REM SUBROUTINES AT THE TOP
200 REM NUMBER CONVERSIONS
300 ? C$:X=NUM:J=16:FOR I=2 TO 3:A=INT(X/J):HEX$(I,I)=CV$(A+1)
400 X=X-J*A:J=1:NEXT I:REM HEX CONVERT
500 X=USR(1581,ADR(B$),NUM):REM BINARY CONVERT
600 RETURN
700 REM INPUT DECIMAL
800 TRAP 800:? C$:POKE HP,15:? M$;:INPUT NUM:IF NUM>255 THEN 800:REM SINGLE BYTES ONLY!
900 TRAP 40000:RETURN
1000 REM MENU AND CHOICE
1100 POKE HP,6:FOR J=0 TO 3:? J+1;" ";M$(J*3+1,J*3+3);" ";:NEXT J:?
1200 POKE HP,15:? "option...";:GET #4,CHOICE:CHOICE=CHOICE-48:IF CHOICE<1 OR CHOICE>4 THEN ? C$:GOTO 1100
1300 RETURN
1400 REM PROGRAM STARTS
1500 GRAPHICS 1:POKE 710,0:POKE 752,1:POKE 711,72:POKE 708,250:POKE 709,152:CLOSE #4:OPEN #4,4,0,"K:"
1510 DLIST=PEEK(560)+256*PEEK(561):FOR I=0 TO 3:POKE DLIST+I+21,2:NEXT I
1600 DIM OP1$(12),OP2$(12),B$(8),C$(1),M$(12):C$=CHR$(125):B$="OOOOOOOO":READ OP1$,OP2$
1700 DATA lsraslrolror,andoraeorbit
1800 DIM OP1(4),OP2(4),HEX$(3),CV$(16):CV$="0123456789ABCDEF":HEX$(1,1)="$"
1900 FOR I=1 TO 4:READ A,B:OP1(I)=A:OP2(I)=B:NEXT I
2000 DATA 74,37,10,5,42,69,106,36
2100 RESULT=205:FLAGS=206:FLAGOPT=207:OPCODE1=1555:OPCODE2=1574:BYTES=1612:HP=657
2200 FOR J=1536 TO 1611:READ A:POKE J,A:NEXT J
2300 DATA 104,201,2,240,22,165,207,240,7,165,206,72,40,76,17,6,24,104,104,234,133,205,8,104,133
2400 DATA 206,96,24,104,104,133,203,104,104,133,204,165,203,234,204,133,205,76,22,6,104,104,133,209,104
2500 DATA 133,208,104,104,160,7,74,72,144,7,169,49,145,208,76,71,6,169,79,145,208,104,136,16,237,96
2600 REM MAIN LOOP
2700 POSITION 7,0:? #6;"bitz":A=PEEK(FLAGS):FOR J=14 TO 1 STEP -1.5:SOUND O,A,10,J:NEXT J:SOUND 0,0,0,0
2800 POKE HP,11:? " bytes-> 1 or 2 ":GET #4,CHOICE:CHOICE=CHOICE-48:IF CHOICE<1 OR CHOICE>2 THEN ? C$;:GOTO 2800
2900 POKE BYTES,CHOICE:? #6;C$
2910 WHICHTYPE=CHOICE
3000 ON PEEK(BYTES) GOTO 3100,4300
3100 REM ONE BYTE
3200 ? C$:POSITION 4,2:? #6;"single byte":M$=OP1$:GOSUB 1000
3300 J=CHOICE-1:POSITION 8,10:? #6;OP1$(J*3+1,J*3+3);
3400 POKE OPCODE1,OP1(CHOICE):REM POKE SINGLE BYTE OPCODE FROM ARRAY
3500 ? C$:POKE HP,0:? " esc OLD carry return CLEAR carry";
3600 GET #4,J:IF J<>27 AND J<>155 THEN 3500
3700 IF J=27 THEN POKE FLAGOPT,1:NUM=PEEK(FLAGS):GOSUB 200:POSITION 5,3:? #6;"carry ";B$(8,8):GOTO 3900
3800 POKE FLAGOPT,0
3900 M$="target ":GOSUB 700
4000 ? C$:POSITION 0,6:? #6;NUM:NUM1=NUM:GOSUB 200
4100 POSITION 5,6:? #6;HEX$;:POSITION 11,6:? #6;B$;
4200 J=USR(1536,NUM1):GOTO 5400
4300 REM TWO BYTES
4400 ? C$:POSITION 4,2:? #6;"double byte":M$=OP2$:GOSUB 1000
4500 J=CHOICE-1:POSITION 8,8:? #6;OP2$(J*3+1,J*3+3):POKE FLAGOPT,0
4600 POKE OPCODE2,OP2(CHOICE):REM POKE OPCODE FROM ARRAY
4700 IF WHICHTYPE=1 THEN M$="target ":GOSUB 700
4710 IF WHICHTYPE=2 THEN M$="mask ":GOSUB 700
4800 POSITION 0,6:? #6;NUM:NUM1=NUM:GOSUB 200
4900 POSITION 5,6:? #6;HEX$;:POSITION 11,6:? #6;B$
5000 IF WHICHTYPE=1 THEN M$="mask ":GOSUB 700
5010 IF WHICHTYPE=2 THEN M$="target ":GOSUB 700
5100 POSITION 0,10:? #6;NUM:NUM2=NUM:GOSUB 200
5200 POSITION 5,10:? #6;HEX$;:POSITION 11,10:? #6;B$
5300 J=USR(1536,NUM1,NUM2)
5400 REM PRINT RESULTS
5500 NUM=PEEK(RESULT):POSITION 0,14:? #6;NUM:GOSUB 200
5600 POSITION 5,14:? #6;HEX$;:POSITION 11,14:? #6;B$;
5700 NUM=PEEK(FLAGS):GOSUB 200
6000 IF B$(1,1)="O" THEN POSITION 10,18:? #6;"negative flag clear"
6010 IF B$(1,1)="1" THEN POSITION 10,18:? #6;"negative flag set"
6020 IF B$(7,7)="O" THEN POSITION 10,20:? #6;"zero flag clear"
6030 IF B$(7,7)="1" THEN POSITION 10,20:? #6;"zero flag set"
6040 IF B$(8,8)="O" THEN POSITION 10,22:? #6;"carry flag clear"
6050 IF B$(8,8)="1" THEN POSITION 10,22:? #6;"carry flag set"
6100 GOTO 2600
