Sysop Santa, telecom utility (SYSANTA.BAS)

Sysop Santa, telecom utility by Scott Anthony and Bill Marquardt, 72

Description

Sysop Santa, telecom utility by Scott Anthony and Bill Marquardt, 72

From the Antic disk of January 1986 (Vol. 4 No. 9).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 8.7 KB

Dialect
Atari BASIC
Lines
174
Variables
F$, CD$, CL$, S$, CODE$, DES$, P$, SO$, AGE, A, B, C, D, CC, K, V, L, S, N, H
BASIC listing (174 lines)
10 REM SYSOP SANTA
20 REM BY SCOTT ANTHONY AND BILL MARQUARDT
30 REM (c) 1985, ANTIC PUBLISHING
50 DIM F$(15):F$="D1:GIFTS.DAT"
60 DIM CD$(4),CL$(1),S$(1)
70 DIM CODE$(4),DES$(80),P$(15),SO$(40)
90 CL$=CHR$(125):S$=CHR$(160)
95 POKE 712,148:POKE 710,148
100 PRINT CL$:RESTORE :POKE 82,0:POKE 752,1:GOSUB 10000:TRAP 9400
110 ? CHR$(125):POSITION 4,7:? "What is the age"
111 POSITION 7,9:? "of the person"
112 POSITION 10,11:? "you are giving to "
113 POSITION 13,13:? "(infants are age 0) ";:INPUT AGE
120 IF AGE<0 OR AGE>100 THEN 110
130 A=1+(AGE>21)+(AGE>15)+(AGE>12)+(AGE>9)+(AGE>5)+(AGE>2):B=0:C=B:D=B
135 ? CL$:GOSUB 9300:POKE 82,7
140 ON A GOSUB 1000,2000,3000,4000,5000,6000,7000
150 POKE 82,0
970 CD$(1,1)=STR$(A):CD$(2,2)=STR$(B):CD$(3,3)=STR$(C):CD$(4,4)=STR$(D)
980 ? CL$:GOTO 9000
997 REM AGE CATEGORY MENUS
1000 POSITION 11,3:? "Infants to 2 years":?
1020 ? "1 - Clothes":? "2 - Toys":? "3 - Helpful things"
1021 ? "    for Mom & Dad":CC=3:GOSUB 12120
1050 B=K:RETURN
2000 POSITION 9,3:? "Pre-Schoolers (3-5 years)":?
2020 ? "1 - Books":? "2 - Toys":? "3 - Software"
2021 ? "4 - Clothes":? "5 - Dolls & Stuffed Animals":? "6 - Games":CC=6:GOSUB 12120
2050 B=K:RETURN
3000 POSITION 15,3:? "Ages 6-9":?
3020 ? "1 - Books":? "2 - Toys":? "3 - Software"
3021 ? "4 - Dolls":? "5 - Games":? "6 - Sports Equipment":CC=6:GOSUB 12120
3050 B=K:RETURN
4000 POSITION 14,3:? "Ages 10-12":?
4020 ? "1 - Books":? "2 - Games":? "3 - Software"
4021 ? "4 - Sports Equipment":? "5 - Hobbies":? "6 - Records/AV/Cassetes":CC=6:GOSUB 12120
4050 B=K:RETURN
5000 POSITION 7,3:? "Junior High (Ages 13-15)":?
5020 ? "1 - Books":? "2 - Software":? "3 - Sports Equipment"
5021 ? "4 - Hobbies":? "5 - Entertainment":? "6 - Records/AV/Cassettes"
5022 ? "7 - Clothes for girls":? "8 - Clothes for boys":CC=8:GOSUB 12120
5050 B=K:RETURN
6000 POSITION 2,3:? "High School & College (Ages 16-21)":?
6020 ? "1 - Books":? "2 - Software":? "3 - Sports Equipment"
6021 ? "4 - Hobbies":? "5 - College Related Materials":? "6 - Records/AV/Cassetes"
6030 ? "7 - Clothes for Females":? "8 - Clothes for Males":CC=8:GOSUB 12120
6050 B=K:RETURN
7000 POSITION 16,3:? "Adults":?
7020 ? "1 - The Arts":? "2 - Sports & Fitness":? "3 - Entertainment"
7021 ? "4 - Computing":? "5 - Repair & Home Crafts":? "6 - Collecting"
7022 ? "7 - Fashion & Style":CC=7:GOSUB 12120
7025 POKE 82,0:? CL$:GOSUB 9300:POKE 82,7
7030 B=K:ON B GOTO 7100,7200,7300,7400,7500,7600,7700
7100 POSITION 13,3:? "The Arts":?
7120 ? "1 - Music Performance":? "2 - Music Listening":? "3 - Arts & Crafts"
7121 ? "4 - Art Appreciation":CC=4:GOSUB 12120
7130 POKE 82,0:? CL$:GOSUB 9300:POKE 82,7:C=K:ON C GOTO 7140,7150,7160,7170
7140 POSITION 9,3:? "Music - Performance":?
7142 ? "1 - Stringed Instruments":? "2 - Piano":? "3 - Wind Instruments"
7143 ? "4 - Percussion":? "5 - Electronic":CC=5:GOSUB 12120:GOTO 7900
7150 POSITION 10,3:? "Music - Listening":?
7152 ? "1 - Classical":? "2 - Pop":? "3 - Jazz":? "4 - Rock"
7153 ? "5 - Country Western":CC=5:GOSUB 12120:GOTO 7900
7160 POSITION 12,3:? "Arts & Crafts":?
7162 ? "1 - Painting":? "2 - Sculpting":? "3 - Wood Carving"
7163 ? "4 - Photography":? "5 - Ceramics":? "6 - Drawing"
7164 ? "7 - Needlecrafts":? "8 - Miniatures":CC=8:GOSUB 12120:GOTO 7900
7170 RETURN
7200 POSITION 11,3:? "Sports & Fitness":?
7220 ? "1 - Fitness":? "2 - Team & Competitive Sports":? "3 - Outdoor Sports"
7221 ? "4 - Spectator Sports":CC=4:GOSUB 12120
7230 POKE 82,0:? CL$:GOSUB 9300:POKE 82,7:C=K:ON C GOTO 7240,7250,7260,7270
7240 POSITION 15,3:? "Fitness":?
7242 ? "1 - Weight Lifting":? "2 - Aerobics":? "3 - Nutrition"
7243 ? "4 - Jogging":? "5 - Walking":? "6 - Swimming":CC=6:GOSUB 12120:GOTO 7900
7250 POSITION 7,3:? "Team & Competitive Sports":?
7252 ? "1 - Volleyball":? "2 - Tennis":? "3 - Squash/Racquetball"
7253 ? "4 - Golf":? "5 - Bowling":? "6 - Baseball"
7254 ? "7 - Football":? "8 - Basketball":? "9 - Hockey":CC=9:GOSUB 12120:GOTO 7900
7260 POSITION 12,3:? "Outdoor Sports":?
7262 ? "1 - Hunting":? "2 - Fishing":? "3 - Hiking"
7263 ? "4 - Bicycling":? "5 - Boating":? "6 - Skiing":CC=6:GOSUB 12120:GOTO 7900
7270 RETURN
7300 POSITION 13,3:? "Entertainment":?
7320 ? "1 - Eating & Drinking":? "2 - Puzzles & Games":? "3 - Movies/Theatre"
7321 ? "4 - Reading":? "5 - Travel":CC=5:GOSUB 12120
7330 POKE 82,0:? CL$:GOSUB 9300:POKE 82,7:C=K:ON C GOTO 7340,7350,7360,7370,7380
7340 POSITION 11,3:? "Eating & Drinking":?
7342 ? "1 - Dining Out":? "2 - Dining In":? "3 - Bar Utensils"
7343 ? "4 - Beverages":? "5 - Favorite Foods":? "6 - Parties"
7344 ? "7 - Barbecues & Picnics":CC=7:GOSUB 12120:GOTO 7900
7350 POSITION 12,3:? "Puzzles & Games":?
7352 ? "1 - Board Games":? "2 - Card Games":? "3 - Pencil Games"
7353 ? "4 - Jigsaw Puzzles":? "5 - Puzzle Toys":? "6 - Magic Tricks"
7354 ? "7 - Fantasy/Role Playing:CC=7:GOSUB 12120:GOTO 7900"
7360 RETURN
7370 POSITION 15,3:? "Reading":?
7372 ? "1 - Fiction":? "2 - Non-fiction":? "3 - Poetry"
7373 ? "4 - Politics & History":? "5 - Mysteries":? "6 - Periodicals"
7374 ? "7 - Science Fiction":? "8 - Biography":? "9 - Classics":CC=9:GOSUB 12120:GOTO 7900
7380 RETURN
7400 POSITION 11,3:? "Computing":?
7420 ? "1 - Hardware":? "2 - Games":? "3 - Productivity"
7421 ? "4 - Languages":? "5 - Other Software":? "6 - Incidentals":CC=6:GOSUB 12120
7430 C=K:GOTO 7900
7500 POSITION 9,3:? "Repair & Home Crafts":?
7520 ? "1 - Cooking":? "2 - Maintenance & Repair":? "3 - Gardening"
7521 ? "4 - Decorating":CC=4:GOSUB 12120
7530 POKE 82,0:? CL$:GOSUB 9300:POKE 82,7:C=K:ON C GOTO 7540,7550,7560,7570
7540 POSITION 15,3:? "Cooking":?
7542 ? "1 - Cookbooks":? "2 - Utensils":? "3 - Table Items"
7543 ? "4 - Pots & Pans":? "5 - Appliances":? "6 - Condiments"
7544 ? "7 - Staples":CC=7:GOSUB 12120:GOTO 7900
7550 POSITION 9,3:? "Repair & Home Crafts":?
7552 ? "1 - Carpentry":? "2 - Plumbing":? "3 - Auto Mechanics"
7553 ? "4 - Electrical":? "5 - Painting":? "6 - Cleaning ":CC=6:GOSUB 12120:GOTO 7900
7560 POSITION 14,3:? "Gardening":?
7562 ? "1 - Clothing":? "2 - Tools":? "3 - Plants & Seeds"
7563 ? "4 - Soil Conditioners":? "5 - Decorative Items":? "6 - Books":CC=6:GOSUB 12120:GOTO 7900
7570 RETURN
7600 POSITION 14,3:? "Collecting":?
7620 ? "1 - Coins":? "2 - Stamps":? "3 - Antiques"
7621 ? "4 - Baseball Cards":CC=4:GOSUB 12120
7630 C=K:GOTO 7900
7700 POSITION 11,3:? "Fashion & Style":?
7720 ? "1 - Sewing":? "2 - Cosmetics":? "3 - Fragrances for":? "    Men & Women"
7721 ? "4 - Men's casual Clothes":? "5 - Women's Casual Clothes":? "6 - Women's Accessories"
7730 ? "7 - Men's Accessories":? "8 - Magazines & Books":CC=8:GOSUB 12120:C=K
7900 D=K:RETURN
9000 GOSUB 9500:V=4:? CL$:? "List of Suggestions:"
9010 INPUT #1;CODE$
9011 IF CODE$=CD$ THEN GOSUB 13000:GOTO 9030
9020 INPUT #1;DES$,P$,SO$
9030 IF V=18 THEN GOSUB 13100
9040 POKE 764,255:GOTO 9010
9300 GOSUB 12020:GOSUB 12030:GOSUB 12020:RETURN
9400 CLOSE #1:TRAP 40000
9410 POSITION 5,23:? "That's all! Press any key . . .";:POKE 764,255
9411 IF PEEK(764)=255 THEN 9411
9412 GOTO 100
9500 OPEN #1,4,0,F$
9530 RETURN
10000 FOR L=1 TO 17:READ S,N:POSITION S,L:FOR H=1 TO N:? "*";:NEXT H:NEXT L
10001 FOR L=18 TO 19:READ S,N:POSITION S,L:FOR H=1 TO N:? S$;:NEXT H:NEXT L
10010 DATA 10,1,9,3,8,5,6,9,7,7,6,9,4,13,6,9,5,11,3,15,5,12,4,14,2,18,4,14,3,16,2,18,1,20,9,3,8,5
10020 FOR N=1 TO 22:READ V,H:POSITION H,V:? "●":NEXT N
10030 DATA 1,10,3,8,4,12,5,8,6,11,7,6,7,15,8,12,9,8,10,5,10,14,11,10,12,4
10031 DATA 12,16,13,9,14,5,14,14,15,10,16,3,16,16,17,6,17,19
10040 POSITION 0,20:GOSUB 12020
10050 POSITION 23,4:? "GIFT SELECTION"
10051 POSITION 27,5:? "HELPER"
10052 ? :POSITION 23,8:? "for readers of"
10053 ? :POSITION 23,10:? "ANTIC Magazine"
10060 POSITION 21,2:FOR N=1 TO 18:? S$;:NEXT N
10061 FOR V=3 TO 12:POSITION 21,V:? S$;:POSITION 38,V:? S$;:NEXT V
10062 POSITION 21,13:FOR N=1 TO 18:? S$;:NEXT N
10070 GOSUB 12140:RETURN
12020 FOR N=0 TO 39:? S$;:NEXT N:RETURN
12030 FOR L=1 TO 19:POSITION 0,L:? S$;:POSITION 39,L:? S$;:NEXT L:RETURN
12120 POKE 764,255:POSITION 7,22:? "Press number of choice ";:OPEN #2,4,0,"K:":GET #2,K
12125 K=K-48:CLOSE #2:IF K<1 OR K>CC THEN 12120
12127 RETURN
12140 POKE 764,255:POSITION 4,23:? "Press any key to continue . . .";
12141 IF PEEK(764)=255 THEN 12141
12145 POKE 764,255:RETURN
13000 INPUT #1;DES$,P$,SO$:POSITION 0,V
13010 ? DES$:POSITION 21,V:? P$
13020 POSITION (39-LEN(SO$)),V:? SO$:V=V+1
13030 RETURN
13100 POSITION 5,23:? "Press any Key to continue . . .";
13110 V=4:POKE 764,255
13120 IF PEEK(764)=255 THEN 13120
13130 ? CL$:? "List continued . . ."
13140 RETURN