game (WIREBALL.BAS)

game by Jean Goulet, 70

Description

game by Jean Goulet, 70

From the Antic disk of January 1986 (Vol. 4 No. 9).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 8.5 KB

Dialect
Atari BASIC
Lines
141
Variables
S, DIRX(, DIRY(, FTIME, SCREEN, POWER, PTIME, PULSON, C711, FIND, FINDCHAR$, SCSTART, SCORE, PX, PY, C, DEATH, INC, X, XLOOP, Y, YLOOP, XR, YR, TIME, DX, EX, DY, EY, CX, CY, XD, FX, YD, FY, DELTAX, DELTAY, XV, YV, FTOUCH, VP, P88, P89, GUY, T, CHSET, L, DL, NDL, NDLH, NDLL, D, MOVE$, MOVE, CH, COL, I, J, F
BASIC listing (141 lines)
10 REM WIREBALL
20 REM BY JEAN GOULET
30 REM (c) 1985, ANTIC PUBLISHING INC.
1020 GOSUB 2200
1030 GOSUB 2450
1070 S=STICK(0):IF DIRX(S)=0 AND DIRY(S)=0 THEN 1090
1080 GOSUB 1180
1090 GOSUB 1590
1100 FTIME=FTIME+1:IF FTIME>4-SCREEN THEN GOSUB 1750:FTIME=0
1110 IF POWER=0 THEN GOSUB 1470
1120 IF POWER=1 THEN PTIME=PTIME+1:SOUND 3,31-PTIME,10,10
1122 IF POWER=1 THEN IF PTIME>30 THEN POWER=0:PTIME=0:SETCOLOR 4,0,0:PULSON=0
1130 POKE 711,C711:C711=C711+16-256*(C711>240):FIND=USR(ADR(FINDCHAR$),SCSTART):IF FIND<>0 THEN 1070
1140 SCORE=SCORE+500:GOSUB 2450:GOTO 1070
1180 LOCATE PX+DIRX(S),PY+DIRY(S),C
1200 IF C=32 THEN 1270
1220 COLOR 32:PLOT PX,PY:PX=PX+DIRX(S):PY=PY+DIRY(S):COLOR ASC("◆"):PLOT PX,PY:GOSUB 2030:IF DEATH=0 THEN 1240
1230 GOTO 1930
1240 SOUND 1,200,10,15:SCORE=SCORE+INC:SOUND 1,0,0,0
1250 RETURN
1270 IF DIRY(S) THEN 1330
1280 FOR X=PX+DIRX(S) TO (S=7)*39+(S=11) STEP DIRX(S):LOCATE X,PY,C:IF C=32 THEN NEXT X:GOTO 1390
1290 POP :COLOR ASC("─"):PLOT PX,PY:DRAWTO X,PY:FOR XLOOP=PX TO X-DIRX(S) STEP DIRX(S):COLOR 32:PLOT XLOOP,PY
1300 SOUND 0,XLOOP,10,8:SCORE=SCORE+5
1310 COLOR ASC("◆"):PLOT XLOOP+DIRX(S),PY:NEXT XLOOP:SOUND 0,0,0,0:PX=X:GOSUB 2030:IF DEATH=0 THEN RETURN
1320 GOTO 1930
1330 FOR Y=PY+DIRY(S) TO (S=13)*22+(S=14) STEP DIRY(S):LOCATE PX,Y,C:IF C=32 THEN NEXT Y:GOTO 1390
1340 POP :COLOR ASC("|"):PLOT PX,PY:DRAWTO PX,Y:FOR YLOOP=PY TO Y-DIRY(S) STEP DIRY(S):COLOR 32:PLOT PX,YLOOP
1350 SOUND 0,YLOOP,10,8:SCORE=SCORE+5
1360 COLOR ASC("◆"):PLOT PX,YLOOP+DIRY(S):NEXT YLOOP:SOUND 0,0,0,0:PY=Y:GOSUB 2030:IF DEATH=0 THEN RETURN
1370 GOTO 1930
1390 COLOR 32:PLOT PX,PY:PX=PX+DIRX(S):PY=PY+DIRY(S)
1400 PX=PX*(PX>0 AND PX<39)+(PX<1)+38*(PX>38)
1410 PY=PY*(PY>0 AND PY<23)+(PY<1)+22*(PY>22)
1420 COLOR ASC("◆"):PLOT PX,PY
1430 RETURN
1470 IF PULSON=1 AND PX=XR AND PY=YR THEN POWER=1:SETCOLOR 4,4,0:RETURN
1480 IF TIME<19 THEN TIME=TIME+1:RETURN
1490 PULSON= NOT (PULSON):POKE 77,0
1500 IF PULSON=0 THEN LOCATE XR,YR,C:IF C=ASC("●") THEN COLOR ASC("●"):PLOT XR,YR:GOTO 1540
1510 IF PULSON=0 THEN 1540
1520 XR=INT(RND(0)*37)+1:YR=INT(RND(0)*21)+1:LOCATE XR,YR,C:IF C<>ASC("●") THEN PULSON=0:GOTO 1540
1530 COLOR ASC("●"):PLOT XR,YR
1540 TIME=0
1550 RETURN
1590 DX=DX*SGN(0.1-(EX+DX>38 OR EX+DX<1)):DY=DY*SGN(0.1-(EY+DY>22 OR EY+DY<1))
1600 LOCATE EX+DX,EY+DY,C:IF C=32 THEN COLOR 32:PLOT EX,EY:COLOR ASC("▌"):EX=EX+DX:EY=EY+DY:PLOT EX,EY:RETURN
1610 LOCATE EX+DX,EY,CX:LOCATE EX,EY+DY,CY
1620 IF CX<>32 THEN DX=-DX:GOTO 1660
1630 IF CY<>32 THEN DY=-DY:GOTO 1680
1640 IF RND(0)>0.5 THEN DY=-DY:GOTO 1700
1650 DX=-DX:GOTO 1700
1660 IF CY<>32 THEN DY=-DY:GOTO 1700
1670 COLOR 32:PLOT EX,EY:EY=EY+DY:COLOR ASC("▌"):PLOT EX,EY:GOTO 1700
1680 IF CX<>32 THEN DX=-DX:GOTO 1700
1690 COLOR 32:PLOT EX,EY:EX=EX+DX:COLOR ASC("▌"):PLOT EX,EY
1700 RETURN
1750 XD=SGN(PX-FX):YD=SGN(PY-FY):DELTAX=ABS(PX-FX):DELTAY=ABS(PY-FY)
1760 IF DELTAX>DELTAY THEN DELTAY=DELTAY/DELTAX:DELTAX=1:GOTO 1780
1770 DELTAX=DELTAX/DELTAY:DELTAY=1
1780 XV=DELTAX*XD:YV=DELTAY*YD:COLOR 32:PLOT FX,FY:FX=FX+XV:FY=FY+YV:LOCATE FX,FY,C
1790 COLOR ASC("╱"):PLOT FX,FY
1810 IF INT(FX+0.5)=INT(PX) AND INT(FY+0.5)=INT(PY) THEN FTOUCH=1:GOTO 1830
1820 GOTO 1870
1830 IF POWER=0 THEN 1930
1840 IF FTOUCH THEN COLOR ASC("◆"):PLOT PX,PY:FX=2:FY=2:POWER=0:SCORE=SCORE+100:PULSON=0
1850 FOR X=-50 TO 50 STEP 5:SOUND 0,ABS(X/(4*(X>0)+0.5*(X<=0))),8,15:GOSUB 1880:NEXT X:POKE 712,0:VP=0
1860 PTIME=0:SOUND 3,0,0,0:SOUND 0,0,0,0
1870 RETURN
1880 POKE 88,0:POKE 89,6:POSITION 15,0:? "SCORE:";SCORE:POKE 54277,7-VP:VP=VP+(VP<7):POKE 88,P88:POKE 89,P89
1890 RETURN
1930 GOSUB 2070
1940 FOR X=0 TO 240 STEP 20:SOUND 0,X,4,15:SOUND 1,240-X/4,10,6:GOSUB 1880:NEXT X:SOUND 0,0,0,0:SOUND 1,0,0,0
1950 VP=0:FTOUCH=0:GUY=GUY-1:IF GUY<=0 THEN 2110
1960 POKE 1536+GUY-1,0
1970 FOR X=GUY-1 TO PX:COLOR ASC("◆"):PLOT X,0:COLOR 32:PLOT X,0:NEXT X
1972 FOR Y=0 TO PY:LOCATE PX,Y,C:COLOR ASC("◆")
1980 PLOT PX,Y:COLOR C:PLOT PX,Y:NEXT Y:COLOR ASC("◆"):PLOT PX,PY
1990 POP :GOTO 1070
2030 DEATH=(C<>ASC("●") AND C<>ASC("●")):IF C=ASC("●") THEN POWER=1:SETCOLOR 4,4,0
2040 IF DEATH=1 AND POWER=1 THEN GOSUB 2070:COLOR ASC("◆"):PLOT PX,PY:DEATH=0:POWER=0:SCORE=SCORE+100:GOSUB 1850
2050 RETURN
2070 COLOR 32:PLOT EX,EY:PLOT FX,FY:FX=2:FY=2:EX=3:EY=4:RETURN
2110 POKE 88,0:POKE 89,6
2120 FOR Y=0 TO 7:FOR T=0 TO 9:NEXT T:POKE 54277,Y:NEXT Y
2130 POSITION 15,0:? "GAME OVER  ";
2140 FOR Y=-7 TO 7:FOR T=0 TO 9:NEXT T:POKE 54277,ABS(Y):NEXT Y
2150 POSITION 15,0:? "score:";SCORE;"  ";
2160 FOR Y=-7 TO 7:FOR T=0 TO 9:NEXT T:POKE 54277,ABS(Y):NEXT Y:GOTO 2130
2200 POKE 106,PEEK(106)-5:GRAPHICS 0:POKE 559,0:CHSET=(PEEK(106)+1)*256:SCSTART=PEEK(88)+256*PEEK(89):POKE 710,0
2210 C711=10:GUY=2:FOR L=0 TO 39:POKE 1536+L,0:NEXT L
2220 DL=PEEK(560)+256*PEEK(561):POKE DL+3,68:FOR X=6 TO 28:POKE DL+X,4:NEXT X:POKE 82,0:POKE 752,1
2230 POKE DL+12,2:POKE DL+10,6:POSITION 6,5:? "WIREBALL":POSITION 33,6:? "By Jean Goulet":RESTORE 2200
2240 NDL=DL-3:NDLH=INT(NDL/256):NDLL=NDL-256*NDLH:POKE 560,NDLL:POKE 561,NDLH
2250 FOR L=NDL TO NDL+5:READ D:POKE L,D:NEXT L:DATA 112,96,98,0,6,0
2260 POKE NDL+33,NDLL:POKE NDL+34,NDLH:POKE 559,34
2270 DIM MOVE$(32):MOVE$="hh┐Wh┐Vh┐Uh┐T"┤ ♥1T┌VHPyfUfWJPp◆":MOVE=USR(ADR(MOVE$),CHSET,57344)
2280 FOR C=1 TO 6:READ CH:FOR X=0 TO 7:READ D:POKE CHSET+CH*8+X,D:NEXT X:NEXT C
2290 DATA 70,20,105,125,105,85,105,190,130
2300 DATA 82,0,0,0,17,68,17,0,0
2310 DATA 84,0,60,255,215,223,255,255,60
2320 DATA 89,0,40,146,40,81,40,146,40
2330 DATA 96,0,65,60,105,125,105,60,65
2340 DATA 124,4,16,4,16,4,16,4,16
2350 DIM DIRX(15),DIRY(15),FINDCHAR$(80):PX=20:PY=12:INC=2:EX=3:EY=5:DX=1:DY=1:FX=2:FY=2
2360 FINDCHAR$="hh┐Lh┐KX%K┴i(┐K%Li♥┐L"♥h ♥H1KITp↓@&PuX%K┴i(┐K%Li♥┐L◆▎P◆)♥┐T┐U◆)T┐T┐U◆"
2370 FOR X=1 TO 15:READ D:DIRX(X)=D:NEXT X:DATA 0,0,0,0,0,0,1,0,0,0,-1,0,0,0,0
2380 FOR X=1 TO 15:READ D:DIRY(X)=D:NEXT X:DATA 0,0,0,0,0,0,0,0,0,0,0,0,1,-1,0
2390 ? "↰":POKE 756,CHSET/256:POKE DL+10,4:POKE DL+12,4
2400 P88=PEEK(88):P89=PEEK(89):POKE 88,0:POKE 89,6:POSITION 0,0:? "◆":POKE 88,P88:POKE 89,P89
2410 FOR C=708 TO 712:READ COL:POKE C,COL:NEXT C:RETURN :DATA 102,172,230,74,0
2450 FOR I=1 TO 8:FOR J=-15 TO 15 STEP 9-I:F=15-ABS(J):SOUND 2,202,10,F:SOUND 1,152,10,F:SOUND 3,241+J,10,9
2460 SETCOLOR 4,0,F:NEXT J:GOSUB 1880:NEXT I:VP=0
2470 GOSUB 2070:GUY=GUY+1:POKE 1536+GUY-2,ASC("◆"):COLOR 32:PLOT PX,PY:PX=20:PY=12
2480 COLOR 20:SCREEN=SCREEN+1:IF SCREEN>6 THEN SCREEN=6:REM IF YOU MAKE EXTRA SCREENS, CHANGE THE 6 TO NEW NO.
2490 ON SCREEN GOSUB 2520,2550,2590,2630,2680,2710
2500 COLOR ASC("◆"):PLOT PX,PY:RETURN
2510 REM SCREEN 1
2520 FOR Y=1 TO 22:PLOT 1,Y:DRAWTO 38,Y:NEXT Y:COLOR 32:FOR Y=2 TO 9:PLOT 2,Y:DRAWTO 37,Y:NEXT Y
2530 FOR X=2 TO 36 STEP 2:PLOT X,15:DRAWTO X,21:NEXT X:RETURN
2540 REM SCREEN 2
2550 PLOT 1,1:DRAWTO 38,1:DRAWTO 38,22:DRAWTO 1,22:DRAWTO 1,1
2560 FOR X=5 TO 30 STEP 5:PLOT X,12:DRAWTO X+4,3:DRAWTO X+4,21:DRAWTO X,12:NEXT X
2570 RETURN
2580 REM SCREEN 3
2590 FOR X=19 TO 20:PLOT X,3:DRAWTO X,20:NEXT X:FOR X=16 TO 17:PLOT X,3:DRAWTO X,12:DRAWTO X-8,20
2600 PLOT 39-X,3:DRAWTO 39-X,12:DRAWTO 39-(X-8),20:NEXT X:PLOT 1,1:DRAWTO 38,1:DRAWTO 38,22:DRAWTO 1,22
2610 DRAWTO 1,1:RETURN
2620 REM SCREEN 4
2630 PLOT 6,11:DRAWTO 7,10:DRAWTO 4,7:DRAWTO 7,7:DRAWTO 10,8:DRAWTO 15,10:DRAWTO 30,10:DRAWTO 36,11
2640 PLOT 6,12:DRAWTO 7,13:DRAWTO 4,16:DRAWTO 7,16:DRAWTO 10,15:DRAWTO 15,13:DRAWTO 30,13:DRAWTO 36,12
2650 PLOT 1,1:DRAWTO 38,1:DRAWTO 38,22:DRAWTO 1,22:DRAWTO 1,1:PLOT 14,4:DRAWTO 29,19:PLOT 14,19:DRAWTO 29,4
2660 RETURN
2670 REM SCREEN 5
2680 FOR Y=1 TO 11 STEP 2:PLOT Y,Y:DRAWTO 39-Y,Y:DRAWTO 39-Y,23-Y:DRAWTO Y,23-Y:DRAWTO Y,Y
2690 NEXT Y:RETURN
2700 REM SCREEN 6
2710 PLOT 1,1:DRAWTO 38,1:DRAWTO 38,22:DRAWTO 1,22:DRAWTO 1,1
2720 PLOT 19,11:DRAWTO 25,11:DRAWTO 27,9:DRAWTO 19,9:DRAWTO 19,13:DRAWTO 27,13:DRAWTO 25,11
2730 PLOT 19,8:DRAWTO 19,3:DRAWTO 12,6:DRAWTO 8,11:DRAWTO 12,15:DRAWTO 19,19:DRAWTO 19,15
2740 DRAWTO 14,11:DRAWTO 19,7:PLOT 28,3:DRAWTO 9,20:PLOT 28,20:DRAWTO 9,3:RETURN