DISKIO Plus Macro Saver (KEYMAC.BAS)
DISKIO Plus Macro Saver, 13
Description
DISKIO Plus Macro Saver, 13
From the Antic disk of December 1985 (Vol. 4 No. 8).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 1.5 KB
- Dialect
- Atari BASIC
- Lines
- 52
- Variables
KEYBFFR$,TEMP$,KEY(,X,Y,FILE$,A,I
BASIC listing (52 lines)
10 REM DISKIO PLUS MACRO SAVER
20 REM BY PATRICK DELL'ERA
30 REM (c) 1985, ANTIC PUBLISHING
50 DIM KEYBFFR$(31*3),TEMP$(31),KEY(2),FILE$(20)
60 KEYBFFR$=CHR$(155):KEYBFFR$(31*3)=KEYBFFR$:KEYBFFR$(2)=KEYBFFR$
70 CLOSE #1:OPEN #1,4,0,"E:"
80 POKE 710,4:POKE 712,4
90 GOSUB 490
100 FOR X=1 TO 31*3
110 KEYBFFR$(X,X)=CHR$(PEEK(7423+X))
120 NEXT X
130 ?
140 FOR X=0 TO 2
150 KEY(X)=PEEK(10818+X*3)
160 ? "DEF";X+1;" ";CHR$(KEY(X)-128);" ";
170 Y=1+X*31
180 ? #1;KEYBFFR$(Y,Y);
190 IF ASC(KEYBFFR$(Y,Y))<>155 THEN Y=Y+1:GOTO 180
200 NEXT X
210 ?
220 ? "Enter filename for saving:":? ">";
230 X=PEEK(10592):POKE 10592,255
240 INPUT #1;TEMP$
250 POKE 10592,X
260 FILE$="D1:":IF TEMP$(2,2)=":" OR TEMP$(3,3)=":" THEN FILE$=TEMP$:GOTO 280
270 FILE$(4)=TEMP$
280 X=1
290 IF X>LEN(FILE$) THEN 320
300 IF FILE$(X,X)="." THEN 320
310 IF X<12 THEN X=X+1:GOTO 290
320 FILE$(X)=".KEY"
330 CLOSE #1:OPEN #1,8,0,FILE$
340 PUT #1,255:PUT #1,255
350 PUT #1,0:PUT #1,29
360 PUT #1,92:PUT #1,29
370 FOR X=1 TO LEN(KEYBFFR$)
380 PUT #1,ASC(KEYBFFR$(X,X))
390 NEXT X
400 A=63
410 FOR X=0 TO 2
420 A=A+3
430 PUT #1,A:PUT #1,42
440 PUT #1,A:PUT #1,42
450 PUT #1,KEY(X)
460 NEXT X
470 CLOSE #1
480 END
490 ? "↰ ▕DISKIO PLUS▎"
500 ? " ▕KEY MACRO SAVE UTILITY▎"
510 ? " by Patrick Dell'Era↓↓↓"
520 ? "Current Keyboard Macro Definitions:"
530 RETURN
