MINEFIELD (MINE.BAS)
MINEFIELD, game by Persing and O'Neill, 15
Description
MINEFIELD, game by Persing and O'Neill, 15
From the Antic disk of November 1985 (Vol. 4 No. 7).
From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.
What is in this file
Atari BASIC program · 1.8 KB
- Dialect
- Atari BASIC
- Lines
- 45
- Variables
C,BOX,A,B,N,X,POO,O,R,I,G,KO
BASIC listing (45 lines)
10 REM MINEFIELD
20 REM BY PERSING AND O'NEILL
30 REM ANTIC PUBLISHING
40 ? "↰":? :? :? :POKE 752,1
50 ? " In MINEFIELD you have just escapedfrom a Communist prison camp. You havestumbled onto a minefield ";
60 ? "and must escape! You may interscreen but your object is to get to the right edge."
65 ? "You may fire a stolen laser that will destroy one pixel of a mine.Be thriftyfor you only have 5 shots."
70 ? "Best of luck!"
80 ? :? "Press START to begin."
90 IF PEEK(53279)<>6 THEN 90
100 C=60
1000 GRAPHICS 7:SETCOLOR 2,0,0
1100 FOR BOX=1 TO 65:COLOR 2
1110 A=INT(145*RND(0))+5:B=INT(70*RND(0)+1)
1120 PLOT A,B:DRAWTO A+5,B:DRAWTO A+5,B+5:DRAWTO A,B+5:DRAWTO A,B
1130 NEXT BOX
1200 N=40:COLOR 1
1210 FOR X=0 TO 158:POKE 752,1
1215 SOUND 0,N+INT(RND(0)*5)+1,12,5
1220 PLOT X,N
1230 IF STICK(0)=14 THEN N=N-1
1235 IF STICK(0)=13 THEN N=N+1
1240 LOCATE X+1,N,POO:IF POO=2 THEN 2000
1241 IF N=79 THEN N=1
1242 IF N=0 THEN N=78
1243 IF STRIG(0)=0 AND O<=4 THEN 3000
1250 NEXT X
1260 ? "YOU FINISHED!!":C=C+20:R=R+1
1270 ? "PRESS FIRE BUTTON":O=0
1273 ? "YOU FINISHED ";R;" ROUND(S)"
1275 SOUND 0,0,0,0
1280 IF STRIG(0)=1 THEN 1280
1290 GOTO 1000
2000 FOR I=29 TO 243:SOUND 0,I,8,10:NEXT I
2010 ? "YOU COMPLETED ";INT(X/158*100);"% OF MINEFIELD"
2020 GOTO 1270
3000 G=X
3010 COLOR 1:PLOT G,N
3015 SOUND 1,G,10,5
3020 LOCATE G+1,N,KO:IF KO=2 THEN 3050
3030 G=G+1:IF G=158 THEN 3050
3040 GOTO 3010
3050 COLOR 0:PLOT X+1,N:DRAWTO G+1,N
3055 SOUND 1,0,0,0
3060 O=O+1:G=0:COLOR 1:GOTO 1250
