Graph 3D (GRAPH3D.BAS)

Graph 3D by Paul Chabot, 102

Description

Graph 3D by Paul Chabot, 102

From the Antic disk of October 1985 (Vol. 4 No. 6).

From the Antic Software Archive at atarimagazines.com. The program remains the property of its author and publisher.

What is in this file

Atari BASIC program · 10.5 KB

Dialect
Atari BASIC
Lines
333
Variables
Z, X, Y, QX, FX, QY, FY, QZ, FZ, SX, A1, A2, A3, SY, A4, A5, A6, SZ, A7, A8, A9, ED, T, M, CX, CY, DX, BX, AX, NX, DY, BY, AY, NY, C, I, J, PX(, PY(, PZ(, CF, SI, SJ, GF, EX, EY, EZ, XX, E$, BL$, I$, N, Z$, ZB$, A$, L, FI$, IO, SA1, K, B$, M$, LBL, RAM, MOD1, DL1L, DL1H, SA1L, SA1H, MOD2, DL2L, DL2H, SA2L, SA2H, DL
BASIC listing (333 lines)
10 REM GRAPH 3-D, LISTING 2
20 REM BY PAUL CHABOT
30 REM (c) 1985, ANTIC PUBLISHING
35 IF PEEK(1536)<>104 THEN RUN "D:GR3DLOAD.BAS"
40 GOTO 2000
100 REM **** THE FUNCTION ***********
120 Z=X*X-Y*Y/2
130 RETURN
150 REM **** FIND SX,SY *************
152 QX=QX-FX:QY=QY-FY:QZ=QZ-FZ
154 SX=QX*A1+QY*A2+QZ*A3
156 SY=QX*A4+QY*A5+QZ*A6
158 SZ=QX*A7+QY*A8+QZ*A9
160 X=ED-SZ:IF X<1 THEN X=1
162 T=(M*ED)/(X+X)
164 SX=T*SX+CX:SY=CY-T*SY
166 IF SX<0 THEN SX=0
168 IF SX>319 THEN SX=319
170 IF SY<0 THEN SY=0
172 IF SY>191 THEN SY=191
174 RETURN
200 REM **** COMPUTE POINTS *********
202 TRAP 800:POSITION 21,14
204 ? " COMPUTING POINTS "
212 DX=(BX-AX)/NX:DY=(BY-AY)/NY
214 X=AX-DX:C=132
216 FOR I=0 TO NX:X=X+DX:Y=AY-DY
218 FOR J=0 TO NY:Y=Y+DY:GOSUB 100
224 PX(I,J)=X:PY(I,J)=Y:PZ(I,J)=Z
226 C=C+2:IF C>255 THEN C=0
228 POKE 708,C:NEXT J:NEXT I
230 POKE 708,132
232 RETURN
300 REM **** GRAPH IT ***************
302 IF CF=1 THEN GOSUB 200:GOSUB 400
304 GRAPHICS 24:GOSUB 1560:COLOR 1
306 CF=0:GOSUB 1180:SI=1:SJ=1
310 IF GF=1 THEN SJ=NY
312 IF GF=2 THEN SI=NX
314 IF GF=3 THEN SJ=3
316 IF GF=4 THEN SI=3
318 IF GF=5 THEN SI=3:SJ=3
329 REM PERP. TO X-AXIS
330 FOR I=0 TO NX STEP SI
332 FOR J=0 TO NY:QX=PX(I,J)
334 QY=PY(I,J):QZ=PZ(I,J):GOSUB 150
336 IF J=0 THEN PLOT SX,SY
338 DRAWTO SX,SY:NEXT J:NEXT I
339 REM PERP. TO Y-AXIS
340 FOR J=0 TO NY STEP SJ
342 FOR I=0 TO NX:QX=PX(I,J)
344 QY=PY(I,J):QZ=PZ(I,J):GOSUB 150
346 IF I=0 THEN PLOT SX,SY
348 DRAWTO SX,SY:NEXT I:NEXT J
350 GOSUB 1180:RETURN
400 REM **** FIX MATRIX *************
402 TRAP 800:POSITION 21,14
404 ? "  fixing  matrix  "
406 X=(AX+BX)/2:Y=(AY+BY)/2
408 GOSUB 100
410 FX=X:FY=Y:FZ=Z
412 A7=EX-FX:A8=EY-FY:A9=EZ-FZ
414 ED=SQR(EX*EX+EY*EY+EZ*EZ)
416 A7=A7/ED:A8=A8/ED:A9=A9/ED
418 A6=A7*A7+A8*A8
420 IF A6=0 THEN A4=0:A5=1:GOTO 430
422 IF A9=0 THEN A4=0:A5=0:A6=1:GOTO 430
424 IF A9<0 THEN A4=A7:A5=A8:A6=-A6/A9:GOTO 430
426 A4=-A7:A5=-A8:A6=A6/A9
430 A1=A5*A9-A6*A8
432 A2=A6*A7-A4*A9
434 A3=A4*A8-A5*A7
436 XX=SQR(A4*A4+A5*A5+A6*A6)
438 A4=A4/XX:A5=A5/XX:A6=A6/XX
440 XX=SQR(A1*A1+A2*A2+A3*A3)
442 A1=A1/XX:A2=A2/XX:A3=A3/XX
444 RETURN
480 REM **** INPUT=[RETURN] *********
482 IF PEEK(764)=255 THEN 482
484 IF PEEK(764)<>12 THEN RETURN
486 POKE 764,255:POP :RETURN
500 REM **** MAG CHANGE *************
502 ? "  magnification":?
504 ? "   MAG=";M;"    INPUT ";
506 GOSUB 480:INPUT M:GOSUB 1120
508 RETURN
520 REM **** OPTION FLAG ************
522 GF=GF+1:IF GF>5 THEN GF=0
524 POSITION 13,3:? GF:RETURN
550 REM **** EYE CHANGE *************
552 ? "  eye   LOCATION":?
554 ? E$;"      EX,EY,EZ"
556 ? BL$(28);"INPUT ";:GOSUB 480
558 INPUT EX,EY,EZ:GOSUB 1130
560 GOSUB 400:RETURN
600 REM **** INTERVAL CHANGE ********
602 ? "    intervals":?
604 ? I$;"    AX,BX,AY,BY"
606 ? BL$(28);"INPUT ";:GOSUB 480
608 INPUT AX,BX,AY,BY:GOSUB 1140
610 CF=1:RETURN
620 REM **** PARTITION SIZE *********
622 ? " partition  SIZES":?
624 ? " NX,NY = ";NX;",";NY
626 ? " INPUT ";:GOSUB 480
628 INPUT NX,NY:IF NX<3 THEN NX=3
630 IF NX>N THEN NX=N
632 IF NY<3 THEN NY=3
634 IF NY>N THEN NY=N
636 CF=1:RETURN
650 REM **** CENTER CHANGE **********
652 ? "  center  screen":?
654 ? " CX,CY = ";CX;",";CY
656 ? " INPUT ";:GOSUB 480
658 INPUT CX,CY:RETURN
700 REM **** FUNCTION CHANGE ********
702 ? "  new  function":?
704 ? Z$:? "Z=";:GOSUB 480:ZB$=Z$
706 INPUT A$:Z$="Z=":Z$(3)=A$
708 GOSUB 720:CF=1:RETURN
720 REM **** CREATE LINE 120 ********
722 GOSUB 1100:? "120 ";Z$:? :? "CONT";
724 POSITION 2,16:POKE 842,13:STOP
726 POKE 842,12:RETURN
750 REM **** RECOVER LAST FUNCTION **
752 ? " ??  recover  ??":?
754 ? " Recover last function    Y/N"
756 ? "** current will die **";
758 L=PEEK(764):IF L=255 THEN 758
760 POKE 764,255:IF L<>43 THEN RETURN
762 A$=Z$:Z$=ZB$:ZB$=A$
764 GOSUB 720:CF=1:RETURN
800 REM **** VALUE ERROR TRAP *******
802 GOSUB 1580:POSITION 21,14
804 ? "**value***error**":POP :POP
806 POKE 764,255:POSITION 2,16
808 ? "  TRY  [any key]    -  to recover "
810 IF PEEK(764)=255 THEN 810
812 RETURN
840 REM **** I/O TRAP ***************
842 GOSUB 1580:POSITION 21,14
844 CLOSE #2:? "*** e r r o r ***"
846 GOTO 806
850 REM **** DISK DIRECTORY *********
852 TRAP 840:POKE 82,21:POSITION 21,3
854 FOR J=1 TO 10:? BL$(22):NEXT J
856 POSITION 21,3
858 CLOSE #2:OPEN #2,6,0,"D:*.G3D"
860 FOR J=1 TO 10:FOR I=0 TO 1
862 INPUT #2,A$:IF LEN(A$)=16 THEN 870
864 ? A$(3,10);" ";:NEXT I:? :NEXT J
870 CLOSE #2:POSITION 21,13:? A$
872 POKE 82,2:RETURN
880 REM **** GET FILENAME ***********
882 ? "  Current name  ";FI$(3)
884 ? " INPUT filename ";:GOSUB 480
886 INPUT A$:FI$="D:":FI$(3)=A$
888 FI$(LEN(FI$)+1)=".G3D":RETURN
890 REM **** 2ND CHANCE *************
891 GOSUB 2190:? "   DO IT ?     Y/N"
892 ? "  filespecs ";FI$
894 L=PEEK(764):IF L=255 THEN 894
896 POKE 764,255:IF L=43 THEN RETURN
898 POP :RETURN
900 REM **** SAVE TO DISK ***********
902 ? "      S A V E":? :GOSUB 880
904 GOSUB 890:GOSUB 1560:TRAP 840
906 OPEN #2,8,0,FI$:POKE 1913,80
908 X=USR(IO,2,7680,SA1,11)
910 ? #2;Z$:? #2;M
912 ? #2;EX:? #2;EY:? #2;EZ
914 ? #2;AX:? #2;BX
916 ? #2;AY:? #2;BY
918 ? #2;CX:? #2;CY
920 ? #2;NX:? #2;NY
922 CLOSE #2:POKE 1913,87
924 GOSUB 1580:GOSUB 850:RETURN
930 REM **** LOAD FROM DISK *********
932 ? "     L O A D":? :GOSUB 880
934 GOSUB 890:GOSUB 1560:TRAP 840
936 ZB$=Z$:OPEN #2,4,0,FI$
938 X=USR(IO,2,7680,SA1,7)
940 INPUT #2;Z$:INPUT #2;M
942 INPUT #2;EX:INPUT #2;EY:INPUT #2;EZ
944 INPUT #2;AX:INPUT #2;BX
946 INPUT #2;AY:INPUT #2;BY
948 INPUT #2;CX:INPUT #2;CY
950 INPUT #2;NX:INPUT #2;NY
952 CLOSE #2:GOSUB 1580
954 GOSUB 1120:GOSUB 1130:GOSUB 1140
956 GOSUB 720:CF=1:RETURN
960 REM **** PRINT IT ***************
961 ? " ?? PRINT   IT ??":?
962 ? "       title  ";FI$(3):?
963 ? "  1-LEFT              2-RIGHT"
964 K=PEEK(764):IF K=255 THEN 964
966 POKE 764,255:TRAP 840
968 IF K<>31 AND K<>30 THEN RETURN
970 CLOSE #2:OPEN #2,8,0,"P:"
971 REM INITIALIZE
972 ? #2;CHR$(27);CHR$(64);
973 REM FILENAME
974 IF K=30 THEN ? #2;BL$;
976 ? #2;CHR$(14);"  ";FI$(3)
977 REM SET LINE FEED
978 ? #2;CHR$(27);CHR$(51);CHR$(16)
980 X=SA1+192*40
982 FOR I=0 TO 39:T=X+I
984 FOR J=1 TO 192:T=T-40
986 B$(J,J)=CHR$(PEEK(T)):NEXT J
987 REM PRINT GRAPHICS STRING
988 IF K=30 THEN ? #2;BL$;
990 ? #2;CHR$(27);CHR$(75);CHR$(192);CHR$(0);B$
992 NEXT I
994 CLOSE #2:RETURN
1100 REM **** FORCED READ ***********
1102 POSITION 2,18:? BL$
1104 POSITION 2,18:RETURN
1110 POSITION 1,18
1112 POKE 842,13:INPUT A$
1114 POKE 842,12:RETURN
1120 REM **** FILL M$
1122 GOSUB 1100:? "MAG:";M
1124 GOSUB 1110:M$=A$:RETURN
1130 REM **** FILL E$
1132 GOSUB 1100
1134 ? "EYE:";EX;",";EY;",";EZ
1136 GOSUB 1110:E$=A$:RETURN
1140 REM **** FILL I$
1142 GOSUB 1100
1144 ? "[";AX;",";BX;"]*[";AY;",";BY;"]"
1146 GOSUB 1110:I$=A$:RETURN
1150 REM **** FILL Z$
1152 GOSUB 1100:POSITION 2,17:LIST 120
1154 GOSUB 1110:Z$=A$(5):RETURN
1180 REM **** LABEL SCREEN **********
1182 X=USR(LBL,32,2,ADR(M$),LEN(M$))
1184 X=USR(LBL,0,23,ADR(I$),LEN(I$))
1186 X=USR(LBL,22,23,ADR(E$),LEN(E$))
1188 L=LEN(Z$):IF L>40 THEN L=40
1190 X=USR(LBL,0,0,ADR(Z$),L)
1192 IF LEN(Z$)<41 THEN RETURN
1194 X=USR(LBL,0,1,ADR(Z$)+40,LEN(Z$)-40)
1196 RETURN
1500 REM ****SETUP 2 SCREENS ********
1502 RAM=PEEK(106):GRAPHICS 24:MOD1=8
1504 DL1L=PEEK(560):DL1H=PEEK(561)
1506 SA1L=PEEK(88):SA1H=PEEK(89)
1508 SA1=SA1L+256*SA1H
1510 POKE 106,RAM-33:GRAPHICS 0:MOD2=0
1512 DL2L=PEEK(560):DL2H=PEEK(561)
1514 SA2L=PEEK(88):SA2H=PEEK(89)
1516 DL=DL2L+256*DL2H:POKE 106,RAM
1518 POKE DL+3,71:POKE DL+6,6
1520 POKE DL+8,64:POKE DL+21,6
1522 POKE DL+22,6:POKE DL+24,48
1524 RETURN
1560 REM **** SCREEN 1 - PICTURE ****
1562 POKE 560,DL1L:POKE 561,DL1H
1564 POKE 88,SA1L:POKE 89,SA1H
1566 POKE 709,26:POKE 710,0:POKE 712,128
1568 POKE 87,MOD1:RETURN
1580 REM **** SCREEN 2 - MENU *******
1582 POKE 560,DL2L:POKE 561,DL2H
1584 POKE 88,SA2L:POKE 89,SA2H
1586 POKE 709,24:POKE 710,194:POKE 712,224:POKE 708,132:POKE 711,68
1588 POKE 87,MOD2:POKE 752,1:RETURN
2000 REM *** MAIN ROUTINE ***********
2002 GOSUB 2200
2010 GOSUB 1580:POSITION 21,14
2012 ? "? ? what  next ? ?";:TRAP 840
2014 GOSUB 2170
2016 K=PEEK(764):IF K=255 THEN 2016
2018 POKE 764,255:GOSUB 2190
2020 POSITION 21,14:? BL$(21):POSITION 21,14
2022 IF K=61 THEN GOSUB 300:REM ...G
2024 IF K=37 THEN GOSUB 500:REM ...M
2026 IF K=8 THEN GOSUB 520:REM ....O
2028 IF K=42 THEN GOSUB 550:REM ...E
2030 IF K=13 THEN GOSUB 600:REM ...I
2032 IF K=35 THEN GOSUB 620:REM ...N
2034 IF K=18 THEN GOSUB 650:REM ...C
2036 IF K=56 THEN GOSUB 700:REM ...F
2038 IF K=40 THEN GOSUB 750:REM ...R
2040 IF K=58 THEN GOSUB 850:REM ...D
2042 IF K=62 THEN GOSUB 900:REM ...S
2044 IF K=0 THEN GOSUB 930:REM ....L
2046 IF K=10 THEN GOSUB 960:REM ...P
2048 IF K=33 THEN GOSUB 1560:REM SPACE
2050 IF PEEK(764)=255 AND PEEK(87)=8 THEN 2050
2052 IF PEEK(764)=33 THEN POKE 764,255
2060 GOTO 2010
2100 REM **** MAIN MENU *************
2102 POKE 752,1:POSITION 2,0
2110 ? " g r a p h 3 D     ^^^^^^^^^^^^^^^^^"
2112 ? "  Paul Chabot            1985"
2114 ? " [G] GRAPH IT          DIRECTORY    "
2116 ? "[O] Option 0       "
2118 ? "[F] Function       "
2120 ? "[M] Magnification  "
2122 ? "[E] Eye Position   "
2124 ? "[C] Center Screen  "
2126 ? "[I] Intervals      "
2128 ? "[N] Partition size "
2130 ? "[R] Recover last   "
2132 ? "     I / O         "
2134 ? "[L] Load  [S] Save "
2136 ? "[P] Print [D] Dir. "
2138 ? "OoOoOoOoOoOoOoOo"
2140 ? "      [SPACE]  -  Picture / Menu    "
2150 GOSUB 850:RETURN
2170 REM **** MINI-MENU
2172 GOSUB 2190:? I$;"     ";E$
2174 ? Z$:RETURN
2190 REM **** CLEAN-UP
2192 POSITION 1,18:? " "
2194 FOR I=16 TO 21:POSITION 2,I
2196 ? BL$;:NEXT I
2198 POSITION 2,16:RETURN
2200 REM **** INITIALIZE ************
2202 N=24:LBL=1536:IO=1704:M=150
2204 AX=-1:BX=1:AY=-1:BY=1:NX=8:NY=10
2206 EX=10:EY=10:EZ=5:CX=160:CY=100
2210 DIM PX(N,N),PY(N,N),PZ(N,N)
2212 DIM A$(78),I$(19),E$(15),M$(9)
2214 DIM Z$(78),ZB$(78),FI$(14)
2216 DIM B$(192),BL$(38)
2218 BL$=" ":BL$(38)=" ":BL$(2)=BL$
2220 FI$="D:SAMPLE.G3D"
2230 GOSUB 1500:GOSUB 1580:GOSUB 2100
2232 GOSUB 1120:GOSUB 1130:GOSUB 1140
2234 GOSUB 1150:CF=1:GF=0:GOSUB 300
2240 ZB$=Z$:RETURN