130XE Memory Management demo (SWITCHER.BAS)
130XE Memory Management demo by Ian Chadwick, 19
Description
130XE Memory Management demo by Ian Chadwick, 19
From the Antic disk of November 1985 (Vol. 4 No. 7).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 2.3 KB
- Dialect
- Atari BASIC
- Lines
- 70
- Variables
START,LOOP,DL,SC1,SC2,SC3,SC4,N
BASIC listing (70 lines)
2 REM 130XE MEMORY MANAGEMENT
4 REM BY IAN CHADWICK
6 REM (c) 1985, ANTIC PUBLISHING
10 ? "↰"
15 PRINT "130XE EXTENDED BANK DEMONSTRATION"
16 PRINT "BY IAN CHADWICK":PRINT
20 POKE 54017,253:REM DEFAULT VALUE
30 START=16384:REM FIRST BYTE OF ACCESS WINDOW
40 LOOP=0:GOSUB 5000
50 DL=PEEK(560)+PEEK(561)*256:REM START OF DISPLAY LIST
60 SC1=PEEK(DL+4):SC2=PEEK(DL+5):REM START OF SCREEN RAM
70 SC3=PEEK(88):SC4=PEEK(89):REM SCREEN POINTERS IN RAM
130 ? "PRESS A CONSOLE KEY"
135 POKE 53279,8:REM CLEAR CONSOLE KEYS
140 IF PEEK(53279)=7 THEN 140:REM TEST FOR CONSOLE KEY
145 POKE 106,128:REM LOWER RAMTOP
150 IF PEEK(53279)=6 THEN GOSUB 1000:REM START
160 IF PEEK(53279)=5 THEN GOSUB 2000:REM SELECT
165 IF PEEK(53279)=2 THEN GOSUB 2500:REM START & OPTION
170 IF PEEK(53279)=3 THEN GOSUB 3000:REM OPTION
180 IF PEEK(53279)=4 THEN GOSUB 4000:REM START & SELECT
185 IF PEEK(53279)=0 THEN GOSUB 4500:REM ALL THREE
190 GOTO 140
999 REM START PRESSED: SHOW EXTENDED BANK 0
1000 POKE DL+4,0:POKE DL+5,64
1010 POKE 88,0:POKE 89,64
1020 POKE 54017,209
1030 RETURN
1999 REM SELECT PRESSED: SHOW EXTENDED BANK 1
2000 POKE DL+4,0:POKE DL+5,64
2010 POKE 88,0:POKE 89,64
2020 POKE 54017,213
2030 RETURN
2499 REM OPTION & START PRESSED: SHOW MAIN BANK 1
2500 POKE DL+4,0:POKE DL+5,64
2510 POKE 88,0:POKE 89,64
2520 POKE 54017,253
2530 RETURN
2999 REM OPTION PRESSED: SHOW EXTENDED BANK 2
3000 POKE DL+4,0:POKE DL+5,64
3010 POKE 88,0:POKE 89,64
3020 POKE 54017,217
3030 RETURN
3999 REM START & SELECT PRESSED: SHOW EXTENDED BANK 3
4000 POKE DL+4,0:POKE DL+5,64
4010 POKE 88,0:POKE 89,64
4020 POKE 54017,221
4030 RETURN
4499 REM ALL THREE PRESSED: RESTORE RAMTOP AND SHOW ORIGINAL SCREEN AREA
4500 POKE 106,160:POKE DL+4,SC1:POKE DL+5,SC2
4510 POKE 88,SC3:POKE 89,SC4
4520 POKE 54017,253
4530 RETURN
4999 REM FILL A SCREEN EQUIVALENT WITH A VALUE
5000 FOR LOOP=0 TO 3
5005 ? "FILLING EXTENDED BANK ";LOOP
5010 POKE 54017,225+LOOP*4
5020 GOSUB 6000:IF LOOP>3 THEN 5040
5030 NEXT LOOP
5035 GOSUB 6500
5040 RETURN
6000 FOR N=START TO START+993
6010 POKE N,17+LOOP-1:NEXT N
6020 RETURN
6499 REM MAIN BANK FILL
6500 POKE 54017,253:? "FILLING MAIN BANK 1"
6505 FOR N=START TO START+993
6510 POKE N,20:NEXT N
6515 POKE 106,128
6520 RETURN
