Typo II Code Generator (TYPOIICG.BAS)
Typo II Code Generator by Andy Barton, 23
Description
Typo II Code Generator by Andy Barton, 23
From the Antic disk of November 1985 (Vol. 4 No. 7).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.7 KB
- Dialect
- Atari BASIC
- Lines
- 54
- Variables
LINE$,OUT$,FILE$,X$,A$,A,X,C,ANS,D,CODE,HCODE,LCODE,RTS,Z,B$
BASIC listing (54 lines)
10 REM TYPO II CODE GENERATOR
20 REM BY ANDY BARTON
30 REM (C) 1985, ANTIC MAGAZINE
50 CLR :DIM LINE$(120),OUT$(128),FILE$(15),X$(19),A$(17)
55 DIM B$(75):B$=")├┐Khh┐Mh┐Lhh┐O)♥▔↰╱▔◀╱▔▶╱ ♥%K┐P1L┐N┴%Nm↰╱▔↰╱♣▝n◀╱-◀╱P┘n▶╱FPPfHfKFOPW◆"
60 ? "↰":? :? "TYPOII CODE GENERATOR"
80 ? :? "Choose a file: [Dn:filename OR C:] ":? :? :INPUT FILE$
90 TRAP 380:CLOSE #2:OPEN #2,4,0,FILE$
100 TRAP 360:INPUT #2;LINE$
110 A=ASC(LINE$(1,1)):IF A<48 OR A>57 THEN 360
120 TRAP 40000:? :? "CHOOSE OUTPUT DEVICE:":? "Screen Printer Disk Cassette":? :? :? " ";:INPUT OUT$
130 IF OUT$="S" THEN OUT$="E":GOTO 190
140 IF OUT$="D" THEN ? :? "GIVE [Dn:file name] ";:INPUT OUT$:IF OUT$<>"" THEN 170
150 IF OUT$<>"P" AND OUT$<>"C" THEN 120
160 GOTO 190
170 FOR X=1 TO LEN(OUT$):IF OUT$(X,X)="." THEN 190
180 NEXT X:OUT$(LEN(OUT$)+1)=".TYP"
190 TRAP 450:CLOSE #3:OPEN #3,8,0,OUT$:TRAP 40000:IF OUT$="C" THEN OUT$=" ":OUT$(128)=" ":OUT$(2)=OUT$:? #3;OUT$
200 GOTO 220
210 TRAP 340:INPUT #2;LINE$:TRAP 40000
220 IF LINE$(LEN(LINE$))=" " THEN LINE$=LINE$(1,LEN(LINE$)-1)
230 C=0:ANS=C:ANS=USR(ADR(B$),ADR(LINE$),LEN(LINE$)):ANS=PEEK(1789)+256*PEEK(1790)+65536*PEEK(1791)
240 CODE=INT(ANS/676)
250 CODE=ANS-(CODE*676)
260 HCODE=INT(CODE/26)
270 LCODE=CODE-(HCODE*26)+65
280 HCODE=HCODE+65
290 OUT$=CHR$(HCODE):OUT$(2,2)=CHR$(LCODE):OUT$(3,3)=" "
300 FOR X=1 TO LEN(LINE$):IF LINE$(X,X)=" " THEN 320
310 NEXT X
320 OUT$(4)=LINE$(1,X-1)
330 ? #3;OUT$:GOTO 210
340 IF PEEK(195)<>136 THEN ? :? "ERROR- ";PEEK(195):END
350 ? :? "^^^ FINISHED ^^^":END
360 ? :? FILE$;" is not a BASIC program"
370 ? "in LIST format.":GOTO 390
380 OUT$=FILE$:RTS=390:GOTO 460
390 OUT$="D1:*.*":TRAP 400:IF FILE$(1,2)>"D1" AND FILE$(1,2)<"D5" THEN OUT$(2,2)=FILE$(2,2)
400 TRAP 440:? :CLOSE #1:OPEN #1,6,0,OUT$:? :? OUT$(1,2);" DIRECTORY":?
410 INPUT #1,A$:IF A$(5,8)="FREE" THEN ? :GOTO 80
420 X$=A$(3,11):X$(10)=A$(11,17):X$(17)=" ":IF A$(11,11)<>" " THEN X$(9,9)="."
430 ? X$;:GOTO 410
440 RTS=80:GOTO 460
450 RTS=120
460 ? :A=PEEK(195):IF A=130 THEN ? OUT$;" DOES NOT EXIST":? "TYPE Dn:filename":Z=1
470 IF A=138 THEN ? OUT$;" DOES NOT RESPOND":Z=1
480 IF A=160 THEN ? "DRIVE NUMBER ERROR":Z=1
490 IF A=162 THEN ? "THIS DISK IS FULL. USE ANOTHER ONE":Z=1
500 IF A=165 THEN ? OUT$;" IS AN INVALID FILE NAME":Z=1
510 IF A=167 THEN ? OUT$;" IS LOCKED":Z=1
520 IF A=169 THEN ? "THE DISK DIRECTORY IF FULL. USE ANOTHER DISKETTE":Z=1
530 IF A=170 THEN ? "FILE NOT FOUND":Z=1
540 IF Z<>1 THEN ? "ERROR- ";A
550 Z=0:? :GOTO RTS
