print utility (TINYLIST.BAS)
print utility by Jerry White
Description
print utility by Jerry White
From the Antic disk of February 1986 (Vol. 4 No. 10) — disk A.
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.0 KB
- Dialect
- Atari BASIC
- Lines
- 42
- Variables
L$,B$,H$,PAGE,TL,LL,IT,LP,PL,RLINE,DEVICE,BUTTON,F$,ME
BASIC listing (42 lines)
10 REM TINYLIST
20 REM BY JERRY WHITE
30 REM (c) 1985, ANTIC PUBLISHING
100 GOSUB 350
110 L$=B$:L$(LEN(L$)+1)=H$:L$(LEN(L$)+1)=" PAGE ":L$(LEN(L$)+1)=STR$(PAGE)
115 GOSUB 470:LPRINT :TL=0
120 TRAP 220:LL=0:L$=""
130 GET #1,IT:IF IT=155 THEN 170
140 LL=LL+1:IF IT>127 THEN IT=IT-128
150 IF IT<32 THEN IT=45
160 L$(LL,LL)=CHR$(IT):GOTO 130
170 LP=INT(LL/132)+1:IF LP=INT(LL/132) THEN LP=LP-1
180 PL=PL+LP:TL=TL+LP
190 GOSUB 470:IF TL<140 THEN 120
200 RLINE=200:TRAP 310:PRINT #3;CHR$(12)
210 PAGE=PAGE+1:GOTO 110
220 POKE 752,1
230 L$=STR$(PL):L$(LEN(L$)+1)=" LINES PRINTED":LPRINT :GOSUB 470
240 ? #3;CHR$(12):FOR DEVICE=1 TO 3:CLOSE #DEVICE:NEXT DEVICE:POKE 766,0
250 TRAP 40000:POP :? :? ,"PRESS OPTION TO RERUN"
260 ? :? ,"PRESS SELECT TO END":? :? ,"PRESS START FOR DOS"
270 BUTTON=PEEK(53279):IF BUTTON=6 THEN DOS
280 IF BUTTON=5 THEN GRAPHICS 0:? :? "BASIC":? "IS";:END
290 IF BUTTON=3 THEN RUN
300 GOTO 270
310 ? CHR$(253):? :? ,"YOUR PRINTER ISN'T READY"
320 ? :? ,"PRESS START WHEN READY":TRAP 40000
330 IF PEEK(53279)=6 THEN GOTO RLINE
340 GOTO 330
350 DIM B$(7),H$(80),F$(15),L$(FRE(0)-256)
360 PAGE=1:POKE 201,8:TRAP 310
370 RLINE=370:CLOSE #2:CLOSE #3:OPEN #2,12,0,"E:":OPEN #3,8,0,"P:"
380 DATA 27,65,5,15,27,83,0
390 FOR ME=1 TO 7:READ IT:SOUND 0,100-IT,10,8:B$(ME,ME)=CHR$(IT):NEXT ME
400 ? :? ," T I N Y L I S T ":SOUND 0,0,0,0
410 POKE 752,0:POKE 764,255:? :? "ENTER HEADING INFORMATION:":? :INPUT H$
420 ? :? "ENTER INPUT FILENAME";:INPUT F$:TRAP 460:IF LEN(F$)<2 THEN 440
430 IF F$(2,2)=":" OR F$(3,3)=":" THEN L$=F$:GOTO 450
440 L$="D:":L$(LEN(L$)+1)=F$
450 CLOSE #1:OPEN #1,4,0,L$:POKE 766,1:RETURN
460 ? CHR$(253):? L$;" NOT FOUND":GOTO 420
470 RLINE=470:TRAP 310:FOR DEVICE=2 TO 3:? #DEVICE;L$:NEXT DEVICE:RETURN
