Appointment Calendar (CALENDAR.BAS)

Appointment Calendar by Alfred Filskov, 74

Description

Appointment Calendar by Alfred Filskov, 74

From the Antic disk of January 1986 (Vol. 4 No. 9).

The magazine article

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 8.9 KB

Dialect
Atari BASIC
Lines
222
Variables
F2, F12, F1, F0, F8, CL$, CSR, SV, LN, F16, LM, A$, B$, C$, A, F6, D$, F11, F20, F15, F7, F17, F22, F4, F19, F3, U$, F13, F10, F14, M$, Y$, F9, B, C, DATE, M, DAYS, Y, FIR, FD$, D, F5, E, J$, F126, F125, BK$, MSG, CSR$, DAY, F21, F18, D(, E$
BASIC listing (222 lines)
1 REM APPOINTMENT CALENDAR
2 REM BY ALFRED FILSKOV
3 REM (c) 1985, ANTIC PUBLISHING INC.
10 DATA     APPOINTMENT CALENDAR
20 DATA     BY ALFRED H. FILSKOV
30 GOTO 1490
40 REM DISPLAY CALENDAR
50 TRAP 2180:SETCOLOR F2,F12,F2:SETCOLOR F1,F0,F8:? CL$:POKE CSR,F1:SV=F0
60 LN=F16:GOSUB 2130:POKE LM,23:POSITION 23,F0:? A$:? B$:? C$:FOR A=F1 TO F6:? B$:NEXT A:? D$
70 LN=F11:GOSUB 2130:POKE LM,28:POSITION 28,F11:? A$:? B$:? C$:FOR A=F1 TO F6:? B$:NEXT A:? D$
80 LN=F20:GOSUB 2130:POKE LM,F8:POSITION F8,F15:? A$:FOR A=F1 TO F7:? B$:NEXT A:? D$;
90 LN=F6:GOSUB 2130:POKE LM,F1:POSITION F1,F17:? A$:? B$:? C$:? B$:? B$:? D$
100 LN=F22:GOSUB 2130:POSITION F1,F0:? A$:? B$
110 FOR A=F4 TO F19 STEP F3:C$(A,A)=CHR$(23):NEXT A:? C$
120 B$(F4)=B$:B$(F22)=U$:FOR A=F3 TO F13 STEP F2:POSITION F1,A:? B$:NEXT A
130 FOR A=F4 TO F19 STEP F3:C$(A,A)=CHR$(F19):NEXT A:FOR A=F4 TO F12 STEP F2:POSITION F1,A:? C$:NEXT A
140 FOR A=F10 TO F19 STEP F3:D$(A,A)=CHR$(24):NEXT A:POSITION F1,F14:? D$
150 D$(F4,F4)=CHR$(24):D$(F7)=CHR$(F3):POSITION F1,F14:? C$(F1,F7):? B$(F1,F7):? D$
160 A$=M$:A$(LEN(A$)+F1)="  ":A$(LEN(A$)+F1)=Y$:POSITION INT(F12-LEN(A$)/F2),F1:? A$
170 RESTORE 180:FOR A=F2 TO F20 STEP F3:READ A$:POSITION A,F3:? A$(F1,F2):NEXT A
180 DATA MONDAY,TUESDAY,WEDNESDAY,THURSDAY,FRIDAY,SATURDAY,SUNDAY
190 FOR A=F1 TO F9:READ B,C,A$:POSITION B,C:? A$:NEXT A
200 DATA 29,1,MENU,24,3,1. View date,24,4,2. Edit date,24,5,3. Print date,24,6,4. Print month
210 DATA 24,7,5. Main menu,30,12,MESSAGE,2,18,DATE,11,15,>APPOINTMENTS<
220 REM DISPLAY DATES
230 DATE=F0:RESTORE 240:FOR A=F1 TO M:READ DAYS:NEXT A:IF DAYS=28 AND Y/F4=INT(Y/F4) THEN DAYS=29
240 DATA 31,28,31,30,31,30,31,31,30,31,30,31
250 A=(Y-1985)*F12+M:FIR=VAL(FD$(A,A)):C=FIR*F3-F1:D=F5:E=F1
260 FOR A=F1 TO DAYS
270 IF E<F10 THEN A$=" ":A$(F2)=STR$(E):GOTO 290
280 A$=STR$(E)
290 IF J$(E*F126-F125,E*F126)<>BK$ THEN FOR B=F1 TO F2:A$(B,B)=CHR$(ASC(A$(B,B))+128):NEXT B
300 POSITION C,D:? A$
310 C=C+F3:IF C>F20 THEN C=F2:D=D+F2
320 E=E+F1:NEXT A
330 REM GET MENU OPTION
340 MSG=F1:GOSUB 1280
350 GET #F1,A:D=A-48:IF D<F1 OR D>F5+SV THEN 350
360 ON D GOTO 380,380,710,860,1120,1190
370 REM VIEW DAY
380 MSG=F1+D:GOSUB 1280:POSITION 36,F17:POKE CSR,F0:? CSR$;
390 GET #F1,A:IF (A>57 OR A<48) AND A<>32 THEN 340
400 ? CHR$(A);:GET #F1,B:? CHR$(B)
410 IF (B>57 OR B<48) AND B<>32 AND B<>155 THEN 340
420 A=A-48:B=B-47:IF A<F0 OR A>F9 THEN A=F0
430 IF B<F0 OR B>F10 THEN B=F0
440 IF B THEN DATE=A*F10+B-F1:GOTO 460
450 DATE=A
460 IF DATE<F1 OR DATE>DAYS THEN 340
470 IF D=F2 THEN MSG=F4:GOSUB 1280
480 DAY=FIR+DATE-F1
490 IF DAY>F7 THEN DAY=DAY-F7:GOTO 490
500 RESTORE 180:FOR B=F1 TO DAY:READ A$:NEXT B:POSITION F3,20:? A$(F1,F2)
510 POSITION F4-LEN(STR$(DATE)),F21:? " ";DATE
520 FOR A=F0 TO F6:B=DATE*F126-F125+A*F18:POSITION F9,F16+A:? J$(B,B+F17):NEXT A:IF D=F1 THEN 340
530 REM EDIT APPOINTMENTS
540 A=F9:B=F16
550 POKE CSR,F0:POSITION A,B:? CSR$;
560 GET #F1,C
570 IF C=27 THEN 680
580 IF C=28 AND B>F16 THEN B=B-F1:GOTO 550
590 IF C=29 AND B<F22 THEN B=B+F1:GOTO 550
600 IF (C=30 OR C=126) AND A>F9 THEN A=A-F1:GOTO 550
610 IF C=31 AND A<26 THEN A=A+F1:GOTO 550
620 IF C=155 AND B<F22 THEN B=B+F1:A=F9:GOTO 550
630 IF C<32 OR (C>124 AND C<160) OR C>252 THEN 560
640 SV=F1:D=DATE*F126-F125+(B-F16)*F18+A-F9
650 J$(D,D)=CHR$(C):? CHR$(C);
660 IF A=26 THEN ? CHR$(30);:GOTO 550
670 A=A+F1:GOTO 550
680 IF SV THEN POSITION 24,F8:? "6. Save month"
690 MSG=F5:GOSUB 1280:GOTO 250
700 REM PRINT DATE
710 IF  NOT DATE THEN 350
720 TRAP 840:MSG=F6:GOSUB 1280
730 A$="-":A$(F22)=" ":A$(F2)=A$:A$(F1,F1)="+":A$(F22)="+"
740 RESTORE 180:FOR A=F1 TO DAY:READ B$:NEXT A:C$=U$:C$(F2)=BK$
750 C$(F12-INT(LEN(B$)/F2+0.5))=B$:C$(LEN(C$)+F1)=BK$:C$(F22)=U$
760 B$=M$:B$(LEN(B$)+F1)=" ":B$(LEN(B$)+F1)=STR$(DATE)
770 B$(LEN(B$)+F1)=", ":B$(LEN(B$)+F1)=STR$(Y):D$=BK$:D$(F12-INT(LEN(B$)/F2+0.5))=B$:D$(F1,F1)=U$
780 D$(LEN(D$)+F1)=BK$:D$(F22)=U$
790 LPRINT A$:LPRINT "|  APPOINTMENTS FOR  |":LPRINT C$:LPRINT D$:LPRINT A$
800 FOR A=F0 TO F6:B=DATE*F126-F125+A*F18:LPRINT "| ";J$(B,B+17);" |":NEXT A
810 B$=U$:B$(F2)=BK$:B$(F22)=U$:C$="_":C$(F20)=" ":C$(F2)=C$:C$(F1,F2)="| ":C$(F21)=" |"
820 FOR A=F1 TO F4:LPRINT B$:LPRINT C$:NEXT A:LPRINT A$
830 LPRINT :LPRINT :LPRINT :GOTO 340
840 MSG=F8:GOSUB 1280:FOR A=F1 TO 400:NEXT A:GOTO 340
850 REM PRINT MONTH
860 MSG=F7:GOSUB 1280:TRAP 1090
870 OPEN #F2,F4,F0,"P":? #F2:? #F2:? #F2;CHR$(27);"A";CHR$(F10):E=F0
880 D$=BK$:D$(F4,F7)=Y$:D$(33)=Y$
890 B=LEN(M$):A=F21-INT(B/F2+0.5):D$(A,A+B-F1)=M$
900 ? #F2;CHR$(F14);D$:? #F2
910 GOSUB 1080:FOR A=F12 TO 67 STEP F11:D$(A,A)="+":NEXT A:D$(78)="+":? #F2;D$
920 D$=BK$:FOR A=F1 TO 67 STEP F11:D$(A,A)=U$:NEXT A:D$(78)=U$
930 RESTORE 180:FOR A=F1 TO F7:READ A$:C=LEN(A$):B=A*11-INT(C/F2+0.5)-F4:D$(B,B+C-F1)=A$:NEXT A:? #F2;D$
940 GOSUB 1080:FOR A=F7 TO 73 STEP F11:D$(A,A)="+":D$(A+F5,A+F5)="+":NEXT A:D$(78)="+":? #F2;D$
950 D$=U$:FOR A=F2 TO 104 STEP F17:D$(A)="     ":D$(A+F5)=CHR$(27):D$(A+F6)="-1|    |":D$(A+F14)=CHR$(27)
960 D$(A+F15)="-0":NEXT A
970 FOR A=F1 TO F7:IF (E=F0 AND A<>FIR) OR E>=DAYS THEN D(A)=F0:GOTO 1000
980 E=E+F1:D(A)=E:C=A*F17-F5:A$=STR$(E):IF E<F10 THEN A$=" ":A$(F2)=STR$(E)
990 D$(C,C+F1)=A$
1000 NEXT A:? #F2;D$;CHR$(F15);CHR$(27);"Q";CHR$(137)
1010 FOR A=F1 TO F7:D$=BK$:D$(100)=BK$:FOR C=F1 TO 134 STEP F19:D$(C,C)=U$:NEXT C
1020 FOR C=F1 TO F7:IF  NOT D(C) THEN 1040
1030 D$(C*F19-F17,C*F19)=J$(D(C)*F126-F125+A*F18-F18)
1040 NEXT C:? #F2;D$:NEXT A
1050 ? #F2;CHR$(F18);CHR$(27);"QP";:IF D(F7) AND D(F7)<DAYS THEN 940
1060 GOSUB 1080:FOR A=F12 TO 67 STEP F11:D$(A,A)="+":NEXT A:D$(78)="+"
1070 ? #F2;D$;CHR$(27);"A";CHR$(F12);CHR$(F12):CLOSE #F2:GOTO 340
1080 D$="-":D$(80)=" ":D$(F2)=D$:D$(F1,F1)="+":RETURN
1090 CLOSE #F2:MSG=F8:GOSUB 1280
1100 FOR A=F1 TO 300:NEXT A:GOTO 340
1110 REM EXIT
1120 IF  NOT SV THEN 1680
1130 MSG=F12:GOSUB 1280
1140 GET #F1,A:A$=CHR$(A)
1150 IF A$="Y" OR A$="y" THEN 1680
1160 IF A$="N" OR A$="n" THEN 340
1170 GOTO 1140
1180 REM SAVE MONTH
1190 TRAP 1240:MSG=F9:GOSUB 1280
1200 B$="D:":B$(F3)=M$:B$(F6)=Y$:B$(F10)=".AC"
1210 OPEN #F2,F8,F0,B$
1220 FOR A=F1 TO 31:B=A*F126-F125:? #F2;J$(B,B+F125):NEXT A:CLOSE #F2
1230 POSITION 24,F8:? BK$(F1,F13):SV=F0:GOTO 340
1240 CLOSE #F2:IF PEEK(195)=162 THEN MSG=F11:GOTO 1260
1250 MSG=F10
1260 GOSUB 1280:FOR A=F1 TO 400:NEXT A:GOTO 340
1270 REM MESSAGE
1280 FOR A=F14 TO F19:POSITION 29,A:? BK$(F1,F9):NEXT A
1290 A=F1:B=F14:RESTORE 1360:POKE CSR,F1
1300 IF A<>MSG THEN 1340
1310 READ A$:IF A$="X" THEN RETURN
1320 POSITION 29,B:? A$
1330 B=B+F1:GOTO 1310
1340 READ A$:IF A$<>"X" THEN 1340
1350 A=A+F1:GOTO 1300
1360 DATA Choose a,menu,option.,X
1370 DATA What date,do you,want to,view? >__,X
1380 DATA What date,do you,want to,edit? >__,X
1390 DATA Edit the,appoint-,ments for,the date,and press,ESC.,X
1400 DATA Finished,editing.,X
1410 DATA Printing,current,date...,X
1420 DATA Printing,month...,X
1430 DATA Error in,printing!,X
1440 DATA Saving,month...,X
1450 DATA Disk not,ready,error!,X
1460 DATA Disk full,error!,X
1470 DATA Exit,without,saving,month?,(Y/N) >_,X
1480 REM START
1490 RESTORE 1510
1500 READ F0,F1,F2,F3,F4,F5,F6,F7,F8,F9,F10,F11,F12,F13,F14,F15,F16,F17,F18,F19,F20,F21,F22,LM,F125,F126,CSR
1510 DATA 0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,82,125,126,752
1520 GRAPHICS F0:POKE 83,39:SETCOLOR F2,F5,F2:POKE CSR,F1:?
1530 DIM J$(3906),BK$(F126),FD$(180),M$(F9),Y$(F4),CSR$(F2),CL$(F1),U$(F1),D(F7)
1540 DIM A$(38),B$(38),C$(38),D$(134),E$(F11)
1550 BK$=" ":BK$(F126)=" ":BK$(F2)=BK$:CSR$=CHR$(30):CSR$(F2)=CHR$(31):CL$=CHR$(125):U$="|"
1560 OPEN #F1,F4,F0,"K"
1570 REM READ FIRST DAY OF EACH MONTH
1580 RESTORE 1590:FD$="":FOR Y=85 TO 99:READ A$:FD$(LEN(FD$)+F1)=A$:NEXT Y
1590 DATA 255136147257,366247251361
1600 DATA 477351362472,512573514624
1610 DATA 733614625735,144725736146
1620 DATA 255136147257,367351362472
1630 DATA 511462473513,622573514624
1640 DATA 733614625735,145136147257
1650 DATA 366247251361,477351362472
1660 DATA 511462473513
1670 REM MAIN MENU
1680 TRAP 2180:POKE LM,F6:POKE CSR,F1:? CL$:SETCOLOR F2,F5,F2:SETCOLOR F1,F0,F8
1690 RESTORE 10:READ A$:? A$:READ A$:? A$
1700 LN=26:GOSUB 2130:POKE LM,F7
1710 POSITION F7,F4:? A$:? B$:? C$:FOR A=F1 TO F9:? B$:NEXT A:? C$:? B$:? D$:RESTORE 1730
1720 FOR A=F1 TO F4:READ A$:POSITION F10,A*F2+F6:? A;". ";A$:NEXT A
1730 DATA Load/Create a month,Delete a month,Disk directory,End program
1740 POSITION F15,F5:? "MAIN MENU":POSITION F10,F17:? "Choose an option =>";:POKE CSR,F0:? CSR$;
1750 GET #F1,A:A=A-48:IF A<F1 OR A>F4 THEN 1750
1760 ? A:ON A GOTO 1780,1850,2040,2110
1770 REM LOAD/CREATE A MONTH
1780 E$="load/create":GOSUB 1880
1790 TRAP 1810:OPEN #F2,F4,F0,B$:? "Loading month...";
1800 FOR A=F1 TO 31:INPUT #F2,D$:J$(A*F126-F125)=D$:NEXT A:CLOSE #F2:GOTO 50
1810 IF PEEK(195)<>170 THEN 2190
1820 CLOSE #F2:? "Creating new month...";:FOR A=F1 TO 150:NEXT A
1830 J$=" ":J$(3906)=" ":J$(F2)=J$:GOTO 50
1840 REM DELETE MONTH
1850 E$="delete":GOSUB 1880
1860 TRAP 2190:? "Erasing...";:XIO 33,#F2,F0,F0,B$:GOTO 1680
1870 REM LOAD/CREATE, DELETE ROUTINE
1880 POKE LM,F1:LN=38:GOSUB 2130:? CL$:? :? A$
1890 ? "| 1-JANUARY   5-MAY      9-SEPTEMBER |"
1900 ? "| 2-FEBRUARY  6-JUNE    10-OCTOBER   |"
1910 ? "| 3-MARCH     7-JULY    11-NOVEMBER  |"
1920 ? "| 4-APRIL     8-AUGUST  12-DECEMBER  |"
1930 ? D$:POKE LM,F2:TRAP 2020
1940 ? :? :? "What # month to ";E$;:INPUT M:IF M<F1 OR M>F12 OR M<>INT(M) THEN 2020
1950 RESTORE 2010:FOR A=F1 TO M:READ M$:NEXT A:POSITION F2,F14:? "MONTH: ";M$
1960 POSITION F2,F12:? "What year (85-99)";BK$(F4,LEN(E$));"19";
1970 INPUT Y:Y=Y+1900:IF Y<1985 OR Y>1999 OR Y<>INT(Y) THEN 2020
1980 Y$=STR$(Y):POSITION F9+LEN(M$),F14:? ", ";Y
1990 B$="D:":B$(F3)=M$:B$(F6)=Y$:B$(F10)=".AC"
2000 ? :? :RETURN
2010 DATA JANUARY,FEBRUARY,MARCH,APRIL,MAY,JUNE,JULY,AUGUST,SEPTEMBER,OCTOBER,NOVEMBER,DECEMBER
2020 POP :GOTO 1680
2030 REM DIRECTORY
2040 POKE LM,F7:? CL$:? "This is the disk directory:":POKE LM,F10:? :TRAP 2190
2050 CLOSE #F2:OPEN #F2,F6,F0,"D:*.*":A=F2
2060 INPUT #F2,A$:? A$
2070 IF A$(F5,F16)="FREE SECTORS" THEN ? :? "   Press a key>";:GET #F1,B:CLOSE #F2:GOTO 1680
2080 A=A+F1:IF A/F21=INT(A/F21) THEN ? :? "   Press a key>";:GET #F1,B:? :? :A=F0
2090 GOTO 2060
2100 REM END
2110 POKE LM,F2:GRAPHICS F0:END
2120 REM CONSTRUCT STRINGS
2130 A$=CHR$(F18):A$(LN)=" ":A$(F2)=A$:A$(F1,F1)=CHR$(F17):A$(LN)=CHR$(F5)
2140 B$=" ":B$(LN)=" ":B$(F2)=B$:B$(F1,F1)=U$:B$(LN)=U$
2150 C$=A$:C$(F1,F1)=CHR$(F1):C$(LN)=CHR$(F4)
2160 D$=A$:D$(F1,F1)=CHR$(26):D$(LN)=CHR$(F3):RETURN
2170 REM ERRORS
2180 POKE LM,F2:? :? "ERROR #";PEEK(195);" AT LINE ";PEEK(186)+PEEK(187)*256:STOP
2190 CLOSE #F2:? :? :? "DISK ERROR--OPERATION ABORTED!";:FOR A=F1 TO 400:NEXT A:GOTO 1680